lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 =cut
  26
  27 sub related {
  28     my ($self, $r) = @_;
  29     return keys %{$self->meta_info('has_many') || {}};
  30 }
  31
  32 sub do_edit :Exported {
  33     my ($self, $r) = @_;
  34     my $h = CGI::Untaint->new(%{$r->{params}});
  35     my $creating = 0;
  36     my ($obj) = @{$r->objects || []};
  37     if ($obj) {
  38         # We have something to edit
  39         $obj->update_from_cgi($h => {
  40            required => $r->{config}{$r->{table}}{required_cols} || [],
  41                                     });
  42     } else {
  43         $obj = $self->create_from_cgi($h => {
  44            required => $r->{config}{$r->{table}}{required_cols} || [],
  45                                     });
  46         $creating++;
  47     }
  48     if (my %errors = $obj->cgi_update_errors) {
  49         # Set it up as it was:
  50         $r->{template_args}{cgi_params} = $r->{params};
  51         $r->{template_args}{errors} = \%errors;
  52         $r->{template} = "edit";
  53         undef $obj if $creating; # Couldn't create
  54     } else {
  55         $r->{template} = "view";
  56     }
  57     $r->objects([ $obj ]);
  58 }
  59
  60 sub delete :Exported {
  61     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  62     my ($self, $r) = @_;
  63     $_->SUPER::delete for @{ $r->objects || [] };
  64     $r->objects([ $self->retrieve_all ]);
  65     $r->{template} = "list";
  66     $self->list($r);
  67 }
  68
  69 sub stringify_column {
  70     my $class = shift;
  71     return ($class->columns("Stringify"),
  72                 (grep { /(name|title)/i } $class->columns),
  73                 (grep { !/id$/i } $class->primary_columns),
  74                )[0];
  75 }
  76
  77 sub adopt {
  78     my ($self, $child) = @_;
  79     $child->autoupdate(1);
  80     if (my $col = $child->stringify_column) {
  81         $child->columns( Stringify => $col );
  82     }
  83 }
  84
  85 sub search :Exported {
  86     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  87                                     # A real CDBI search.
  88     my ($self, $r) = @_;
  89     my %fields = map {$_ => 1 } $self->columns;
  90     my $oper = "like"; # For now
  91     my %params = %{$r->{params}};
  92     my %values = map { $_ => {$oper, $params{$_} } }
  93                  grep { $params{$_} and $fields{$_} } keys %params;
  94
  95     $r->template("list");
  96     if (!%values) { return $self->list($r) }
  97     my $order = $self->order($r);
  98     $self = $self->do_pager($r);
  99     $r->objects([ $self->search_where(\%values),
 100                   ($order ? { order => $order } : ())
 101                 ]);
 102     $r->{template_args}{search} = 1;
 103 }
 104
 105 sub do_pager {
 106     my ($self, $r) = @_;
 107     if ( my $rows = $r->config->{rows_per_page}) {
 108         return $r->{template_args}{pager} = $self->pager($rows, $r->query->{page});
 109     } else { return $self }
 110 }
 111
 112 sub order {
 113     my ($self, $r) = @_;
 114     my $order;
 115     my %ok_columns = map {$_ => 1} $self->columns;
 116     if ($order = $r->query->{order} and $ok_columns{$order}) {
 117        $order .= ($r->query->{o2} eq "desc" && " DESC")
 118     }
 119     $order;
 120 }
 121
 122 sub list :Exported {
 123     my ($self, $r) = @_;
 124     my $order = $self->order($r);
 125     $self = $self->do_pager($r);
 126     if ($order) {
 127         $r->objects([ $self->retrieve_all_sorted_by( $order )]);
 128     } else {
 129         $r->objects([ $self->retrieve_all ]);
 130     }
 131 }
 132
 133 sub setup_database {
 134     my ($self, $config, $namespace, $dsn, $u, $p, $opts) = @_;
 135     $config->{dsn} = $dsn;
 136     $config->{loader} = Class::DBI::Loader->new(
 137         namespace => $namespace,
 138         dsn => $dsn,
 139         user => $u,
 140         password => $p,
 141         options => $opts,
 142     );
 143     $config->{classes} = [ $config->{loader}->classes ];
 144     $config->{tables}  = [ $config->{loader}->tables ];
 145 }
 146
 147 sub class_of {
 148     my ($self, $r, $table) = @_;
 149     return $r->config->{loader}->_table2class($table);
 150 }
 151
 152 1;
 153