lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 =cut
  26
  27 sub related {
  28     my ($self, $r) = @_;
  29
  30     # Has-many methods; XXX this is a hack
  31     map {to_PL($_)}
  32     grep { exists $r->{config}{ok_tables}{$_} }
  33     map {$_->table}
  34     keys %{shift->__hasa_list || {}}
  35 }
  36
  37 sub do_edit :Exported {
  38     my ($self, $r) = @_;
  39     my $h = CGI::Untaint->new(%{$r->{params}});
  40     my ($obj) = @{$r->objects || []};
  41     if ($obj) {
  42         # We have something to edit
  43         $obj->update_from_cgi($h);
  44     } else {
  45         $obj = $self->create_from_cgi($h);
  46     }
  47     if (my %errors = $obj->cgi_update_errors) {
  48         # Set it up as it was:
  49         $r->{template_args}{cgi_params} = $r->{params};
  50         $r->{template_args}{errors} = \%errors;
  51         $r->{template} = "edit";
  52     } else {
  53         $r->{template} = "view";
  54     }
  55     $r->objects([ $obj ]);
  56 }
  57
  58 sub delete :Exported {
  59     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  60     my ($self, $r) = @_;
  61     $_->SUPER::delete for @{ $r->objects || [] };
  62     $r->objects([ $self->retrieve_all ]);
  63     $r->{template} = "list";
  64     $self->list($r);
  65 }
  66
  67 sub stringify_column {
  68     my $class = shift;
  69     return ($class->columns("Stringify"),
  70                 (grep { /(name|title)/i } $class->columns),
  71                 (grep { !/id$/i } $class->primary_columns),
  72                )[0];
  73 }
  74
  75 sub adopt {
  76     my ($self, $child) = @_;
  77     $child->autoupdate(1);
  78     if (my $col = $child->stringify_column) {
  79         $child->columns( Stringify => $col );
  80     }
  81 }
  82
  83 sub search :Exported {
  84     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  85                                     # A real CDBI search.
  86     my ($self, $r) = @_;
  87     my %fields = map {$_ => 1 } $self->columns;
  88     my $oper = "like"; # For now
  89     my %params = %{$r->{params}};
  90     my %values = map { $_ => {$oper, $params{$_} } }
  91                  grep { $params{$_} and $fields{$_} } keys %params;
  92
  93     $r->template("list");
  94     if (!%values) { return $self->list($r) }
  95     my $order = $self->order($r);
  96     $self = $self->do_pager($r);
  97     $r->objects([ $self->search_where(\%values),
  98                   ($order ? { order => $order } : ())
  99                 ]);
 100     $r->{template_args}{search} = 1;
 101 }
 102
 103 sub do_pager {
 104     my ($self, $r) = @_;
 105     if ( my $rows = $r->config->{rows_per_page}) {
 106         return $r->{template_args}{pager} = $self->pager($rows, $r->query->{page});
 107     } else { return $self }
 108 }
 109
 110 sub order {
 111     my ($self, $r) = @_;
 112     my $order;
 113     my %ok_columns = map {$_ => 1} $self->columns;
 114     if ($order = $r->query->{order} and $ok_columns{$order}) {
 115        $order .= ($r->query->{o2} eq "desc" && " DESC")
 116     }
 117     $order;
 118 }
 119
 120 sub list :Exported {
 121     my ($self, $r) = @_;
 122     my $order = $self->order($r);
 123     $self = $self->do_pager($r);
 124     if ($order) {
 125         $r->objects([ $self->retrieve_all_sorted_by( $order )]);
 126     } else {
 127         $r->objects([ $self->retrieve_all ]);
 128     }
 129 }
 130
 131 sub setup_database {
 132     my ($self, $config, $namespace, $dsn, $u, $p) = @_;
 133     $config->{dsn} = $dsn;
 134     $config->{loader} = Class::DBI::Loader->new(
 135         namespace => $namespace,
 136         dsn => $dsn,
 137         user => $u,
 138         password => $p,
 139     );
 140     $config->{classes} = [ $config->{loader}->classes ];
 141     $config->{tables}  = [ $config->{loader}->tables ];
 142 }
 143
 144 sub class_of {
 145     my ($self, $r, $table) = @_;
 146     return $r->config->{loader}->_table2class($table);
 147 }
 148
 149 1;
 150