configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.1.1],[linux-nfs@vger.kernel.org],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_MACRO_DIR(aclocal)
   7 AM_INIT_AUTOMAKE
   8 AC_PREREQ(2.59)
   9 AC_PREFIX_DEFAULT(/usr)
  10 AM_MAINTAINER_MODE
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_WITH(start-statd,
  41         [AC_HELP_STRING([--with-start-statd=scriptname],
  42                         [When an nfs filesystems is mounted with locking, run this script]
  43         )],
  44         startstatd=$withval,
  45         startstatd=/usr/sbin/start-statd
  46         )
  47         AC_SUBST(startstatd)
  48         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  49 AC_ARG_ENABLE(nfsv3,
  50         [AC_HELP_STRING([--enable-nfsv3],
  51                         [enable support for NFSv3 @<:@default=yes@:>@])],
  52         enable_nfsv3=$enableval,
  53         enable_nfsv3=yes)
  54         if test "$enable_nfsv3" = yes; then
  55                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  56         else
  57                 enable_nfsv3=
  58         fi
  59         AC_SUBST(enable_nfsv3)
  60 AC_ARG_ENABLE(nfsv4,
  61         [AC_HELP_STRING([--enable-nfsv4],
  62                         [enable support for NFSv4 @<:@default=yes@:>@])],
  63         enable_nfsv4=$enableval,
  64         enable_nfsv4=yes)
  65         if test "$enable_nfsv4" = yes; then
  66                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  67                 IDMAPD=idmapd
  68         else
  69                 enable_nfsv4=
  70                 IDMAPD=
  71         fi
  72         AC_SUBST(IDMAPD)
  73         AC_SUBST(enable_nfsv4)
  74         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  75 AC_ARG_ENABLE(gss,
  76         [AC_HELP_STRING([--enable-gss],
  77                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  78         enable_gss=$enableval,
  79         enable_gss=yes)
  80         if test "$enable_gss" = yes; then
  81                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  82                 GSSD=gssd
  83                 SVCGSSD=svcgssd
  84         else
  85                 enable_gss=
  86                 GSSD=
  87                 SVCGSSD=
  88         fi
  89         AC_SUBST(GSSD)
  90         AC_SUBST(SVCGSSD)
  91         AC_SUBST(enable_gss)
  92         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  93 AC_ARG_ENABLE(kprefix,
  94         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  95         test "$enableval" = "yes" && kprefix=k,
  96         kprefix=)
  97         AC_SUBST(kprefix)
  98 AC_ARG_ENABLE(secure-statd,
  99         [AC_HELP_STRING([--enable-secure-statd],
 100                         [Only lockd can use statd (security)])],
 101         test "$enableval" = "yes" && secure_statd=yes,
 102         secure_statd=yes)
 103         if test "$secure_statd" = yes; then
 104                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
 105         fi
 106         AC_SUBST(secure_statd)
 107 AC_ARG_WITH(rpcgen,
 108         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
 109         rpcgen_path=$withval,
 110         rpcgen_path=yes )
 111         RPCGEN_PATH=
 112         if test "$rpcgen_path" == "yes"; then
 113             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
 114             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
 115         elif test "$rpcgen_path" != "internal"; then
 116             RPCGEN_PATH=$rpcgen_path
 117         fi
 118         AC_SUBST(RPCGEN_PATH)
 119         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" == ""])
 120 AC_ARG_ENABLE(uuid,
 121         [AC_HELP_STRING([--without-uuid], [Exclude uuid support and so avoid possibly buggy libblkid])],
 122         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
 123         choose_blkid=default)
 124 AC_ARG_ENABLE(mount,
 125         [AC_HELP_STRING([--enable-mount],
 126                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
 127         enable_mount=$enableval,
 128         enable_mount=yes)
 129         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 130
 131 # Check whether user wants TCP wrappers support
 132 AC_TCP_WRAPPERS
 133
 134 # Arrange for large-file support
 135 AC_SYS_LARGEFILE
 136
 137 AC_CONFIG_SRCDIR([support/include/config.h.in])
 138 AC_CONFIG_HEADERS([support/include/config.h])
 139
 140 # Checks for programs.
 141 AC_PROG_CXX
 142 AC_PROG_CC
 143 AC_PROG_CPP
 144 AC_PROG_INSTALL
 145 AC_PROG_LN_S
 146 AC_PROG_MAKE_SET
 147 AC_PROG_LIBTOOL
 148 AM_PROG_CC_C_O
 149
 150 if test "x$cross_compiling" = "xno"; then
 151         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 152 else
 153         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 154 fi
 155
 156 AC_SUBST(CC_FOR_BUILD)
 157
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(LD, ld)
 160
 161 AC_HEADER_STDC([])
 162 AC_GNULIBC
 163 AC_BSD_SIGNALS
 164
 165 dnl *************************************************************
 166 dnl * Check for required libraries
 167 dnl *************************************************************
 168 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(nsl, gethostbyname, [LIBNSL="-lnsl"])])
 169 AC_SUBST(LIBNSL)
 170
 171 AC_CHECK_FUNC(connect, ,
 172       AC_CHECK_LIB(socket, connect, [LIBSOCKET="-lsocket"],
 173                 AC_MSG_ERROR(Function 'socket' not found.), $LIBNSL))
 174
 175 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 176 if test "$enable_nfsv4" = yes; then
 177     AC_CHECK_LIB(event, event_dispatch, [libevent=1], AC_MSG_ERROR([libevent needed for nfsv4 support]))
 178     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 179     AC_CHECK_HEADERS(event.h, ,AC_MSG_ERROR([libevent needed for nfsv4 support]))
 180     AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 181     dnl librpcsecgss already has a dependency on libgssapi,
 182     dnl but we need to make sure we get the right version
 183     if test "$enable_gss" = yes; then
 184      PKG_CHECK_MODULES(RPCSECGSS, librpcsecgss >= 0.16, ,
 185       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.  If you have pkgconfig installed, you might try setting environment variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
 186       ]
 187      )
 188     PKG_CHECK_MODULES(GSSGLUE, libgssglue >= 0.1)
 189     fi
 190
 191 fi
 192 if test "$knfsd_cv_glibc2" = no; then
 193     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 194 fi
 195
 196 if test "$choose_blkid" != no; then
 197    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 198    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
 199    AC_BLKID_VERS
 200    if test $choose_blkid = yes; then
 201       use_blkid=1
 202       test $libblkid_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
 203    else
 204       if test $libblkid_is_recent = yes
 205       then use_blkid=1
 206       else use_blkid=0
 207            AC_MSG_WARN([uuid support disabled as libblkid is too old])
 208       fi
 209     fi
 210     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
 211 fi
 212 AC_SUBST(LIBSOCKET)
 213 AC_SUBST(LIBCRYPT)
 214 AC_SUBST(LIBBSD)
 215 AC_SUBST(LIBBLKID)
 216
 217 if test "$enable_gss" = yes; then
 218   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 219   AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for gss support]))
 220   AC_CHECK_HEADERS(spkm3.h, ,AC_MSG_WARN([could not locate SPKM3 header; will not have SPKM3 support]))
 221   dnl the nfs4_set_debug function doesn't appear in all version of the library
 222   AC_CHECK_LIB(nfsidmap, nfs4_set_debug,
 223                AC_DEFINE(HAVE_NFS4_SET_DEBUG,1,
 224                          [Whether nfs4_set_debug() is present in libnfsidmap]),)
 225
 226   dnl Check for Kerberos V5
 227   AC_KERBEROS_V5
 228
 229   dnl This is not done until here because we need to have KRBLIBS set
 230   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
 231   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], AC_MSG_ERROR([librpcsecgss needed for nfsv4 support]), -lgssglue -ldl)
 232   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 233                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, -lgssglue -ldl)
 234
 235 fi
 236
 237 dnl *************************************************************
 238 dnl Check for headers
 239 dnl *************************************************************
 240 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 241                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 242                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 243                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 244                  syslog.h unistd.h com_err.h et/com_err.h \
 245                  ifaddrs.h])
 246
 247 dnl *************************************************************
 248 dnl Checks for typedefs, structures, and compiler characteristics
 249 dnl *************************************************************
 250 AC_C_CONST
 251 AC_TYPE_UID_T
 252 AC_C_INLINE
 253 AC_TYPE_OFF_T
 254 AC_TYPE_PID_T
 255 AC_TYPE_SIZE_T
 256 AC_HEADER_TIME
 257 AC_STRUCT_TM
 258
 259 dnl *************************************************************
 260 dnl Check for functions
 261 dnl *************************************************************
 262 AC_FUNC_ALLOCA
 263 AC_FUNC_CLOSEDIR_VOID
 264 AC_FUNC_ERROR_AT_LINE
 265 AC_FUNC_FORK
 266 AC_FUNC_GETGROUPS
 267 AC_FUNC_GETMNTENT
 268 AC_PROG_GCC_TRADITIONAL
 269 AC_FUNC_LSTAT
 270 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 271 AC_HEADER_MAJOR
 272 #AC_FUNC_MALLOC
 273 AC_FUNC_MEMCMP
 274 #AC_FUNC_REALLOC
 275 AC_FUNC_SELECT_ARGTYPES
 276 AC_TYPE_SIGNAL
 277 AC_FUNC_STAT
 278 AC_FUNC_VPRINTF
 279 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 280                gethostbyaddr gethostbyname gethostname getmntent \
 281                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 282                realpath rmdir select socket strcasecmp strchr strdup \
 283                strerror strrchr strtol strtoul sigprocmask])
 284
 285
 286 dnl *************************************************************
 287 dnl Check for data sizes
 288 dnl *************************************************************
 289 AC_CHECK_SIZEOF(short)
 290 AC_CHECK_SIZEOF(int)
 291 AC_CHECK_SIZEOF(long)
 292 AC_CHECK_SIZEOF(size_t)
 293 AC_CHECK_SIZEOF(socklen_t)
 294
 295
 296 dnl *************************************************************
 297 dnl Export some path names to config.h
 298 dnl *************************************************************
 299 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 300
 301 if test "x$cross_compiling" = "xno"; then
 302         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 303         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 304         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 305         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 306 else
 307         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 308         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 309         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 310         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 311 fi
 312
 313 AC_SUBST(CFLAGS)
 314 AC_SUBST(CXXFLAGS)
 315 AC_SUBST(CPPFLAGS)
 316 AC_SUBST(LDFLAGS)
 317
 318 AC_SUBST(CFLAGS_FOR_BUILD)
 319 AC_SUBST(CXXFLAGS_FOR_BUILD)
 320 AC_SUBST(CPPFLAGS_FOR_BUILD)
 321 AC_SUBST(LDFLAGS_FOR_BUILD)
 322
 323 dnl *************************************************************
 324 dnl Set up "global" CFLAGS
 325 dnl *************************************************************
 326 dnl Use architecture-specific compile flags
 327 dnl (We use $host and not $build in case we are cross-compiling)
 328 dnl *************************************************************
 329 dnl Note: we no longer have arch specific compile flags, but
 330 dnl the stub is left here in case they are needed one day.
 331 case $host in
 332   *)
 333     ARCHFLAGS="" ;;
 334 esac
 335
 336 my_am_cflags="-Wall -Wstrict-prototypes $ARCHFLAGS -pipe"
 337
 338 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include"])
 339 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 340
 341 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 342 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 343
 344 AC_CONFIG_FILES([
 345         Makefile
 346         linux-nfs/Makefile
 347         support/Makefile
 348         support/export/Makefile
 349         support/include/nfs/Makefile
 350         support/include/rpcsvc/Makefile
 351         support/include/sys/fs/Makefile
 352         support/include/sys/Makefile
 353         support/include/Makefile
 354         support/misc/Makefile
 355         support/nfs/Makefile
 356         tools/Makefile
 357         tools/locktest/Makefile
 358         tools/nlmtest/Makefile
 359         tools/rpcdebug/Makefile
 360         tools/rpcgen/Makefile
 361         utils/Makefile
 362         utils/exportfs/Makefile
 363         utils/gssd/Makefile
 364         utils/idmapd/Makefile
 365         utils/mount/Makefile
 366         utils/mountd/Makefile
 367         utils/nfsd/Makefile
 368         utils/nfsstat/Makefile
 369         utils/showmount/Makefile
 370         utils/statd/Makefile])
 371 AC_OUTPUT
 372