Remove the rpcsec_gss code and rely on an external library instead.
[nfs-utils.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 dnl
3 AC_INIT(rules.mk)
4 AC_PREFIX_DEFAULT(/usr)
5
6 # The nfs-utils version
7 VERSION="1.0.7"
8 AC_SUBST(VERSION)
9
10 dnl *************************************************************
11 dnl * Define the set of applicable options
12 dnl *************************************************************
13 AC_ARG_WITH(release,
14         [  --with-release=XXX      set release to XXX [1]],
15         RELEASE=$withval,
16         RELEASE=1)
17         AC_SUBST(RELEASE)
18 AC_ARG_WITH(statedir,
19         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
20         statedir=$withval,
21         statedir=/var/lib/nfs)
22         AC_SUBST(statedir)
23 AC_ARG_WITH(statduser,
24         [  --with-statduser=rpcuser user for statd to run under [rpcuser or nobody]],
25         statduser=$withval,
26         if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
27                 statduser=rpcuser
28         else
29                 statduser=nobody
30         fi)
31         AC_SUBST(statduser)
32 AC_ARG_ENABLE(nfsv3,
33         [  --enable-nfsv3          enable support for NFSv3],
34         enable_nfsv3=$enableval,
35         enable_nfsv3=yes)
36         if test "$enable_nfsv3" = yes; then
37                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
38         else
39                 enable_nfsv3=
40         fi
41         AC_SUBST(enable_nfsv3)
42 AC_ARG_ENABLE(nfsv4,
43         [  --enable-nfsv4          enable support for NFSv4],
44         enable_nfsv4=$enableval,
45         enable_nfsv4=yes)
46         if test "$enable_nfsv4" = yes; then
47                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
48                 IDMAPD=idmapd
49         else
50                 enable_nfsv4=
51                 IDMAPD=
52         fi
53         AC_SUBST(IDMAPD)
54         AC_SUBST(enable_nfsv4)
55 AC_ARG_ENABLE(gss,
56         [  --enable-gss           enable support for rpcsec_gss],
57         enable_gss=$enableval,
58         enable_gss=yes)
59         if test "$enable_gss" = yes; then
60                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
61                 GSSD=gssd
62                 SVCGSSD=svcgssd
63         else
64                 enable_gss=
65                 GSSD=
66                 SVCGSSD=
67         fi
68         AC_SUBST(GSSD)
69         AC_SUBST(SVCGSSD)
70         AC_SUBST(enable_gss)
71 AC_ARG_ENABLE(kprefix,
72         [  --enable-kprefix       install progs as rpc.knfsd etc],
73         test "$enableval" = "yes" && kprefix=k,
74         kprefix=)
75         AC_SUBST(kprefix)
76 AC_ARG_ENABLE(secure-statd,
77         [  --enable-secure-statd  Only lockd can use statd (security)],
78         test "$enableval" = "yes" && secure_statd=yes,
79         secure_statd=no)
80         if test "$secure_statd" = yes; then
81                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
82         fi
83         AC_SUBST(secure_statd)
84 AC_ARG_ENABLE(rquotad,
85         [  --enable-rquotad          enable rquotad],
86         enable_rquotad=$enableval,
87         enable_rquotad=yes)
88         if test "$enable_rquotad" = yes; then
89                 RQUOTAD=rquotad
90         else
91                 RQUOTAD=
92         fi
93         AC_SUBST(RQUOTAD)
94 dnl AC_ARG_ENABLE(frob, enable frobnicator,,                enable_frob=test)
95 AC_CONFIG_HEADER(support/include/config.h)
96
97 AC_PROG_CC
98 AC_PROG_CPP
99 AC_PROG_INSTALL
100
101 test "${CC_FOR_BUILD+set}" = set || CC_FOR_BUILD="$CC"
102 AC_SUBST(CC_FOR_BUILD)
103
104 AC_CHECK_TOOL(RANLIB, ranlib, :)
105 AC_CHECK_TOOL(AR, ar)
106 AC_CHECK_TOOL(LD, ld)
107
108 AC_STDC_HEADERS
109 AC_GNULIBC
110 dnl AC_LN_SF
111 dnl AC_BSD_SIGNALS
112
113 dnl *************************************************************
114 dnl * Check for required librarues
115 dnl *************************************************************
116 AC_CHECK_LIB(socket, main, [LIBSOCKET="-lnsl"])
117 AC_CHECK_LIB(nsl, main, [LIBNSL="-lnsl"])
118 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
119 if test "$enable_nfsv4" = yes; then
120     AC_CHECK_LIB(event, event_dispatch, [libevent=1], [AC_MSG_ERROR(libevent needed for nfsv4 support)])
121     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], [AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
122     AC_CHECK_HEADERS(event.h, ,[AC_MSG_ERROR(libevent needed for nfsv4 support)])
123     AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
124 fi
125 if test "$knfsd_cv_glibc2" = no; then
126     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
127 fi
128 AC_SUBST(LIBSOCKET)
129 AC_SUBST(LIBNSL)
130 AC_SUBST(LIBCRYPT)
131 AC_SUBST(LIBBSD)
132
133 AC_TCP_WRAPPER
134 AC_SUBST(LIBWRAP)
135
136 if test "$enable_gss" = yes; then
137   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
138   AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for gss support)])
139   
140   dnl Checks for Kerberos
141   dnl NOTE: while we intend to do generic gss-api, currently we
142   dnl have a requirement to get an initial Kerberos machine
143   dnl credential.  Thus, the requirement for Kerberos.
144   dnl The Kerberos gssapi library will be dynamically loaded?
145   AC_MSG_CHECKING(for Kerberos v5)
146   AC_ARG_WITH(krb5,
147   [  --with-krb5=DIR         use Kerberos v5 installation in DIR],
148   [ case "$withval" in
149     yes|no)
150        krb5_with=""
151        ;;
152     *)
153        krb5_with="$withval"
154        ;;
155     esac ]
156   )
157
158   for dir in $krb5_with /usr /usr/kerberos /usr/local /usr/local/krb5 \
159              /usr/krb5 /usr/heimdal /usr/local/heimdal /usr/athena ; do
160     dnl This ugly hack brought on by the split installation of
161     dnl MIT Kerberos on Fedora Core 1
162     K5CONFIG=""
163     if test -f $dir/bin/krb5-config; then
164       K5CONFIG=$dir/bin/krb5-config
165     elif test -f "/usr/kerberos/bin/krb5-config"; then
166       K5CONFIG="/usr/kerberos/bin/krb5-config"
167     fi
168     if test "$K5CONFIG" != ""; then
169       KRBINC=`$K5CONFIG --cflags`
170       KRBLIB=`$K5CONFIG --libs gssapi`
171       K5VERS=`$K5CONFIG --version | head -n 1 | awk '{split($4,v,"."); if (v[[3]] == "") v[[3]] = "0"; print v[[1]]v[[2]]v[[3]] }'`
172       AC_DEFINE_UNQUOTED(KRB5_VERSION, $K5VERS, [Define this as the Kerberos version number])
173       if test -f $dir/include/gssapi/gssapi_krb5.h -a \
174               \( -f $dir/lib/libgssapi_krb5.a -o \
175             -f $dir/lib/libgssapi_krb5.so \) ; then
176          AC_DEFINE(HAVE_KRB5, 1, [Define this if you have MIT Kerberos libraries])
177          KRBDIR="$dir"
178          dnl If we are using MIT K5 1.3.1 and before, we *MUST* use the
179          dnl private function (gss_krb5_ccache_name) to get correct
180          dnl behavior of changing the ccache used by gssapi.
181          dnl Starting in 1.3.2, we *DO NOT* want to use
182          dnl gss_krb5_ccache_name, instead we want to set KRB5CCNAME
183          dnl to get gssapi to use a different ccache
184          if test $K5VERS -le 131; then
185            AC_DEFINE(USE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the private function, gss_krb5_cache_name, must be used to tell the Kerberos library which credentials cache to use. Otherwise, this is done by setting the KRB5CCNAME environment variable])
186          fi
187          gssapi_lib=gssapi_krb5
188          break
189       dnl The following ugly hack brought on by the split installation
190       dnl of Heimdal Kerberos on SuSe
191       elif test \( -f $dir/include/heim_err.h -o\
192                  -f $dir/include/heimdal/heim_err.h \) -a \
193                 -f $dir/lib/libroken.a; then
194          AC_DEFINE(HAVE_HEIMDAL, 1, [Define this if you have Heimdal Kerberos libraries])
195          KRBDIR="$dir"
196          gssapi_lib=gssapi
197         break
198       fi
199       CFLAGS=$CFLAGS `$K5CONFIG --cflags`
200     fi
201   done
202   dnl We didn't find a usable Kerberos environment
203   if test "x$KRBDIR" = "x"; then
204     if test "x$krb5_with" = "x"; then
205       AC_MSG_ERROR(Kerberos v5 with GSS support not found: consider --disable-gss or --with-krb5=)
206     else
207       AC_MSG_ERROR(Kerberos v5 with GSS support not found at $krb5_with)
208     fi
209   fi
210   CFLAGS="$CFLAGS `$K5CONFIG --cflags`"
211   AC_MSG_RESULT($KRBDIR)
212
213   dnl Now check for functions within gssapi library
214   AC_CHECK_LIB($gssapi_lib, gss_krb5_export_lucid_sec_context,
215     AC_DEFINE(HAVE_LUCID_CONTEXT_SUPPORT, 1, [Define this if the Kerberos GSS library supports gss_krb5_export_lucid_sec_context]), ,$KRBLIB)
216   AC_CHECK_LIB($gssapi_lib, gss_krb5_set_allowable_enctypes,
217     AC_DEFINE(HAVE_SET_ALLOWABLE_ENCTYPES, 1, [Define this if the Kerberos GSS library supports gss_krb5_set_allowable_enctypes]), ,$KRBLIB)
218   AC_CHECK_LIB($gssapi_lib, gss_krb5_ccache_name,
219     AC_DEFINE(HAVE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the Kerberos GSS library supports gss_krb5_ccache_name]), ,$KRBLIB)
220
221   dnl If they specified a directory and it didn't work, give them a warning
222   if test "x$krb5_with" != "x" -a "$krb5_with" != "$KRBDIR"; then
223     AC_MSG_WARN(Using $KRBDIR instead of requested value of $krb5_with for Kerberos!)
224   fi
225
226   dnl This is not done until here because we need to have KRBLIB set
227   dnl "librpcsecgss=1" is so that it doesn't get added to LIBS
228   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], [AC_MSG_ERROR(librpcsecgss needed for nfsv4 support)], $KRBLIB)
229   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
230                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, $KRBLIB)
231
232   AC_SUBST([KRBDIR])
233   AC_SUBST([KRBLIB])
234   AC_SUBST([KRBINC])
235   AC_SUBST([K5VERS])
236 fi
237
238 dnl *************************************************************
239 dnl Check for headers
240 dnl *************************************************************
241 dnl AC_HAVE_HEADERS(string.h)
242 AC_HAVE_HEADERS(com_err.h)
243 AC_HAVE_HEADERS(et/com_err.h)
244
245 dnl *************************************************************
246 dnl Check for functions
247 dnl *************************************************************
248 AC_HAVE_FUNCS(innetgr)
249
250 dnl *************************************************************
251 dnl Check for data sizes
252 dnl *************************************************************
253 AC_CHECK_SIZEOF(short)
254 AC_CHECK_SIZEOF(int)
255 AC_CHECK_SIZEOF(long)
256 AC_CHECK_SIZEOF(size_t)
257
258 dnl *************************************************************
259 dnl Export some path names to config.h
260 dnl *************************************************************
261 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
262
263 AC_SUBST(LDFLAGS)
264 AC_SUBST(CXXFLAGS)
265 AC_SUBST(CFLAGS)
266 AC_OUTPUT(config.mk utils/Makefile)