lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =item fetch_objects
  43
  44 =back
  45
  46 =head1 Additional Commands
  47
  48 =over
  49
  50 =item delete
  51
  52 Surprisingly, this command causes a database record to be forever lost.
  53
  54 =item search
  55
  56 The search action
  57
  58 =back
  59
  60 =head1 Helper Methods
  61
  62 =over
  63
  64 =item order
  65
  66 =item stringify_column
  67
  68 =item do_pager
  69
  70 =item related_class
  71
  72 Given an accessor name as a method, this function returns the class this accessor returns.
  73
  74 =back
  75
  76 =cut
  77
  78 sub related {
  79     my ( $self, $r ) = @_;
  80     return keys %{ $self->meta_info('has_many') || {} };
  81 }
  82
  83 sub related_class {
  84     my ( $self, $r, $accessor ) = @_;
  85     my $related = $self->related->{$accessor};
  86     if ( my $mapping = $related->{args}->{mapping} ) {
  87         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  88           ->{foreign_class};
  89     }
  90     else {
  91         return $related->{foreign_class};
  92     }
  93 }
  94
  95 sub do_edit : Exported {
  96     my ( $self, $r ) = @_;
  97     my $h        = CGI::Untaint->new( %{ $r->{params} } );
  98     my $creating = 0;
  99     my ($obj) = @{ $r->objects || [] };
 100     my $fatal;
 101     if ($obj) {
 102         # We have something to edit
 103         eval {
 104             $obj->update_from_cgi( $h =>
 105                 { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 106             );
 107         };
 108         $fatal = $@;
 109     }
 110     else {
 111         eval {
 112             $obj =
 113                 $self->create_from_cgi( $h =>
 114                     { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 115             );
 116         };
 117         $fatal = $@;
 118         $creating++;
 119     }
 120     if ( my %errors = $fatal ? (FATAL => $fatal) : $obj->cgi_update_errors ) {
 121
 122         # Set it up as it was:
 123         $r->{template_args}{cgi_params} = $r->{params};
 124         $r->{template_args}{errors}     = \%errors;
 125
 126         if ($creating) {
 127             undef $obj;
 128             $r->template("addnew");
 129         } else {
 130             $r->template("edit");
 131         }
 132     }
 133     else {
 134         $r->{template} = "view";
 135     }
 136     $r->objects( [$obj] );
 137 }
 138
 139 sub delete : Exported {
 140     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 141     my ( $self, $r ) = @_;
 142     $_->SUPER::delete for @{ $r->objects || [] };
 143     $r->objects( [ $self->retrieve_all ] );
 144     $r->{template} = "list";
 145     $self->list($r);
 146 }
 147
 148 sub stringify_column {
 149     my $class = shift;
 150     return (
 151         $class->columns("Stringify"),
 152         ( grep { /(name|title)/i } $class->columns ),
 153         ( grep { !/id$/i } $class->primary_columns ),
 154     )[0];
 155 }
 156
 157 sub adopt {
 158     my ( $self, $child ) = @_;
 159     $child->autoupdate(1);
 160     if ( my $col = $child->stringify_column ) {
 161         $child->columns( Stringify => $col );
 162     }
 163 }
 164
 165 sub search : Exported {
 166     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 167
 168     # A real CDBI search.
 169     my ( $self, $r ) = @_;
 170     my %fields = map { $_ => 1 } $self->columns;
 171     my $oper   = "like";                                # For now
 172     my %params = %{ $r->{params} };
 173     my %values = map { $_ => { $oper, $params{$_} } }
 174       grep { length ($params{$_}) and $fields{$_} } keys %params;
 175
 176     $r->template("list");
 177     if ( !%values ) { return $self->list($r) }
 178     my $order = $self->order($r);
 179     $self = $self->do_pager($r);
 180     $r->objects(
 181         [
 182             $self->search_where(
 183                 \%values, ( $order ? { order_by => $order } : () )
 184             )
 185         ]
 186     );
 187     $r->{template_args}{search} = 1;
 188 }
 189
 190 sub do_pager {
 191     my ( $self, $r ) = @_;
 192     if ( my $rows = $r->config->rows_per_page ) {
 193         return $r->{template_args}{pager} =
 194           $self->pager( $rows, $r->query->{page} );
 195     }
 196     else { return $self }
 197 }
 198
 199 sub order {
 200     my ( $self, $r ) = @_;
 201     my $order;
 202     my %ok_columns = map { $_ => 1 } $self->columns;
 203     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 204         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 205     }
 206     $order;
 207 }
 208
 209 sub list : Exported {
 210     my ( $self, $r ) = @_;
 211     my $order = $self->order($r);
 212     $self = $self->do_pager($r);
 213     if ($order) {
 214         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 215     }
 216     else {
 217         $r->objects( [ $self->retrieve_all ] );
 218     }
 219 }
 220
 221 sub setup_database {
 222     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 223     $dsn  ||= $config->dsn;
 224     $u    ||= $config->user;
 225     $p    ||= $config->pass;
 226     $opts ||= $config->opts;
 227     $config->dsn($dsn);
 228     warn "No DSN set in config" unless $dsn;
 229     $config->loader || $config->loader(
 230         Class::DBI::Loader->new(
 231             namespace => $namespace,
 232             dsn       => $dsn,
 233             user      => $u,
 234             password  => $p,
 235             options   => $opts,
 236         )
 237     );
 238     $config->{classes} = [ $config->{loader}->classes ];
 239     $config->{tables}  = [ $config->{loader}->tables ];
 240     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 241       if $namespace->debug;
 242 }
 243
 244 sub class_of {
 245     my ( $self, $r, $table ) = @_;
 246     return $r->config->loader->_table2class($table);
 247 }
 248
 249 sub fetch_objects {
 250     my ($class,$r)=@_;
 251     my @pcs = $class->primary_columns;
 252     if ( $#pcs ) {
 253     my %pks;
 254         @pks{@pcs}=(@{$r->{args}});
 255         return $class->retrieve( %pks );
 256     }
 257     return $class->retrieve( $r->{args}->[0] );
 258 }
 259
 260 1;