aclocal/kerberos5.m4

   1 dnl Checks for Kerberos
   2 dnl NOTE: while we intend to do generic gss-api, currently we
   3 dnl have a requirement to get an initial Kerberos machine
   4 dnl credential.  Thus, the requirement for Kerberos.
   5 dnl The Kerberos gssapi library will be dynamically loaded?
   6 AC_DEFUN([AC_KERBEROS_V5],[
   7   AC_MSG_CHECKING(for Kerberos v5)
   8   AC_ARG_WITH(krb5,
   9   [AC_HELP_STRING([--with-krb5=DIR], [use Kerberos v5 installation in DIR])],
  10   [ case "$withval" in
  11     yes|no)
  12        krb5_with=""
  13        ;;
  14     *)
  15        krb5_with="$withval"
  16        ;;
  17     esac ]
  18   )
  19
  20   for dir in $krb5_with /usr /usr/kerberos /usr/local /usr/local/krb5 \
  21              /usr/krb5 /usr/heimdal /usr/local/heimdal /usr/athena ; do
  22     dnl This ugly hack brought on by the split installation of
  23     dnl MIT Kerberos on Fedora Core 1
  24     K5CONFIG=""
  25     if test -f $dir/bin/krb5-config; then
  26       K5CONFIG=$dir/bin/krb5-config
  27     elif test -f "/usr/kerberos/bin/krb5-config"; then
  28       K5CONFIG="/usr/kerberos/bin/krb5-config"
  29     elif test -f "/usr/lib/mit/bin/krb5-config"; then
  30       K5CONFIG="/usr/lib/mit/bin/krb5-config"
  31     fi
  32     if test "$K5CONFIG" != ""; then
  33       KRBCFLAGS=`$K5CONFIG --cflags`
  34       KRBLIBS=`$K5CONFIG --libs`
  35       GSSKRB_CFLAGS=`$K5CONFIG --cflags gssapi`
  36       GSSKRB_LIBS=`$K5CONFIG --libs gssapi`
  37       K5VERS=`$K5CONFIG --version | head -n 1 | awk '{split($(4),v,"."); if (v@<:@"3"@:>@ == "") v@<:@"3"@:>@ = "0"; print v@<:@"1"@:>@v@<:@"2"@:>@v@<:@"3"@:>@ }'`
  38       AC_DEFINE_UNQUOTED(KRB5_VERSION, $K5VERS, [Define this as the Kerberos version number])
  39       if test -f $dir/include/gssapi/gssapi_krb5.h -a \
  40                 \( -f $dir/lib/libgssapi_krb5.a -o \
  41                    -f $dir/lib64/libgssapi_krb5.a -o \
  42                    -f $dir/lib64/libgssapi_krb5.so -o \
  43                    -f $dir/lib/libgssapi_krb5.so \) ; then
  44          AC_DEFINE(HAVE_KRB5, 1, [Define this if you have MIT Kerberos libraries])
  45          KRBDIR="$dir"
  46   dnl If we are using MIT K5 1.3.1 and before, we *MUST* use the
  47   dnl private function (gss_krb5_ccache_name) to get correct
  48   dnl behavior of changing the ccache used by gssapi.
  49   dnl Starting in 1.3.2, we *DO NOT* want to use
  50   dnl gss_krb5_ccache_name, instead we want to set KRB5CCNAME
  51   dnl to get gssapi to use a different ccache
  52          if test $K5VERS -le 131; then
  53            AC_DEFINE(USE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the private function, gss_krb5_cache_name, must be used to tell the Kerberos library which credentials cache to use. Otherwise, this is done by setting the KRB5CCNAME environment variable])
  54          fi
  55          gssapi_lib=gssapi_krb5
  56          break
  57       dnl The following ugly hack brought on by the split installation
  58       dnl of Heimdal Kerberos on SuSe
  59       elif test \( -f $dir/include/heim_err.h -o\
  60                  -f $dir/include/heimdal/heim_err.h \) -a \
  61                 -f $dir/lib/libroken.a; then
  62          AC_DEFINE(HAVE_HEIMDAL, 1, [Define this if you have Heimdal Kerberos libraries])
  63          KRBDIR="$dir"
  64          gssapi_lib=gssapi
  65         break
  66       fi
  67     fi
  68   done
  69   dnl We didn't find a usable Kerberos environment
  70   if test "x$KRBDIR" = "x"; then
  71     if test "x$krb5_with" = "x"; then
  72       AC_MSG_ERROR(Kerberos v5 with GSS support not found: consider --disable-gss or --with-krb5=)
  73     else
  74       AC_MSG_ERROR(Kerberos v5 with GSS support not found at $krb5_with)
  75     fi
  76   fi
  77   AC_MSG_RESULT($KRBDIR)
  78
  79   dnl Check if -rpath=$(KRBDIR)/lib is needed
  80   echo "The current KRBDIR is $KRBDIR"
  81   if test "$KRBDIR/lib" = "/lib" -o "$KRBDIR/lib" = "/usr/lib" \
  82        -o "$KRBDIR/lib" = "//lib" -o "$KRBDIR/lib" = "/usr//lib" ; then
  83     KRBLDFLAGS="";
  84   elif /sbin/ldconfig -p | grep > /dev/null "=> $KRBDIR/lib/"; then
  85     KRBLDFLAGS="";
  86   else
  87     KRBLDFLAGS="-Wl,-rpath=$KRBDIR/lib"
  88   fi
  89
  90   dnl Now check for functions within gssapi library
  91   AC_CHECK_LIB($gssapi_lib, gss_krb5_export_lucid_sec_context,
  92     AC_DEFINE(HAVE_LUCID_CONTEXT_SUPPORT, 1, [Define this if the Kerberos GSS library supports gss_krb5_export_lucid_sec_context]), ,$KRBLIBS)
  93   AC_CHECK_LIB($gssapi_lib, gss_krb5_set_allowable_enctypes,
  94     AC_DEFINE(HAVE_SET_ALLOWABLE_ENCTYPES, 1, [Define this if the Kerberos GSS library supports gss_krb5_set_allowable_enctypes]), ,$KRBLIBS)
  95   AC_CHECK_LIB($gssapi_lib, gss_krb5_ccache_name,
  96     AC_DEFINE(HAVE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the Kerberos GSS library supports gss_krb5_ccache_name]), ,$KRBLIBS)
  97   AC_CHECK_LIB($gssapi_lib, gss_krb5_free_lucid_sec_context,
  98     AC_DEFINE(HAVE_GSS_KRB5_FREE_LUCID_SEC_CONTEXT, 1, [Define this if the Kerberos GSS library supports gss_krb5_free_lucid_sec_context]), ,$KRBLIBS)
  99
 100   dnl Check for newer error message facility
 101   AC_CHECK_LIB($gssapi_lib, krb5_get_error_message,
 102     AC_DEFINE(HAVE_KRB5_GET_ERROR_MESSAGE, 1, [Define this if the function krb5_get_error_message is available]), ,$KRBLIBS)
 103
 104   dnl Check for function to specify addressless tickets
 105   AC_CHECK_LIB($gssapi_lib, krb5_get_init_creds_opt_set_addressless,
 106     AC_DEFINE(HAVE_KRB5_GET_INIT_CREDS_OPT_SET_ADDRESSLESS, 1, [Define this if the function krb5_get_init_creds_opt_set_addressless is available]), ,$KRBLIBS)
 107
 108   dnl If they specified a directory and it didn't work, give them a warning
 109   if test "x$krb5_with" != "x" -a "$krb5_with" != "$KRBDIR"; then
 110     AC_MSG_WARN(Using $KRBDIR instead of requested value of $krb5_with for Kerberos!)
 111   fi
 112
 113   AC_SUBST([KRBDIR])
 114   AC_SUBST([KRBLIBS])
 115   AC_SUBST([KRBCFLAGS])
 116   AC_SUBST([KRBLDFLAGS])
 117   AC_SUBST([K5VERS])
 118   AC_SUBST([GSSKRB_CFLAGS])
 119   AC_SUBST([GSSKRB_LIBS])
 120
 121 ])