blkmapd: Add complex block layout discovery and mapping daemon
[nfs-utils.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 dnl
3 AC_INIT([linux nfs-utils],[1.2.4],[linux-nfs@vger.kernel.org],[nfs-utils])
4 AC_CANONICAL_BUILD([])
5 AC_CANONICAL_HOST([])
6 AC_CONFIG_MACRO_DIR(aclocal)
7 AM_INIT_AUTOMAKE
8 AC_PREREQ(2.59)
9 AC_PREFIX_DEFAULT(/usr)
10 AM_MAINTAINER_MODE
11
12 dnl *************************************************************
13 dnl * Define the set of applicable options
14 dnl *************************************************************
15 AC_ARG_WITH(release,
16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
17         RELEASE=$withval,
18         RELEASE=1)
19         AC_SUBST(RELEASE)
20 AC_ARG_WITH(statedir,
21         [AC_HELP_STRING([--with-statedir=/foo],
22                         [use state dir /foo @<:@default=/var/lib/nfs@:>@])],
23         statedir=$withval,
24         statedir=/var/lib/nfs)
25         AC_SUBST(statedir)
26 AC_ARG_WITH(statdpath,
27         [AC_HELP_STRING([--with-statdpath=/foo @<:@default=/var/lib/nfs@:>@],
28                 [define statd's state dir as /foo instead of the NFS statedir]
29         )],
30         statdpath=$withval,
31         statdpath=$statedir
32         )
33         AC_SUBST(statdpath)
34 AC_ARG_WITH(statduser,
35         [AC_HELP_STRING([--with-statduser=rpcuser],
36                         [statd to run under @<:@rpcuser or nobody@:>@]
37         )],
38         statduser=$withval,
39         if test "x$cross_compiling" = "xno"; then
40                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
41                         statduser=rpcuser
42                 else
43                         statduser=nobody
44                 fi
45         else
46                 statduser=nobody
47         fi)
48         AC_SUBST(statduser)
49 AC_ARG_WITH(start-statd,
50         [AC_HELP_STRING([--with-start-statd=scriptname],
51                         [When an nfs filesystems is mounted with locking, run this script]
52         )],
53         startstatd=$withval,
54         startstatd=/usr/sbin/start-statd
55         )
56         AC_SUBST(startstatd)
57         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
58 AC_ARG_ENABLE(nfsv3,
59         [AC_HELP_STRING([--enable-nfsv3],
60                         [enable support for NFSv3 @<:@default=yes@:>@])],
61         enable_nfsv3=$enableval,
62         enable_nfsv3=yes)
63         if test "$enable_nfsv3" = yes; then
64                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
65         else
66                 enable_nfsv3=
67         fi
68         AC_SUBST(enable_nfsv3)
69 AC_ARG_ENABLE(nfsv4,
70         [AC_HELP_STRING([--enable-nfsv4],
71                         [enable support for NFSv4 @<:@default=yes@:>@])],
72         enable_nfsv4=$enableval,
73         enable_nfsv4=yes)
74         if test "$enable_nfsv4" = yes; then
75                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
76                 IDMAPD=idmapd
77         else
78                 enable_nfsv4=
79                 IDMAPD=
80         fi
81         AC_SUBST(IDMAPD)
82         AC_SUBST(enable_nfsv4)
83         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
84
85 AC_ARG_ENABLE(nfsv41,
86         [AC_HELP_STRING([--enable-nfsv41],
87                         [enable support for NFSv41 @<:@default=yes@:>@])],
88         enable_nfsv41=$enableval,
89         enable_nfsv41=yes)
90         if test "$enable_nfsv41" = yes; then
91                 BLKMAPD=blkmapd
92                 AC_DEFINE(NFS41_SUPPORTED, 1, [Define this if you want NFSv41 support compiled in])
93         else
94                 enable_nfsv41=
95                 BLKMAPD=
96         fi
97         AC_SUBST(enable_nfsv41)
98         AM_CONDITIONAL(CONFIG_NFSV41, [test "$enable_nfsv41" = "yes"])
99
100 AC_ARG_ENABLE(gss,
101         [AC_HELP_STRING([--enable-gss],
102                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
103         enable_gss=$enableval,
104         enable_gss=yes)
105         if test "$enable_gss" = yes; then
106                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
107                 GSSD=gssd
108                 SVCGSSD=svcgssd
109         else
110                 enable_gss=
111                 GSSD=
112                 SVCGSSD=
113         fi
114         AC_SUBST(GSSD)
115         AC_SUBST(SVCGSSD)
116         AC_SUBST(enable_gss)
117         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
118 AC_ARG_ENABLE(kprefix,
119         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
120         test "$enableval" = "yes" && kprefix=k,
121         kprefix=)
122         AC_SUBST(kprefix)
123 AC_ARG_WITH(rpcgen,
124         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
125         rpcgen_path=$withval,
126         rpcgen_path=yes )
127         RPCGEN_PATH=
128         if test "$rpcgen_path" = "yes"; then
129             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
130             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
131         elif test "$rpcgen_path" != "internal"; then
132             RPCGEN_PATH=$rpcgen_path
133         fi
134         AC_SUBST(RPCGEN_PATH)
135         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" = ""])
136 AC_ARG_ENABLE(uuid,
137         [AC_HELP_STRING([--disable-uuid], [Exclude uuid support to avoid buggy libblkid])],
138         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
139         choose_blkid=default)
140 AC_ARG_ENABLE(mount,
141         [AC_HELP_STRING([--enable-mount],
142                         [Create mount.nfs and do not use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
143         enable_mount=$enableval,
144         enable_mount=yes)
145         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
146
147 if test "$enable_mount" = yes; then
148         AC_ARG_ENABLE(libmount-mount,
149                 [AC_HELP_STRING([--enable-libmount-mount],
150                                 [Link mount.nfs with libmount (EXPERIMENTAL)])],
151                 enable_libmount=$enableval,
152                 enable_libmount=no)
153 fi
154
155 AC_ARG_ENABLE(tirpc,
156         [AC_HELP_STRING([--enable-tirpc],
157                         [enable use of TI-RPC @<:@default=yes@:>@])],
158         enable_tirpc=$enableval,
159         enable_tirpc='')
160 AC_ARG_ENABLE(ipv6,
161         [AC_HELP_STRING([--enable-ipv6],
162                         [enable support for IPv6 @<:@default=no@:>@])],
163         enable_ipv6=$enableval,
164         enable_ipv6=no)
165         if test "$enable_ipv6" = yes; then
166                 AC_DEFINE(IPV6_SUPPORTED, 1, [Define this if you want IPv6 support compiled in])
167         else
168                 enable_ipv6=
169         fi
170         AC_SUBST(enable_ipv6)
171         AM_CONDITIONAL(CONFIG_IPV6, [test "$enable_ipv6" = "yes"])
172
173 if test "$enable_mount" = yes; then
174         AC_ARG_ENABLE(mountconfig,
175         [AC_HELP_STRING([--enable-mountconfig],
176                         [enable mount to use a configuration file])],
177         mountconfig=$enableval,
178         mountconfig=no)
179         if test "$enable_mountconfig" = yes; then
180                 AC_DEFINE(MOUNT_CONFIG, 1, 
181                         [Define this if you want mount to read a configuration file])
182                 AC_ARG_WITH(mountfile,
183                         [AC_HELP_STRING([--with-mountfile=filename],
184                         [Using filename as the NFS mount options file [/etc/nfsmounts.conf]]
185                         )],
186                 mountfile=$withval,
187                 mountfile=/etc/nfsmount.conf)
188                 AC_SUBST(mountfile)
189                 AC_DEFINE_UNQUOTED(MOUNTOPTS_CONFFILE, "$mountfile", 
190                         [This defines the location of the NFS mount configuration file])
191         else
192                 enable_mountconfig=
193         fi
194         AC_SUBST(enable_mountconfig)
195         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mountconfig" = "yes"])
196 else
197         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mount" = "yes"])
198 fi
199
200 dnl Check for TI-RPC library and headers
201 AC_LIBTIRPC
202
203 dnl Check for -lcap
204 AC_LIBCAP
205
206 # Check whether user wants TCP wrappers support
207 AC_TCP_WRAPPERS
208
209 # Arrange for large-file support
210 AC_SYS_LARGEFILE
211
212 AC_CONFIG_SRCDIR([support/include/config.h.in])
213 AC_CONFIG_HEADERS([support/include/config.h])
214
215 # Checks for programs.
216 AC_PROG_CXX
217 AC_PROG_CC
218 AC_PROG_CPP
219 AC_PROG_INSTALL
220 AC_PROG_LN_S
221 AC_PROG_MAKE_SET
222 AC_PROG_LIBTOOL
223 AM_PROG_CC_C_O
224
225 if test "x$cross_compiling" = "xno"; then
226         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
227 else
228         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
229 fi
230
231 AC_SUBST(CC_FOR_BUILD)
232
233 AC_CHECK_TOOL(AR, ar)
234 AC_CHECK_TOOL(LD, ld)
235
236 AC_HEADER_STDC([])
237 AC_GNULIBC
238 AC_BSD_SIGNALS
239
240 dnl *************************************************************
241 dnl * Check for required libraries
242 dnl *************************************************************
243
244 AC_CHECK_FUNC([gethostbyname], ,
245               [AC_CHECK_LIB([nsl], [gethostbyname], [LIBNSL="-lnsl"])])
246 AC_SUBST(LIBNSL)
247
248 AC_CHECK_FUNC([connect], ,
249               [AC_CHECK_LIB([socket], [connect], [LIBSOCKET="-lsocket"],
250                     [AC_MSG_ERROR([Function 'socket' not found.])], [$LIBNSL])])
251
252 AC_CHECK_FUNC([getaddrinfo], ,
253               [AC_MSG_ERROR([Function 'getaddrinfo' not found.])])
254
255 AC_CHECK_FUNC([getrpcbynumber], ,
256               [AC_MSG_ERROR([Function 'getrpcbynumber' not found.])])
257
258 AC_CHECK_FUNC([getservbyname], ,
259               [AC_MSG_ERROR([Function 'getservbyname' not found.])])
260
261 AC_CHECK_LIB([crypt], [crypt], [LIBCRYPT="-lcrypt"])
262
263 if test "$enable_nfsv4" = yes; then
264   dnl check for libevent libraries and headers
265   AC_LIBEVENT
266
267   dnl check for nfsidmap libraries and headers
268   AC_LIBNFSIDMAP
269
270   dnl check for the keyutils libraries and headers
271   AC_KEYUTILS
272
273   dnl librpcsecgss already has a dependency on libgssapi,
274   dnl but we need to make sure we get the right version
275   if test "$enable_gss" = yes; then
276     AC_RPCSEC_VERSION
277   fi
278 fi
279 dnl enable nfsidmap when its support by libnfsidmap
280 AM_CONDITIONAL(CONFIG_NFSIDMAP, [test "$ac_cv_header_keyutils_h$ac_cv_lib_nfsidmap_nfs4_owner_to_uid" = "yesyes"])
281
282
283 if test "$knfsd_cv_glibc2" = no; then
284     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
285 fi
286
287 if test "$choose_blkid" != no; then 
288    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
289    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
290    AC_BLKID_VERS
291    if test $choose_blkid = yes; then
292       use_blkid=1
293       test $libblkid_cv_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
294    else
295       if test $libblkid_cv_is_recent = yes
296       then use_blkid=1
297       else use_blkid=0
298            AC_MSG_WARN([uuid support disabled as libblkid is too old])
299       fi
300     fi
301     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
302 fi
303 AC_SUBST(LIBSOCKET)
304 AC_SUBST(LIBCRYPT)
305 AC_SUBST(LIBBSD)
306 AC_SUBST(LIBBLKID)
307
308 if test "$enable_libmount" != no; then
309    AC_CHECK_LIB(mount, mnt_context_do_mount, [LIBMOUNT="-lmount"], AC_MSG_ERROR([libmount needed]))
310    AC_CHECK_HEADER(libmount/libmount.h, , AC_MSG_ERROR([Cannot find libmount header file libmount/libmount.h]))
311 fi
312 AM_CONDITIONAL(CONFIG_LIBMOUNT, [test "$enable_libmount" = "yes"])
313 AC_SUBST(LIBMOUNT)
314
315 if test "$enable_gss" = yes; then
316   dnl 'gss' requires getnameinfo - at least for gssd_proc.c
317   AC_CHECK_FUNC([getnameinfo], , [AC_MSG_ERROR([GSSAPI support requires 'getnameinfo' function])])
318
319   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
320   AC_LIBNFSIDMAP
321
322   AC_CHECK_HEADERS([spkm3.h], ,
323                    [AC_MSG_WARN([Could not locate SPKM3 header; will not have SPKM3 support])])
324
325   dnl Check for Kerberos V5
326   AC_KERBEROS_V5
327
328   dnl Invoked after AC_KERBEROS_V5; AC_LIBRPCSECGSS needs to have KRBLIBS set
329   AC_LIBRPCSECGSS
330
331 fi
332
333 dnl Check for IPv6 support
334 AC_IPV6
335
336 dnl *************************************************************
337 dnl Check for headers
338 dnl *************************************************************
339 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
340                  malloc.h memory.h netdb.h netinet/in.h paths.h \
341                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
342                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
343                  syslog.h unistd.h com_err.h et/com_err.h \
344                  ifaddrs.h])
345
346 dnl *************************************************************
347 dnl Checks for typedefs, structures, and compiler characteristics
348 dnl *************************************************************
349 AC_C_CONST
350 AC_TYPE_UID_T
351 AC_C_INLINE
352 AC_TYPE_OFF_T
353 AC_TYPE_PID_T
354 AC_TYPE_SIZE_T
355 AC_HEADER_TIME
356 AC_STRUCT_TM
357
358 dnl *************************************************************
359 dnl Check for functions
360 dnl *************************************************************
361 AC_FUNC_ALLOCA
362 AC_FUNC_CLOSEDIR_VOID
363 AC_FUNC_ERROR_AT_LINE
364 AC_FUNC_FORK
365 AC_FUNC_GETGROUPS
366 AC_FUNC_GETMNTENT
367 AC_PROG_GCC_TRADITIONAL
368 AC_FUNC_LSTAT
369 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
370 AC_HEADER_MAJOR
371 #AC_FUNC_MALLOC
372 AC_FUNC_MEMCMP
373 #AC_FUNC_REALLOC
374 AC_FUNC_SELECT_ARGTYPES
375 AC_TYPE_SIGNAL
376 AC_FUNC_STAT
377 AC_FUNC_VPRINTF
378 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
379                gethostbyaddr gethostbyname gethostname getmntent \
380                getnameinfo getrpcbyname getifaddrs \
381                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
382                realpath rmdir select socket strcasecmp strchr strdup \
383                strerror strrchr strtol strtoul sigprocmask])
384
385
386 dnl *************************************************************
387 dnl Check for data sizes
388 dnl *************************************************************
389 AC_CHECK_SIZEOF(short)
390 AC_CHECK_SIZEOF(int)
391 AC_CHECK_SIZEOF(long)
392 AC_CHECK_SIZEOF(size_t)
393 AC_CHECK_SIZEOF(socklen_t)
394
395
396 dnl *************************************************************
397 dnl Export some path names to config.h
398 dnl *************************************************************
399 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
400 AC_DEFINE_UNQUOTED(NSM_DEFAULT_STATEDIR, "$statdpath", [Define this to the pathname where statd keeps its state file])
401
402 if test "x$cross_compiling" = "xno"; then
403         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
404         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
405         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
406         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
407 else
408         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
409         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
410         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
411         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
412 fi
413
414 AC_SUBST(CFLAGS)
415 AC_SUBST(CXXFLAGS)
416 AC_SUBST(CPPFLAGS)
417 AC_SUBST(LDFLAGS)
418
419 AC_SUBST(CFLAGS_FOR_BUILD)
420 AC_SUBST(CXXFLAGS_FOR_BUILD)
421 AC_SUBST(CPPFLAGS_FOR_BUILD)
422 AC_SUBST(LDFLAGS_FOR_BUILD)
423
424 dnl *************************************************************
425 dnl Set up "global" CFLAGS
426 dnl *************************************************************
427 dnl Use architecture-specific compile flags
428 dnl (We use $host and not $build in case we are cross-compiling)
429 dnl *************************************************************
430 dnl Note: we no longer have arch specific compile flags, but 
431 dnl the stub is left here in case they are needed one day.
432 case $host in
433   *)
434     ARCHFLAGS="" ;;
435 esac
436
437 my_am_cflags="-Wall -Wextra -Wstrict-prototypes $ARCHFLAGS -pipe"
438
439 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
440
441 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
442 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
443
444 AC_CONFIG_FILES([
445         Makefile
446         linux-nfs/Makefile
447         support/Makefile
448         support/export/Makefile
449         support/include/nfs/Makefile
450         support/include/rpcsvc/Makefile
451         support/include/sys/fs/Makefile
452         support/include/sys/Makefile
453         support/include/Makefile
454         support/misc/Makefile
455         support/nfs/Makefile
456         support/nsm/Makefile
457         tools/Makefile
458         tools/locktest/Makefile
459         tools/nlmtest/Makefile
460         tools/rpcdebug/Makefile
461         tools/rpcgen/Makefile
462         tools/mountstats/Makefile
463         tools/nfs-iostat/Makefile
464         utils/Makefile
465         utils/blkmapd/Makefile
466         utils/exportfs/Makefile
467         utils/gssd/Makefile
468         utils/idmapd/Makefile
469         utils/mount/Makefile
470         utils/mountd/Makefile
471         utils/nfsd/Makefile
472         utils/nfsstat/Makefile
473         utils/nfsidmap/Makefile
474         utils/showmount/Makefile
475         utils/statd/Makefile
476         tests/Makefile
477         tests/nsm_client/Makefile])
478 AC_OUTPUT
479