lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Lingua::EN::Inflect::Number qw(to_PL);
   4 use Class::DBI::AsForm;
   5 use Class::DBI::FromCGI;
   6 use Class::DBI::Loader;
   7 use Class::DBI::AbstractSearch;
   8 use Class::DBI::Plugin::RetrieveAll;
   9 use Class::DBI::Pager;
  10 use CGI::Untaint;
  11 use strict;
  12
  13 =head1 NAME
  14
  15 Maypole::Model::CDBI - Model class based on Class::DBI
  16
  17 =head1 DESCRIPTION
  18
  19 This is a master model class which uses C<Class::DBI> to do all the hard
  20 work of fetching rows and representing them as objects. It is a good
  21 model to copy if you're replacing it with other database abstraction
  22 modules.
  23
  24 =cut
  25
  26 sub related {
  27     my ($self, $r) = @_;
  28     # Has-many methods; XXX this is a hack
  29     map {to_PL($_)}
  30     grep { exists $r->{config}{ok_tables}{$_} }
  31     map {$_->table}
  32     keys %{shift->__hasa_list || {}}
  33 }
  34
  35 sub do_edit :Exported {
  36     my ($self, $r) = @_;
  37     my $h = CGI::Untaint->new(%{$r->{params}});
  38     my ($obj) = @{$r->objects || []};
  39     if ($obj) {
  40         # We have something to edit
  41         $obj->update_from_cgi($h);
  42     } else {
  43         $obj = $self->create_from_cgi($h);
  44     }
  45     if (my %errors = $obj->cgi_update_errors) {
  46         # Set it up as it was:
  47         $r->{template_args}{cgi_params} = $r->{params};
  48         $r->{template_args}{errors} = \%errors;
  49         $r->{template} = "edit";
  50     } else {
  51         $r->{template} = "view";
  52     }
  53     $r->objects([ $obj ]);
  54 }
  55
  56 sub delete :Exported {
  57     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  58     my ($self, $r) = @_;
  59     $_->SUPER::delete for @{ $r->objects || [] };
  60     $r->objects([ $self->retrieve_all ]);
  61     $r->{template} = "list";
  62 }
  63
  64 sub stringify_column {
  65     my $class = shift;
  66     return ($class->columns("Stringify"),
  67                 (grep { $_ ne "id" } $class->primary_columns),
  68                 (grep { $_ eq "name" } $class->columns)
  69                )[0];
  70 }
  71
  72 sub adopt {
  73     my ($self, $child) = @_;
  74     $child->autoupdate(1);
  75     if (my $col = $child->stringify_column) {
  76         $child->columns( Stringify => $col );
  77     }
  78 }
  79
  80 sub search :Exported {
  81     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  82                                     # A real CDBI search.
  83     my ($self, $r) = @_;
  84     my %fields = map {$_ => 1 } $self->columns;
  85     my $oper = "like"; # For now
  86     my %params = %{$r->{params}};
  87     my %values = map { $_ => {$oper, $params{$_} } }
  88                  grep { $params{$_} and $fields{$_} } keys %params;
  89
  90     $self = $self->do_pager($r);
  91     $r->objects([ %values ? $self->search_where(%values) : $self->retrieve_all ]);
  92     $r->template("list");
  93     $r->{template_args}{search} = 1;
  94 }
  95
  96 sub do_pager {
  97     my ($self, $r) = @_;
  98     if ( my $rows = $r->config->{rows_per_page}) {
  99         return $r->{template_args}{pager} = $self->pager($rows, $r->query->{page});
 100     } else { return $self }
 101 }
 102
 103 sub list :Exported {
 104     my ($self, $r) = @_;
 105     my %ok_columns = map {$_ => 1} $self->columns;
 106     $self = $self->do_pager($r);
 107     my $order;
 108     if ($order = $r->query->{order} and $ok_columns{$order}) {
 109         $r->objects([ $self->retrieve_all_sorted_by( $order.
 110             ($r->query->{o2} eq "desc" && " DESC")
 111         )]);
 112     } else {
 113         $r->objects([ $self->retrieve_all ]);
 114     }
 115 }
 116
 117 sub setup_database {
 118     my ($self, $config, $namespace, $dsn, $u, $p) = @_;
 119     $config->{dsn} = $dsn;
 120     $config->{loader} = Class::DBI::Loader->new(
 121         namespace => $namespace,
 122         dsn => $dsn,
 123         user => $u,
 124         password => $p,
 125     );
 126     $config->{classes} = [ $config->{loader}->classes ];
 127     $config->{tables}  = [ $config->{loader}->tables ];
 128 }
 129
 130 sub class_of {
 131     my ($self, $r, $table) = @_;
 132     return $r->config->{loader}->_table2class($table);
 133 }
 134
 135 1;
 136