configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.0.11],[nfs@lists.sf.net],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_MACRO_DIR(aclocal)
   7 AM_INIT_AUTOMAKE
   8 AC_PREREQ(2.59)
   9 AC_PREFIX_DEFAULT(/usr)
  10 AM_MAINTAINER_MODE
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_WITH(start-statd,
  41         [AC_HELP_STRING([--with-start-statd=scriptname],
  42                         [When an nfs filesystems is mounted with locking, run this script]
  43         )],
  44         startstatd=$withval,
  45         startstatd=/usr/sbin/start-statd
  46         )
  47         AC_SUBST(startstatd)
  48         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  49 AC_ARG_ENABLE(nfsv3,
  50         [AC_HELP_STRING([--enable-nfsv3],
  51                         [enable support for NFSv3 @<:@default=yes@:>@])],
  52         enable_nfsv3=$enableval,
  53         enable_nfsv3=yes)
  54         if test "$enable_nfsv3" = yes; then
  55                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  56         else
  57                 enable_nfsv3=
  58         fi
  59         AC_SUBST(enable_nfsv3)
  60 AC_ARG_ENABLE(nfsv4,
  61         [AC_HELP_STRING([--enable-nfsv4],
  62                         [enable support for NFSv4 @<:@default=yes@:>@])],
  63         enable_nfsv4=$enableval,
  64         enable_nfsv4=yes)
  65         if test "$enable_nfsv4" = yes; then
  66                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  67                 IDMAPD=idmapd
  68         else
  69                 enable_nfsv4=
  70                 IDMAPD=
  71         fi
  72         AC_SUBST(IDMAPD)
  73         AC_SUBST(enable_nfsv4)
  74         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  75 AC_ARG_ENABLE(gss,
  76         [AC_HELP_STRING([--enable-gss],
  77                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  78         enable_gss=$enableval,
  79         enable_gss=yes)
  80         if test "$enable_gss" = yes; then
  81                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  82                 GSSD=gssd
  83                 SVCGSSD=svcgssd
  84         else
  85                 enable_gss=
  86                 GSSD=
  87                 SVCGSSD=
  88         fi
  89         AC_SUBST(GSSD)
  90         AC_SUBST(SVCGSSD)
  91         AC_SUBST(enable_gss)
  92         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  93 AC_ARG_ENABLE(kprefix,
  94         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  95         test "$enableval" = "yes" && kprefix=k,
  96         kprefix=)
  97         AC_SUBST(kprefix)
  98 AC_ARG_ENABLE(secure-statd,
  99         [AC_HELP_STRING([--enable-secure-statd],
 100                         [Only lockd can use statd (security)])],
 101         test "$enableval" = "yes" && secure_statd=yes,
 102         secure_statd=yes)
 103         if test "$secure_statd" = yes; then
 104                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
 105         fi
 106         AC_SUBST(secure_statd)
 107 AC_ARG_ENABLE(rquotad,
 108         [AC_HELP_STRING([--enable-rquotad],
 109                         [enable rquotad @<:@default=yes@:>@])],
 110         enable_rquotad=$enableval,
 111         enable_rquotad=yes)
 112         if test "$enable_rquotad" = yes; then
 113                 RQUOTAD=rquotad
 114         else
 115                 RQUOTAD=
 116         fi
 117         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
 118 AC_ARG_WITH(rpcgen,
 119         [AC_HELP_STRING([--with-rpcgen=/usr/bin/rpcgen], [use system rpcgen instead of compiling our own])],
 120         if test "$withval" == "yes"; then
 121             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
 122             do if test -f $p ; then withval=$p ; break; fi ; done
 123         fi
 124         RPCGEN_PATH=$withval,
 125         RPCGEN_PATH= )
 126         AC_SUBST(RPCGEN_PATH)
 127         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" == ""])
 128 AC_ARG_ENABLE(uuid,
 129         [AC_HELP_STRING([--without-uuid], [Exclude uuid support and so avoid possibly buggy libblkid])],
 130         if test "$enableval" = "yes" ; then use_blkid=1; else use_blkid=0; fi,
 131         use_blkid=1)
 132         AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
 133 AC_ARG_ENABLE(mount,
 134         [AC_HELP_STRING([--enable-mount],
 135                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=no@:>@])],
 136         enable_mount=$enableval,
 137         enable_mount=yes)
 138         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 139
 140 # Check whether user wants TCP wrappers support
 141 AC_TCP_WRAPPERS
 142
 143 # Arrange for large-file support
 144 AC_SYS_LARGEFILE
 145
 146 AC_CONFIG_SRCDIR([support/include/config.h.in])
 147 AC_CONFIG_HEADERS([support/include/config.h])
 148
 149 # Checks for programs.
 150 AC_PROG_CXX
 151 AC_PROG_CC
 152 AC_PROG_CPP
 153 AC_PROG_INSTALL
 154 AC_PROG_LN_S
 155 AC_PROG_MAKE_SET
 156 AC_PROG_LIBTOOL
 157 AM_PROG_CC_C_O
 158
 159 if test "x$cross_compiling" = "xno"; then
 160         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 161 else
 162         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 163 fi
 164
 165 AC_SUBST(CC_FOR_BUILD)
 166
 167 AC_CHECK_TOOL(AR, ar)
 168 AC_CHECK_TOOL(LD, ld)
 169
 170 AC_HEADER_STDC([])
 171 AC_GNULIBC
 172 AC_BSD_SIGNALS
 173
 174 dnl *************************************************************
 175 dnl * Check for required libraries
 176 dnl *************************************************************
 177 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(nsl, gethostbyname, [LIBNSL="-lnsl"])])
 178 AC_SUBST(LIBNSL)
 179
 180 AC_CHECK_FUNC(connect, ,
 181       AC_CHECK_LIB(socket, connect, [LIBSOCKET="-lsocket"],
 182                 AC_MSG_ERROR(Function 'socket' not found.), $LIBNSL))
 183
 184 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 185 if test "$enable_nfsv4" = yes; then
 186     AC_CHECK_LIB(event, event_dispatch, [libevent=1], AC_MSG_ERROR([libevent needed for nfsv4 support]))
 187     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 188     AC_CHECK_HEADERS(event.h, ,AC_MSG_ERROR([libevent needed for nfsv4 support]))
 189     AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 190     dnl librpcsecgss already has a dependency on libgssapi,
 191     dnl but we need to make sure we get the right version
 192     if test "$enable_gss" = yes; then
 193      PKG_CHECK_MODULES(RPCSECGSS, librpcsecgss >= 0.10, ,
 194       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.  If you have pkgconfig installed, you might try setting environment variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
 195       ]
 196      )
 197     PKG_CHECK_MODULES(GSSAPI, libgssapi >= 0.9)
 198     fi
 199
 200 fi
 201 if test "$knfsd_cv_glibc2" = no; then
 202     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 203 fi
 204 if test "$use_blkid" = 1; then
 205    AC_CHECK_LIB(blkid, blkid_get_cache, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 206    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot file libblkid header file blkid/blkid.h]))
 207 fi
 208 AC_SUBST(LIBSOCKET)
 209 AC_SUBST(LIBCRYPT)
 210 AC_SUBST(LIBBSD)
 211 AC_SUBST(LIBBLKID)
 212
 213 if test "$enable_gss" = yes; then
 214   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 215   AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for gss support]))
 216   AC_CHECK_HEADERS(spkm3.h, ,AC_MSG_WARN([could not locate SPKM3 header; will not have SPKM3 support]))
 217   dnl the nfs4_set_debug function doesn't appear in all version of the library
 218   AC_CHECK_LIB(nfsidmap, nfs4_set_debug,
 219                AC_DEFINE(HAVE_NFS4_SET_DEBUG,1,
 220                          [Whether nfs4_set_debug() is present in libnfsidmap]),)
 221
 222   dnl Check for Kerberos V5
 223   AC_KERBEROS_V5
 224
 225   dnl This is not done until here because we need to have KRBLIBS set
 226   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
 227   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], AC_MSG_ERROR([librpcsecgss needed for nfsv4 support]), -lgssapi -ldl)
 228   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 229                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, -lgssapi -ldl)
 230
 231 fi
 232
 233 dnl *************************************************************
 234 dnl Check for headers
 235 dnl *************************************************************
 236 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 237                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 238                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 239                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 240                  syslog.h unistd.h com_err.h et/com_err.h \
 241                  ifaddrs.h])
 242
 243 dnl *************************************************************
 244 dnl Checks for typedefs, structures, and compiler characteristics
 245 dnl *************************************************************
 246 AC_C_CONST
 247 AC_TYPE_UID_T
 248 AC_C_INLINE
 249 AC_TYPE_OFF_T
 250 AC_TYPE_PID_T
 251 AC_TYPE_SIZE_T
 252 AC_HEADER_TIME
 253 AC_STRUCT_TM
 254
 255 dnl *************************************************************
 256 dnl Check for functions
 257 dnl *************************************************************
 258 AC_FUNC_ALLOCA
 259 AC_FUNC_CLOSEDIR_VOID
 260 AC_FUNC_ERROR_AT_LINE
 261 AC_FUNC_FORK
 262 AC_FUNC_GETGROUPS
 263 AC_FUNC_GETMNTENT
 264 AC_PROG_GCC_TRADITIONAL
 265 AC_FUNC_LSTAT
 266 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 267 AC_HEADER_MAJOR
 268 #AC_FUNC_MALLOC
 269 AC_FUNC_MEMCMP
 270 #AC_FUNC_REALLOC
 271 AC_FUNC_SELECT_ARGTYPES
 272 AC_TYPE_SIGNAL
 273 AC_FUNC_STAT
 274 AC_FUNC_VPRINTF
 275 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 276                gethostbyaddr gethostbyname gethostname getmntent \
 277                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 278                realpath rmdir select socket strcasecmp strchr strdup \
 279                strerror strrchr strtol strtoul sigprocmask])
 280
 281
 282 dnl *************************************************************
 283 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
 284 dnl *************************************************************
 285 AC_CHECK_SIZEOF(short)
 286 AC_CHECK_SIZEOF(int)
 287 AC_CHECK_SIZEOF(long)
 288 AC_CHECK_SIZEOF(size_t)
 289 AC_CHECK_SIZEOF(socklen_t)
 290
 291
 292 dnl *************************************************************
 293 dnl Export some path names to config.h
 294 dnl *************************************************************
 295 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 296
 297 if test "x$cross_compiling" = "xno"; then
 298         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 299         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 300         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 301         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 302 else
 303         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 304         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 305         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 306         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 307 fi
 308
 309 AC_SUBST(CFLAGS)
 310 AC_SUBST(CXXFLAGS)
 311 AC_SUBST(CPPFLAGS)
 312 AC_SUBST(LDFLAGS)
 313
 314 AC_SUBST(CFLAGS_FOR_BUILD)
 315 AC_SUBST(CXXFLAGS_FOR_BUILD)
 316 AC_SUBST(CPPFLAGS_FOR_BUILD)
 317 AC_SUBST(LDFLAGS_FOR_BUILD)
 318
 319 dnl *************************************************************
 320 dnl Set up "global" CFLAGS
 321 dnl *************************************************************
 322 dnl Use architecture-specific compile flags
 323 dnl (We use $host and not $build in case we are cross-compiling)
 324 dnl *************************************************************
 325 case $host in
 326   alpha*)
 327     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
 328   *)
 329     ARCHFLAGS="" ;;
 330 esac
 331
 332 my_am_cflags="-Wall $ARCHFLAGS -pipe"
 333
 334 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include"])
 335 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 336
 337 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 338 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 339
 340 AC_CONFIG_FILES([
 341         Makefile
 342         linux-nfs/Makefile
 343         support/Makefile
 344         support/export/Makefile
 345         support/include/nfs/Makefile
 346         support/include/rpcsvc/Makefile
 347         support/include/sys/fs/Makefile
 348         support/include/sys/Makefile
 349         support/include/Makefile
 350         support/misc/Makefile
 351         support/nfs/Makefile
 352         tools/Makefile
 353         tools/locktest/Makefile
 354         tools/nlmtest/Makefile
 355         tools/rpcdebug/Makefile
 356         tools/rpcgen/Makefile
 357         utils/Makefile
 358         utils/exportfs/Makefile
 359         utils/gssd/Makefile
 360         utils/idmapd/Makefile
 361         utils/mount/Makefile
 362         utils/mountd/Makefile
 363         utils/nfsd/Makefile
 364         utils/nfsstat/Makefile
 365         utils/rquotad/Makefile
 366         utils/showmount/Makefile
 367         utils/statd/Makefile])
 368 AC_OUTPUT
 369