518b6d80254473a77248a88a6aa21fea173de0ea
[nfs-utils.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 dnl
3 AC_INIT([linux nfs-utils],[1.2.2],[linux-nfs@vger.kernel.org],[nfs-utils])
4 AC_CANONICAL_BUILD([])
5 AC_CANONICAL_HOST([])
6 AC_CONFIG_MACRO_DIR(aclocal)
7 AM_INIT_AUTOMAKE
8 AC_PREREQ(2.59)
9 AC_PREFIX_DEFAULT(/usr)
10 AM_MAINTAINER_MODE
11
12 dnl *************************************************************
13 dnl * Define the set of applicable options
14 dnl *************************************************************
15 AC_ARG_WITH(release,
16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
17         RELEASE=$withval,
18         RELEASE=1)
19         AC_SUBST(RELEASE)
20 AC_ARG_WITH(statedir,
21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
22         statedir=$withval,
23         statedir=/var/lib/nfs)
24         AC_SUBST(statedir)
25 AC_ARG_WITH(statduser,
26         [AC_HELP_STRING([--with-statduser=rpcuser],
27                         [statd to run under @<:@rpcuser or nobody@:>@]
28         )],
29         statduser=$withval,
30         if test "x$cross_compiling" = "xno"; then
31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
32                         statduser=rpcuser
33                 else
34                         statduser=nobody
35                 fi
36         else
37                 statduser=nobody
38         fi)
39         AC_SUBST(statduser)
40 AC_ARG_WITH(start-statd,
41         [AC_HELP_STRING([--with-start-statd=scriptname],
42                         [When an nfs filesystems is mounted with locking, run this script]
43         )],
44         startstatd=$withval,
45         startstatd=/usr/sbin/start-statd
46         )
47         AC_SUBST(startstatd)
48         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
49 AC_ARG_ENABLE(nfsv3,
50         [AC_HELP_STRING([--enable-nfsv3],
51                         [enable support for NFSv3 @<:@default=yes@:>@])],
52         enable_nfsv3=$enableval,
53         enable_nfsv3=yes)
54         if test "$enable_nfsv3" = yes; then
55                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
56         else
57                 enable_nfsv3=
58         fi
59         AC_SUBST(enable_nfsv3)
60 AC_ARG_ENABLE(nfsv4,
61         [AC_HELP_STRING([--enable-nfsv4],
62                         [enable support for NFSv4 @<:@default=yes@:>@])],
63         enable_nfsv4=$enableval,
64         enable_nfsv4=yes)
65         if test "$enable_nfsv4" = yes; then
66                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
67                 IDMAPD=idmapd
68         else
69                 enable_nfsv4=
70                 IDMAPD=
71         fi
72         AC_SUBST(IDMAPD)
73         AC_SUBST(enable_nfsv4)
74         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
75
76 AC_ARG_ENABLE(nfsv41,
77         [AC_HELP_STRING([--enable-nfsv41],
78                         [enable support for NFSv41 @<:@default=no@:>@])],
79         enable_nfsv41=$enableval,
80         enable_nfsv41=no)
81         if test "$enable_nfsv41" = yes; then
82                 AC_DEFINE(NFS41_SUPPORTED, 1, [Define this if you want NFSv41 support compiled in])
83         else
84                 enable_nfsv41=
85         fi
86         AC_SUBST(enable_nfsv41)
87         AM_CONDITIONAL(CONFIG_NFSV41, [test "$enable_nfsv41" = "yes"])
88
89 AC_ARG_ENABLE(gss,
90         [AC_HELP_STRING([--enable-gss],
91                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
92         enable_gss=$enableval,
93         enable_gss=yes)
94         if test "$enable_gss" = yes; then
95                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
96                 GSSD=gssd
97                 SVCGSSD=svcgssd
98         else
99                 enable_gss=
100                 GSSD=
101                 SVCGSSD=
102         fi
103         AC_SUBST(GSSD)
104         AC_SUBST(SVCGSSD)
105         AC_SUBST(enable_gss)
106         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
107 AC_ARG_ENABLE(kprefix,
108         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
109         test "$enableval" = "yes" && kprefix=k,
110         kprefix=)
111         AC_SUBST(kprefix)
112 AC_ARG_WITH(rpcgen,
113         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
114         rpcgen_path=$withval,
115         rpcgen_path=yes )
116         RPCGEN_PATH=
117         if test "$rpcgen_path" == "yes"; then
118             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
119             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
120         elif test "$rpcgen_path" != "internal"; then
121             RPCGEN_PATH=$rpcgen_path
122         fi
123         AC_SUBST(RPCGEN_PATH)
124         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" == ""])
125 AC_ARG_ENABLE(uuid,
126         [AC_HELP_STRING([--disable-uuid], [Exclude uuid support to avoid buggy libblkid])],
127         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
128         choose_blkid=default)
129 AC_ARG_ENABLE(mount,
130         [AC_HELP_STRING([--enable-mount],
131                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
132         enable_mount=$enableval,
133         enable_mount=yes)
134         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
135 AC_ARG_ENABLE(tirpc,
136         [AC_HELP_STRING([--enable-tirpc],
137                         [enable use of TI-RPC @<:@default=yes@:>@])],
138         enable_tirpc=$enableval,
139         enable_tirpc='yes')
140 AC_ARG_ENABLE(ipv6,
141         [AC_HELP_STRING([--enable-ipv6],
142                         [enable support for IPv6 @<:@default=no@:>@])],
143         enable_ipv6=$enableval,
144         enable_ipv6=no)
145         if test "$enable_ipv6" = yes; then
146                 AC_DEFINE(IPV6_SUPPORTED, 1, [Define this if you want IPv6 support compiled in])
147         else
148                 enable_ipv6=
149         fi
150         AC_SUBST(enable_ipv6)
151         AM_CONDITIONAL(CONFIG_IPV6, [test "$enable_ipv6" = "yes"])
152
153 if test "$enable_mount" = yes; then
154         AC_ARG_ENABLE(mountconfig,
155         [AC_HELP_STRING([--enable-mountconfig],
156                         [enable mount to use a configuration file])],
157         mountconfig=$enableval,
158         mountconfig=no)
159         if test "$enable_mountconfig" = yes; then
160                 AC_DEFINE(MOUNT_CONFIG, 1, 
161                         [Define this if you want mount to read a configuration file])
162                 AC_ARG_WITH(mountfile,
163                         [AC_HELP_STRING([--with-mountfile=filename],
164                         [Using filename as the NFS mount options file [/etc/nfsmounts.conf]]
165                         )],
166                 mountfile=$withval,
167                 mountfile=/etc/nfsmount.conf)
168                 AC_SUBST(mountfile)
169                 AC_DEFINE_UNQUOTED(MOUNTOPTS_CONFFILE, "$mountfile", 
170                         [This defines the location of the NFS mount configuration file])
171         else
172                 enable_mountconfig=
173         fi
174         AC_SUBST(enable_mountconfig)
175         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mountconfig" = "yes"])
176 else
177         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mount" = "yes"])
178 fi
179
180 dnl Check for TI-RPC library and headers
181 AC_LIBTIRPC
182
183 dnl Check for -lcap
184 AC_LIBCAP
185
186 # Check whether user wants TCP wrappers support
187 AC_TCP_WRAPPERS
188
189 # Arrange for large-file support
190 AC_SYS_LARGEFILE
191
192 AC_CONFIG_SRCDIR([support/include/config.h.in])
193 AC_CONFIG_HEADERS([support/include/config.h])
194
195 # Checks for programs.
196 AC_PROG_CXX
197 AC_PROG_CC
198 AC_PROG_CPP
199 AC_PROG_INSTALL
200 AC_PROG_LN_S
201 AC_PROG_MAKE_SET
202 AC_PROG_LIBTOOL
203 AM_PROG_CC_C_O
204
205 if test "x$cross_compiling" = "xno"; then
206         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
207 else
208         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
209 fi
210
211 AC_SUBST(CC_FOR_BUILD)
212
213 AC_CHECK_TOOL(AR, ar)
214 AC_CHECK_TOOL(LD, ld)
215
216 AC_HEADER_STDC([])
217 AC_GNULIBC
218 AC_BSD_SIGNALS
219
220 dnl *************************************************************
221 dnl * Check for required libraries
222 dnl *************************************************************
223
224 AC_CHECK_FUNC([gethostbyname], ,
225               [AC_CHECK_LIB([nsl], [gethostbyname], [LIBNSL="-lnsl"])])
226 AC_SUBST(LIBNSL)
227
228 AC_CHECK_FUNC([connect], ,
229               [AC_CHECK_LIB([socket], [connect], [LIBSOCKET="-lsocket"],
230                     [AC_MSG_ERROR([Function 'socket' not found.])], [$LIBNSL])])
231
232 AC_CHECK_FUNC([getaddrinfo], ,
233               [AC_MSG_ERROR([Function 'getaddrinfo' not found.])])
234
235 AC_CHECK_FUNC([getrpcbynumber], ,
236               [AC_MSG_ERROR([Function 'getrpcbynumber' not found.])])
237
238 AC_CHECK_FUNC([getservbyname], ,
239               [AC_MSG_ERROR([Function 'getservbyname' not found.])])
240
241 AC_CHECK_LIB([crypt], [crypt], [LIBCRYPT="-lcrypt"])
242
243 if test "$enable_nfsv4" = yes; then
244   dnl check for libevent libraries and headers
245   AC_LIBEVENT
246
247   dnl check for nfsidmap libraries and headers
248   AC_LIBNFSIDMAP
249
250   dnl librpcsecgss already has a dependency on libgssapi,
251   dnl but we need to make sure we get the right version
252   if test "$enable_gss" = yes; then
253     AC_RPCSEC_VERSION
254   fi
255 fi
256
257 if test "$knfsd_cv_glibc2" = no; then
258     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
259 fi
260
261 if test "$choose_blkid" != no; then 
262    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
263    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
264    AC_BLKID_VERS
265    if test $choose_blkid = yes; then
266       use_blkid=1
267       test $libblkid_cv_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
268    else
269       if test $libblkid_cv_is_recent = yes
270       then use_blkid=1
271       else use_blkid=0
272            AC_MSG_WARN([uuid support disabled as libblkid is too old])
273       fi
274     fi
275     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
276 fi
277 AC_SUBST(LIBSOCKET)
278 AC_SUBST(LIBCRYPT)
279 AC_SUBST(LIBBSD)
280 AC_SUBST(LIBBLKID)
281
282 if test "$enable_gss" = yes; then
283   dnl 'gss' requires getnameinfo - at least for gssd_proc.c
284   AC_CHECK_FUNC([getnameinfo], , [AC_MSG_ERROR([GSSAPI support requires 'getnameinfo' function])])
285
286   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
287   AC_LIBNFSIDMAP
288
289   AC_CHECK_HEADERS([spkm3.h], ,
290                    [AC_MSG_WARN([Could not locate SPKM3 header; will not have SPKM3 support])])
291
292   dnl Check for Kerberos V5
293   AC_KERBEROS_V5
294
295   dnl Invoked after AC_KERBEROS_V5; AC_LIBRPCSECGSS needs to have KRBLIBS set
296   AC_LIBRPCSECGSS
297
298 fi
299
300 dnl Check for IPv6 support
301 AC_IPV6
302
303 dnl *************************************************************
304 dnl Check for headers
305 dnl *************************************************************
306 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
307                  malloc.h memory.h netdb.h netinet/in.h paths.h \
308                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
309                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
310                  syslog.h unistd.h com_err.h et/com_err.h \
311                  ifaddrs.h])
312
313 dnl *************************************************************
314 dnl Checks for typedefs, structures, and compiler characteristics
315 dnl *************************************************************
316 AC_C_CONST
317 AC_TYPE_UID_T
318 AC_C_INLINE
319 AC_TYPE_OFF_T
320 AC_TYPE_PID_T
321 AC_TYPE_SIZE_T
322 AC_HEADER_TIME
323 AC_STRUCT_TM
324
325 dnl *************************************************************
326 dnl Check for functions
327 dnl *************************************************************
328 AC_FUNC_ALLOCA
329 AC_FUNC_CLOSEDIR_VOID
330 AC_FUNC_ERROR_AT_LINE
331 AC_FUNC_FORK
332 AC_FUNC_GETGROUPS
333 AC_FUNC_GETMNTENT
334 AC_PROG_GCC_TRADITIONAL
335 AC_FUNC_LSTAT
336 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
337 AC_HEADER_MAJOR
338 #AC_FUNC_MALLOC
339 AC_FUNC_MEMCMP
340 #AC_FUNC_REALLOC
341 AC_FUNC_SELECT_ARGTYPES
342 AC_TYPE_SIGNAL
343 AC_FUNC_STAT
344 AC_FUNC_VPRINTF
345 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
346                gethostbyaddr gethostbyname gethostname getmntent \
347                getnameinfo getrpcbyname getifaddrs \
348                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
349                realpath rmdir select socket strcasecmp strchr strdup \
350                strerror strrchr strtol strtoul sigprocmask])
351
352
353 dnl *************************************************************
354 dnl Check for data sizes
355 dnl *************************************************************
356 AC_CHECK_SIZEOF(short)
357 AC_CHECK_SIZEOF(int)
358 AC_CHECK_SIZEOF(long)
359 AC_CHECK_SIZEOF(size_t)
360 AC_CHECK_SIZEOF(socklen_t)
361
362
363 dnl *************************************************************
364 dnl Export some path names to config.h
365 dnl *************************************************************
366 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
367
368 if test "x$cross_compiling" = "xno"; then
369         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
370         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
371         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
372         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
373 else
374         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
375         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
376         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
377         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
378 fi
379
380 AC_SUBST(CFLAGS)
381 AC_SUBST(CXXFLAGS)
382 AC_SUBST(CPPFLAGS)
383 AC_SUBST(LDFLAGS)
384
385 AC_SUBST(CFLAGS_FOR_BUILD)
386 AC_SUBST(CXXFLAGS_FOR_BUILD)
387 AC_SUBST(CPPFLAGS_FOR_BUILD)
388 AC_SUBST(LDFLAGS_FOR_BUILD)
389
390 dnl *************************************************************
391 dnl Set up "global" CFLAGS
392 dnl *************************************************************
393 dnl Use architecture-specific compile flags
394 dnl (We use $host and not $build in case we are cross-compiling)
395 dnl *************************************************************
396 dnl Note: we no longer have arch specific compile flags, but 
397 dnl the stub is left here in case they are needed one day.
398 case $host in
399   *)
400     ARCHFLAGS="" ;;
401 esac
402
403 my_am_cflags="-Wall -Wstrict-prototypes $ARCHFLAGS -pipe"
404
405 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
406
407 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
408 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
409
410 AC_CONFIG_FILES([
411         Makefile
412         linux-nfs/Makefile
413         support/Makefile
414         support/export/Makefile
415         support/include/nfs/Makefile
416         support/include/rpcsvc/Makefile
417         support/include/sys/fs/Makefile
418         support/include/sys/Makefile
419         support/include/Makefile
420         support/misc/Makefile
421         support/nfs/Makefile
422         support/nsm/Makefile
423         tools/Makefile
424         tools/locktest/Makefile
425         tools/nlmtest/Makefile
426         tools/rpcdebug/Makefile
427         tools/rpcgen/Makefile
428         utils/Makefile
429         utils/exportfs/Makefile
430         utils/gssd/Makefile
431         utils/idmapd/Makefile
432         utils/mount/Makefile
433         utils/mountd/Makefile
434         utils/nfsd/Makefile
435         utils/nfsstat/Makefile
436         utils/showmount/Makefile
437         utils/statd/Makefile
438         tests/Makefile
439         tests/nsm_client/Makefile])
440 AC_OUTPUT
441