1.0.8
[nfs-utils.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 dnl
3 AC_INIT([linux nfs-utils],[1.0.8],[nfs@lists.sf.net],[nfs-utils])
4 AC_CANONICAL_BUILD([])
5 AC_CANONICAL_HOST([])
6 AC_CONFIG_SRCDIR(tools/getiversion/getiversion.c)
7 AC_CONFIG_MACRO_DIR(aclocal)
8 AM_INIT_AUTOMAKE
9 AC_PREREQ(2.59)
10 AC_PREFIX_DEFAULT(/usr)
11
12 dnl *************************************************************
13 dnl * Define the set of applicable options
14 dnl *************************************************************
15 AC_ARG_WITH(release,
16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
17         RELEASE=$withval,
18         RELEASE=1)
19         AC_SUBST(RELEASE)
20 AC_ARG_WITH(statedir,
21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
22         statedir=$withval,
23         statedir=/var/lib/nfs)
24         AC_SUBST(statedir)
25 AC_ARG_WITH(statduser,
26         [AC_HELP_STRING([--with-statduser=rpcuser],
27                         [statd to run under @<:@rpcuser or nobody@:>@]
28         )],
29         statduser=$withval,
30         if test "x$cross_compiling" = "xno"; then
31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
32                         statduser=rpcuser
33                 else
34                         statduser=nobody
35                 fi
36         else
37                 statduser=nobody
38         fi)
39         AC_SUBST(statduser)
40 AC_ARG_ENABLE(nfsv3,
41         [AC_HELP_STRING([--enable-nfsv3],
42                         [enable support for NFSv3 @<:@default=yes@:>@])],
43         enable_nfsv3=$enableval,
44         enable_nfsv3=yes)
45         if test "$enable_nfsv3" = yes; then
46                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
47         else
48                 enable_nfsv3=
49         fi
50         AC_SUBST(enable_nfsv3)
51 AC_ARG_ENABLE(nfsv4,
52         [AC_HELP_STRING([--enable-nfsv4],
53                         [enable support for NFSv4 @<:@default=yes@:>@])],
54         enable_nfsv4=$enableval,
55         enable_nfsv4=yes)
56         if test "$enable_nfsv4" = yes; then
57                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
58                 IDMAPD=idmapd
59         else
60                 enable_nfsv4=
61                 IDMAPD=
62         fi
63         AC_SUBST(IDMAPD)
64         AC_SUBST(enable_nfsv4)
65         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
66 AC_ARG_ENABLE(gss,
67         [AC_HELP_STRING([--enable-gss],
68                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
69         enable_gss=$enableval,
70         enable_gss=yes)
71         if test "$enable_gss" = yes; then
72                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
73                 GSSD=gssd
74                 SVCGSSD=svcgssd
75         else
76                 enable_gss=
77                 GSSD=
78                 SVCGSSD=
79         fi
80         AC_SUBST(GSSD)
81         AC_SUBST(SVCGSSD)
82         AC_SUBST(enable_gss)
83         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
84 AC_ARG_ENABLE(kprefix,
85         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
86         test "$enableval" = "yes" && kprefix=k,
87         kprefix=)
88         AC_SUBST(kprefix)
89 AC_ARG_ENABLE(secure-statd,
90         [AC_HELP_STRING([--enable-secure-statd],
91                         [Only lockd can use statd (security)])],
92         test "$enableval" = "yes" && secure_statd=yes,
93         secure_statd=no)
94         if test "$secure_statd" = yes; then
95                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
96         fi
97         AC_SUBST(secure_statd)
98 AC_ARG_ENABLE(rquotad,
99         [AC_HELP_STRING([--enable-rquotad],
100                         [enable rquotad @<:@default=yes@:>@])],
101         enable_rquotad=$enableval,
102         enable_rquotad=yes)
103         if test "$enable_rquotad" = yes; then
104                 RQUOTAD=rquotad
105         else
106                 RQUOTAD=
107         fi
108         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
109
110 # Check whether user wants TCP wrappers support
111 AC_TCP_WRAPPERS
112
113 AC_CONFIG_SRCDIR([support/include/config.h.in])
114 AC_CONFIG_HEADERS([support/include/config.h])
115
116 # Checks for programs.
117 AC_PROG_CXX
118 AC_PROG_CC
119 AC_PROG_CPP
120 AC_PROG_INSTALL
121 AC_PROG_LN_S
122 AC_PROG_MAKE_SET
123 AC_PROG_LIBTOOL
124
125 if test "x$cross_compiling" = "xno"; then
126         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
127 else
128         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
129 fi
130
131 AC_SUBST(CC_FOR_BUILD)
132
133 AC_CHECK_TOOL(AR, ar)
134 AC_CHECK_TOOL(LD, ld)
135
136 AC_HEADER_STDC([])
137 AC_GNULIBC
138 AC_BSD_SIGNALS
139
140 dnl *************************************************************
141 dnl * Check for required libraries
142 dnl *************************************************************
143 AC_CHECK_LIB(socket, main, [LIBSOCKET="-lnsl"])
144 AC_CHECK_LIB(nsl, main, [LIBNSL="-lnsl"])
145 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
146 if test "$enable_nfsv4" = yes; then
147     AC_CHECK_LIB(event, event_dispatch, [libevent=1], [AC_MSG_ERROR(libevent needed for nfsv4 support)])
148     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], [AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
149     AC_CHECK_HEADERS(event.h, ,[AC_MSG_ERROR(libevent needed for nfsv4 support)])
150     AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
151     dnl librpcsecgss already has a dependency on libgssapi,
152     dnl but we need to make sure we get the right version
153     if test "$enable_gss" = yes; then
154      PKG_CHECK_MODULES([RPCSECGSS], [librpcsecgss >= 0.10], [],
155       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.
156        If you have pkgconfig installed, you might try setting environment
157        variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
158       ]
159      )
160     PKG_CHECK_MODULES([GSSAPI], [libgssapi >= 0.9])
161     fi
162
163 fi
164 if test "$knfsd_cv_glibc2" = no; then
165     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
166 fi
167 AC_SUBST(LIBSOCKET)
168 AC_SUBST(LIBNSL)
169 AC_SUBST(LIBCRYPT)
170 AC_SUBST(LIBBSD)
171
172 if test "$enable_gss" = yes; then
173   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
174   AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for gss support)])
175   AC_CHECK_HEADERS(spkm3.h, ,[AC_MSG_WARN(could not locate SPKM3 header; will not have SPKM3 support)])
176
177   dnl Check for Kerberos V5
178   AC_KERBEROS_V5
179
180   dnl This is not done until here because we need to have KRBLIBS set
181   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
182   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], [AC_MSG_ERROR(librpcsecgss needed for nfsv4 support)], $KRBLIBS)
183   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
184                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, $KRBLIBS)
185
186 fi
187
188 dnl *************************************************************
189 dnl Check for headers
190 dnl *************************************************************
191 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
192                  malloc.h memory.h netdb.h netinet/in.h paths.h \
193                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
194                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
195                  syslog.h unistd.h com_err.h et/com_err.h])
196
197 dnl *************************************************************
198 dnl Checks for typedefs, structures, and compiler characteristics
199 dnl *************************************************************
200 AC_C_CONST
201 AC_TYPE_UID_T
202 AC_C_INLINE
203 AC_TYPE_OFF_T
204 AC_TYPE_PID_T
205 AC_TYPE_SIZE_T
206 AC_HEADER_TIME
207 AC_STRUCT_TM
208
209 dnl *************************************************************
210 dnl Check for functions
211 dnl *************************************************************
212 AC_FUNC_ALLOCA
213 AC_FUNC_CLOSEDIR_VOID
214 AC_FUNC_ERROR_AT_LINE
215 AC_FUNC_FORK
216 AC_FUNC_GETGROUPS
217 AC_FUNC_GETMNTENT
218 AC_PROG_GCC_TRADITIONAL
219 AC_FUNC_LSTAT
220 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
221 AC_HEADER_MAJOR
222 #AC_FUNC_MALLOC
223 AC_FUNC_MEMCMP
224 #AC_FUNC_REALLOC
225 AC_FUNC_SELECT_ARGTYPES
226 AC_TYPE_SIGNAL
227 AC_FUNC_STAT
228 AC_FUNC_VPRINTF
229 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
230                gethostbyaddr gethostbyname gethostname getmntent \
231                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
232                realpath rmdir select socket strcasecmp strchr strdup \
233                strerror strrchr strtol strtoul])
234
235
236 dnl *************************************************************
237 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
238 dnl *************************************************************
239 AC_CHECK_SIZEOF(short)
240 AC_CHECK_SIZEOF(int)
241 AC_CHECK_SIZEOF(long)
242 AC_CHECK_SIZEOF(size_t)
243
244 dnl *************************************************************
245 dnl Export some path names to config.h
246 dnl *************************************************************
247 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
248
249 if test "x$cross_compiling" = "xno"; then
250         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
251         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
252         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
253         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
254 else
255         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
256         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
257         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
258         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
259 fi
260
261 AC_SUBST(CFLAGS)
262 AC_SUBST(CXXFLAGS)
263 AC_SUBST(CPPFLAGS)
264 AC_SUBST(LDFLAGS)
265
266 AC_SUBST(CFLAGS_FOR_BUILD)
267 AC_SUBST(CXXFLAGS_FOR_BUILD)
268 AC_SUBST(CPPFLAGS_FOR_BUILD)
269 AC_SUBST(LDFLAGS_FOR_BUILD)
270
271 dnl *************************************************************
272 dnl Set up "global" CFLAGS
273 dnl *************************************************************
274 dnl Use architecture-specific compile flags
275 dnl (We use $host and not $build in case we are cross-compiling)
276 dnl *************************************************************
277 case $host in
278   alpha*)
279     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
280   *)
281     ARCHFLAGS="" ;;
282 esac
283
284 my_am_cflags="-Wall $ARCHFLAGS -pipe"
285
286 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include -D_FILE_OFFSET_BITS=64"])
287 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
288
289 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
290 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
291
292 AC_CONFIG_FILES([
293         Makefile
294         linux-nfs/Makefile
295         support/Makefile
296         support/export/Makefile
297         support/include/nfs/Makefile
298         support/include/rpcsvc/Makefile
299         support/include/sys/fs/Makefile
300         support/include/sys/Makefile
301         support/include/Makefile
302         support/misc/Makefile
303         support/nfs/Makefile
304         tools/Makefile
305         tools/getiversion/Makefile
306         tools/getkversion/Makefile
307         tools/locktest/Makefile
308         tools/nlmtest/Makefile
309         tools/rpcdebug/Makefile
310         tools/rpcgen/Makefile
311         utils/Makefile
312         utils/exportfs/Makefile
313         utils/gssd/Makefile
314         utils/idmapd/Makefile
315         utils/lockd/Makefile
316         utils/mountd/Makefile
317         utils/nfsd/Makefile
318         utils/nfsstat/Makefile
319         utils/nhfsstone/Makefile
320         utils/rquotad/Makefile
321         utils/showmount/Makefile
322         utils/statd/Makefile])
323 AC_OUTPUT
324