lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 =cut
  26
  27 sub related {
  28     my ($self, $r) = @_;
  29     return keys %{$self->meta_info('has_many') || {}};
  30 }
  31
  32 sub do_edit :Exported {
  33     my ($self, $r) = @_;
  34     my $h = CGI::Untaint->new(%{$r->{params}});
  35     my $creating = 0;
  36     my ($obj) = @{$r->objects || []};
  37     if ($obj) {
  38         # We have something to edit
  39         $obj->update_from_cgi($h);
  40     } else {
  41         $obj = $self->create_from_cgi($h);
  42         $creating++;
  43     }
  44     if (my %errors = $obj->cgi_update_errors) {
  45         # Set it up as it was:
  46         $r->{template_args}{cgi_params} = $r->{params};
  47         $r->{template_args}{errors} = \%errors;
  48         $r->{template} = "edit";
  49         undef $obj if $creating; # Couldn't create
  50     } else {
  51         $r->{template} = "view";
  52     }
  53     $r->objects([ $obj ]);
  54 }
  55
  56 sub delete :Exported {
  57     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  58     my ($self, $r) = @_;
  59     $_->SUPER::delete for @{ $r->objects || [] };
  60     $r->objects([ $self->retrieve_all ]);
  61     $r->{template} = "list";
  62     $self->list($r);
  63 }
  64
  65 sub stringify_column {
  66     my $class = shift;
  67     return ($class->columns("Stringify"),
  68                 (grep { /(name|title)/i } $class->columns),
  69                 (grep { !/id$/i } $class->primary_columns),
  70                )[0];
  71 }
  72
  73 sub adopt {
  74     my ($self, $child) = @_;
  75     $child->autoupdate(1);
  76     if (my $col = $child->stringify_column) {
  77         $child->columns( Stringify => $col );
  78     }
  79 }
  80
  81 sub search :Exported {
  82     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  83                                     # A real CDBI search.
  84     my ($self, $r) = @_;
  85     my %fields = map {$_ => 1 } $self->columns;
  86     my $oper = "like"; # For now
  87     my %params = %{$r->{params}};
  88     my %values = map { $_ => {$oper, $params{$_} } }
  89                  grep { $params{$_} and $fields{$_} } keys %params;
  90
  91     $r->template("list");
  92     if (!%values) { return $self->list($r) }
  93     my $order = $self->order($r);
  94     $self = $self->do_pager($r);
  95     $r->objects([ $self->search_where(\%values),
  96                   ($order ? { order => $order } : ())
  97                 ]);
  98     $r->{template_args}{search} = 1;
  99 }
 100
 101 sub do_pager {
 102     my ($self, $r) = @_;
 103     if ( my $rows = $r->config->{rows_per_page}) {
 104         return $r->{template_args}{pager} = $self->pager($rows, $r->query->{page});
 105     } else { return $self }
 106 }
 107
 108 sub order {
 109     my ($self, $r) = @_;
 110     my $order;
 111     my %ok_columns = map {$_ => 1} $self->columns;
 112     if ($order = $r->query->{order} and $ok_columns{$order}) {
 113        $order .= ($r->query->{o2} eq "desc" && " DESC")
 114     }
 115     $order;
 116 }
 117
 118 sub list :Exported {
 119     my ($self, $r) = @_;
 120     my $order = $self->order($r);
 121     $self = $self->do_pager($r);
 122     if ($order) {
 123         $r->objects([ $self->retrieve_all_sorted_by( $order )]);
 124     } else {
 125         $r->objects([ $self->retrieve_all ]);
 126     }
 127 }
 128
 129 sub setup_database {
 130     my ($self, $config, $namespace, $dsn, $u, $p, $opts) = @_;
 131     $config->{dsn} = $dsn;
 132     $config->{loader} = Class::DBI::Loader->new(
 133         namespace => $namespace,
 134         dsn => $dsn,
 135         user => $u,
 136         password => $p,
 137         options => $opts,
 138     );
 139     $config->{classes} = [ $config->{loader}->classes ];
 140     $config->{tables}  = [ $config->{loader}->tables ];
 141 }
 142
 143 sub class_of {
 144     my ($self, $r, $table) = @_;
 145     return $r->config->{loader}->_table2class($table);
 146 }
 147
 148 1;
 149