tcp_wrappers: Use getifaddrs(3) if it is available
[nfs-utils.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 dnl
3 AC_INIT([linux nfs-utils],[1.2.1],[linux-nfs@vger.kernel.org],[nfs-utils])
4 AC_CANONICAL_BUILD([])
5 AC_CANONICAL_HOST([])
6 AC_CONFIG_MACRO_DIR(aclocal)
7 AM_INIT_AUTOMAKE
8 AC_PREREQ(2.59)
9 AC_PREFIX_DEFAULT(/usr)
10 AM_MAINTAINER_MODE
11
12 dnl *************************************************************
13 dnl * Define the set of applicable options
14 dnl *************************************************************
15 AC_ARG_WITH(release,
16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
17         RELEASE=$withval,
18         RELEASE=1)
19         AC_SUBST(RELEASE)
20 AC_ARG_WITH(statedir,
21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
22         statedir=$withval,
23         statedir=/var/lib/nfs)
24         AC_SUBST(statedir)
25 AC_ARG_WITH(statduser,
26         [AC_HELP_STRING([--with-statduser=rpcuser],
27                         [statd to run under @<:@rpcuser or nobody@:>@]
28         )],
29         statduser=$withval,
30         if test "x$cross_compiling" = "xno"; then
31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
32                         statduser=rpcuser
33                 else
34                         statduser=nobody
35                 fi
36         else
37                 statduser=nobody
38         fi)
39         AC_SUBST(statduser)
40 AC_ARG_WITH(start-statd,
41         [AC_HELP_STRING([--with-start-statd=scriptname],
42                         [When an nfs filesystems is mounted with locking, run this script]
43         )],
44         startstatd=$withval,
45         startstatd=/usr/sbin/start-statd
46         )
47         AC_SUBST(startstatd)
48         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
49 AC_ARG_ENABLE(nfsv3,
50         [AC_HELP_STRING([--enable-nfsv3],
51                         [enable support for NFSv3 @<:@default=yes@:>@])],
52         enable_nfsv3=$enableval,
53         enable_nfsv3=yes)
54         if test "$enable_nfsv3" = yes; then
55                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
56         else
57                 enable_nfsv3=
58         fi
59         AC_SUBST(enable_nfsv3)
60 AC_ARG_ENABLE(nfsv4,
61         [AC_HELP_STRING([--enable-nfsv4],
62                         [enable support for NFSv4 @<:@default=yes@:>@])],
63         enable_nfsv4=$enableval,
64         enable_nfsv4=yes)
65         if test "$enable_nfsv4" = yes; then
66                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
67                 IDMAPD=idmapd
68         else
69                 enable_nfsv4=
70                 IDMAPD=
71         fi
72         AC_SUBST(IDMAPD)
73         AC_SUBST(enable_nfsv4)
74         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
75 AC_ARG_ENABLE(gss,
76         [AC_HELP_STRING([--enable-gss],
77                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
78         enable_gss=$enableval,
79         enable_gss=yes)
80         if test "$enable_gss" = yes; then
81                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
82                 GSSD=gssd
83                 SVCGSSD=svcgssd
84         else
85                 enable_gss=
86                 GSSD=
87                 SVCGSSD=
88         fi
89         AC_SUBST(GSSD)
90         AC_SUBST(SVCGSSD)
91         AC_SUBST(enable_gss)
92         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
93 AC_ARG_ENABLE(kprefix,
94         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
95         test "$enableval" = "yes" && kprefix=k,
96         kprefix=)
97         AC_SUBST(kprefix)
98 AC_ARG_WITH(rpcgen,
99         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
100         rpcgen_path=$withval,
101         rpcgen_path=yes )
102         RPCGEN_PATH=
103         if test "$rpcgen_path" == "yes"; then
104             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
105             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
106         elif test "$rpcgen_path" != "internal"; then
107             RPCGEN_PATH=$rpcgen_path
108         fi
109         AC_SUBST(RPCGEN_PATH)
110         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" == ""])
111 AC_ARG_ENABLE(uuid,
112         [AC_HELP_STRING([--disable-uuid], [Exclude uuid support to avoid buggy libblkid])],
113         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
114         choose_blkid=default)
115 AC_ARG_ENABLE(mount,
116         [AC_HELP_STRING([--enable-mount],
117                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
118         enable_mount=$enableval,
119         enable_mount=yes)
120         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
121 AC_ARG_ENABLE(tirpc,
122         [AC_HELP_STRING([--enable-tirpc],
123                         [enable use of TI-RPC @<:@default=yes@:>@])],
124         enable_tirpc=$enableval,
125         enable_tirpc='yes')
126 AC_ARG_ENABLE(ipv6,
127         [AC_HELP_STRING([--enable-ipv6],
128                         [enable support for IPv6 @<:@default=no@:>@])],
129         enable_ipv6=$enableval,
130         enable_ipv6=no)
131         if test "$enable_ipv6" = yes; then
132                 AC_DEFINE(IPV6_SUPPORTED, 1, [Define this if you want IPv6 support compiled in])
133         else
134                 enable_ipv6=
135         fi
136         AC_SUBST(enable_ipv6)
137         AM_CONDITIONAL(CONFIG_IPV6, [test "$enable_ipv6" = "yes"])
138
139 if test "$enable_mount" = yes; then
140         AC_ARG_ENABLE(mountconfig,
141         [AC_HELP_STRING([--enable-mountconfig],
142                         [enable mount to use a configuration file])],
143         mountconfig=$enableval,
144         mountconfig=no)
145         if test "$enable_mountconfig" = yes; then
146                 AC_DEFINE(MOUNT_CONFIG, 1, 
147                         [Define this if you want mount to read a configuration file])
148                 AC_ARG_WITH(mountfile,
149                         [AC_HELP_STRING([--with-mountfile=filename],
150                         [Using filename as the NFS mount options file [/etc/nfsmounts.conf]]
151                         )],
152                 mountfile=$withval,
153                 mountfile=/etc/nfsmount.conf)
154                 AC_SUBST(mountfile)
155                 AC_DEFINE_UNQUOTED(MOUNTOPTS_CONFFILE, "$mountfile", 
156                         [This defines the location of the NFS mount configuration file])
157         else
158                 enable_mountconfig=
159         fi
160         AC_SUBST(enable_mountconfig)
161         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mountconfig" = "yes"])
162 else
163         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mount" = "yes"])
164 fi
165
166 dnl Check for TI-RPC library and headers
167 AC_LIBTIRPC
168
169 dnl Check for -lcap
170 AC_LIBCAP
171
172 # Check whether user wants TCP wrappers support
173 AC_TCP_WRAPPERS
174
175 # Arrange for large-file support
176 AC_SYS_LARGEFILE
177
178 AC_CONFIG_SRCDIR([support/include/config.h.in])
179 AC_CONFIG_HEADERS([support/include/config.h])
180
181 # Checks for programs.
182 AC_PROG_CXX
183 AC_PROG_CC
184 AC_PROG_CPP
185 AC_PROG_INSTALL
186 AC_PROG_LN_S
187 AC_PROG_MAKE_SET
188 AC_PROG_LIBTOOL
189 AM_PROG_CC_C_O
190
191 if test "x$cross_compiling" = "xno"; then
192         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
193 else
194         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
195 fi
196
197 AC_SUBST(CC_FOR_BUILD)
198
199 AC_CHECK_TOOL(AR, ar)
200 AC_CHECK_TOOL(LD, ld)
201
202 AC_HEADER_STDC([])
203 AC_GNULIBC
204 AC_BSD_SIGNALS
205
206 dnl *************************************************************
207 dnl * Check for required libraries
208 dnl *************************************************************
209
210 AC_CHECK_FUNC([gethostbyname], ,
211               [AC_CHECK_LIB([nsl], [gethostbyname], [LIBNSL="-lnsl"])])
212 AC_SUBST(LIBNSL)
213
214 AC_CHECK_FUNC([connect], ,
215               [AC_CHECK_LIB([socket], [connect], [LIBSOCKET="-lsocket"],
216                     [AC_MSG_ERROR([Function 'socket' not found.])], [$LIBNSL])])
217
218 AC_CHECK_FUNC([getaddrinfo], ,
219               [AC_MSG_ERROR([Function 'getaddrinfo' not found.])])
220
221 AC_CHECK_FUNC([getrpcbynumber], ,
222               [AC_MSG_ERROR([Function 'getrpcbynumber' not found.])])
223
224 AC_CHECK_FUNC([getservbyname], ,
225               [AC_MSG_ERROR([Function 'getservbyname' not found.])])
226
227 AC_CHECK_LIB([crypt], [crypt], [LIBCRYPT="-lcrypt"])
228
229 if test "$enable_nfsv4" = yes; then
230   dnl check for libevent libraries and headers
231   AC_LIBEVENT
232
233   dnl check for nfsidmap libraries and headers
234   AC_LIBNFSIDMAP
235
236   dnl librpcsecgss already has a dependency on libgssapi,
237   dnl but we need to make sure we get the right version
238   if test "$enable_gss" = yes; then
239     AC_RPCSEC_VERSION
240   fi
241 fi
242
243 if test "$knfsd_cv_glibc2" = no; then
244     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
245 fi
246
247 if test "$choose_blkid" != no; then 
248    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
249    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
250    AC_BLKID_VERS
251    if test $choose_blkid = yes; then
252       use_blkid=1
253       test $libblkid_cv_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
254    else
255       if test $libblkid_cv_is_recent = yes
256       then use_blkid=1
257       else use_blkid=0
258            AC_MSG_WARN([uuid support disabled as libblkid is too old])
259       fi
260     fi
261     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
262 fi
263 AC_SUBST(LIBSOCKET)
264 AC_SUBST(LIBCRYPT)
265 AC_SUBST(LIBBSD)
266 AC_SUBST(LIBBLKID)
267
268 if test "$enable_gss" = yes; then
269   dnl 'gss' requires getnameinfo - at least for gssd_proc.c
270   AC_CHECK_FUNC([getnameinfo], , [AC_MSG_ERROR([GSSAPI support requires 'getnameinfo' function])])
271
272   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
273   AC_LIBNFSIDMAP
274
275   AC_CHECK_HEADERS([spkm3.h], ,
276                    [AC_MSG_WARN([Could not locate SPKM3 header; will not have SPKM3 support])])
277
278   dnl Check for Kerberos V5
279   AC_KERBEROS_V5
280
281   dnl Invoked after AC_KERBEROS_V5; AC_LIBRPCSECGSS needs to have KRBLIBS set
282   AC_LIBRPCSECGSS
283
284 fi
285
286 dnl Check for IPv6 support
287 AC_IPV6
288
289 dnl *************************************************************
290 dnl Check for headers
291 dnl *************************************************************
292 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
293                  malloc.h memory.h netdb.h netinet/in.h paths.h \
294                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
295                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
296                  syslog.h unistd.h com_err.h et/com_err.h \
297                  ifaddrs.h])
298
299 dnl *************************************************************
300 dnl Checks for typedefs, structures, and compiler characteristics
301 dnl *************************************************************
302 AC_C_CONST
303 AC_TYPE_UID_T
304 AC_C_INLINE
305 AC_TYPE_OFF_T
306 AC_TYPE_PID_T
307 AC_TYPE_SIZE_T
308 AC_HEADER_TIME
309 AC_STRUCT_TM
310
311 dnl *************************************************************
312 dnl Check for functions
313 dnl *************************************************************
314 AC_FUNC_ALLOCA
315 AC_FUNC_CLOSEDIR_VOID
316 AC_FUNC_ERROR_AT_LINE
317 AC_FUNC_FORK
318 AC_FUNC_GETGROUPS
319 AC_FUNC_GETMNTENT
320 AC_PROG_GCC_TRADITIONAL
321 AC_FUNC_LSTAT
322 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
323 AC_HEADER_MAJOR
324 #AC_FUNC_MALLOC
325 AC_FUNC_MEMCMP
326 #AC_FUNC_REALLOC
327 AC_FUNC_SELECT_ARGTYPES
328 AC_TYPE_SIGNAL
329 AC_FUNC_STAT
330 AC_FUNC_VPRINTF
331 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
332                gethostbyaddr gethostbyname gethostname getmntent \
333                getnameinfo getrpcbyname getifaddrs \
334                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
335                realpath rmdir select socket strcasecmp strchr strdup \
336                strerror strrchr strtol strtoul sigprocmask])
337
338
339 dnl *************************************************************
340 dnl Check for data sizes
341 dnl *************************************************************
342 AC_CHECK_SIZEOF(short)
343 AC_CHECK_SIZEOF(int)
344 AC_CHECK_SIZEOF(long)
345 AC_CHECK_SIZEOF(size_t)
346 AC_CHECK_SIZEOF(socklen_t)
347
348
349 dnl *************************************************************
350 dnl Export some path names to config.h
351 dnl *************************************************************
352 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
353
354 if test "x$cross_compiling" = "xno"; then
355         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
356         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
357         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
358         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
359 else
360         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
361         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
362         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
363         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
364 fi
365
366 AC_SUBST(CFLAGS)
367 AC_SUBST(CXXFLAGS)
368 AC_SUBST(CPPFLAGS)
369 AC_SUBST(LDFLAGS)
370
371 AC_SUBST(CFLAGS_FOR_BUILD)
372 AC_SUBST(CXXFLAGS_FOR_BUILD)
373 AC_SUBST(CPPFLAGS_FOR_BUILD)
374 AC_SUBST(LDFLAGS_FOR_BUILD)
375
376 dnl *************************************************************
377 dnl Set up "global" CFLAGS
378 dnl *************************************************************
379 dnl Use architecture-specific compile flags
380 dnl (We use $host and not $build in case we are cross-compiling)
381 dnl *************************************************************
382 dnl Note: we no longer have arch specific compile flags, but 
383 dnl the stub is left here in case they are needed one day.
384 case $host in
385   *)
386     ARCHFLAGS="" ;;
387 esac
388
389 my_am_cflags="-Wall -Wstrict-prototypes $ARCHFLAGS -pipe"
390
391 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
392
393 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
394 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
395
396 AC_CONFIG_FILES([
397         Makefile
398         linux-nfs/Makefile
399         support/Makefile
400         support/export/Makefile
401         support/include/nfs/Makefile
402         support/include/rpcsvc/Makefile
403         support/include/sys/fs/Makefile
404         support/include/sys/Makefile
405         support/include/Makefile
406         support/misc/Makefile
407         support/nfs/Makefile
408         support/nsm/Makefile
409         tools/Makefile
410         tools/locktest/Makefile
411         tools/nlmtest/Makefile
412         tools/rpcdebug/Makefile
413         tools/rpcgen/Makefile
414         utils/Makefile
415         utils/exportfs/Makefile
416         utils/gssd/Makefile
417         utils/idmapd/Makefile
418         utils/mount/Makefile
419         utils/mountd/Makefile
420         utils/nfsd/Makefile
421         utils/nfsstat/Makefile
422         utils/showmount/Makefile
423         utils/statd/Makefile
424         tests/Makefile
425         tests/nsm_client/Makefile])
426 AC_OUTPUT
427