lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Lingua::EN::Inflect::Number qw(to_PL);
   4 use Class::DBI::AsForm;
   5 use Class::DBI::FromCGI;
   6 use Class::DBI::Loader;
   7 use Class::DBI::AbstractSearch;
   8 use Class::DBI::Plugin::RetrieveAll;
   9 use Class::DBI::Pager;
  10 use CGI::Untaint;
  11 use strict;
  12
  13 =head1 NAME
  14
  15 Maypole::Model::CDBI - Model class based on Class::DBI
  16
  17 =head1 DESCRIPTION
  18
  19 This is a master model class which uses C<Class::DBI> to do all the hard
  20 work of fetching rows and representing them as objects. It is a good
  21 model to copy if you're replacing it with other database abstraction
  22 modules.
  23
  24 =cut
  25
  26 sub related {
  27     my ($self, $r) = @_;
  28     # Has-many methods; XXX this is a hack
  29     map {to_PL($_)}
  30     grep { exists $r->{config}{ok_tables}{$_} }
  31     map {$_->table}
  32     keys %{shift->__hasa_list || {}}
  33 }
  34
  35 sub do_edit :Exported {
  36     my ($self, $r) = @_;
  37     my $h = CGI::Untaint->new(%{$r->{params}});
  38     my ($obj) = @{$r->objects || []};
  39     if ($obj) {
  40         # We have something to edit
  41         $obj->update_from_cgi($h);
  42         warn "Updating an object ($obj) with ".Dumper($h); use Data::Dumper;
  43     } else {
  44         $obj = $self->create_from_cgi($h);
  45     }
  46     if (my %errors = $obj->cgi_update_errors) {
  47         # Set it up as it was:
  48         warn "There were errors: ".Dumper(\%errors)."\n";
  49         $r->{template_args}{cgi_params} = $r->{params};
  50         $r->{template_args}{errors} = \%errors;
  51         $r->{template} = "edit";
  52     } else {
  53         $r->{template} = "view";
  54     }
  55     $r->objects([ $obj ]);
  56 }
  57
  58 sub delete :Exported {
  59     my ($self, $r) = @_;
  60     $_->SUPER::delete for @{ $r->objects || [] };
  61     $r->objects([ $self->retrieve_all ]);
  62     $r->{template} = "list";
  63 }
  64
  65 sub adopt {
  66     my ($self, $child) = @_;
  67     $child->autoupdate(1);
  68     if (grep { $_ eq "name" } $child->columns) { # Common case
  69         $child->columns( Stringify => qw/ name / );
  70     } # Otherwise, work it out for yourself.
  71 }
  72
  73 sub search :Exported {
  74     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  75                                     # A real CDBI search.
  76     my ($self, $r) = @_;
  77     my %fields = map {$_ => 1 } $self->columns;
  78     my $oper = "like"; # For now
  79     use Carp; Carp::confess("Urgh") unless ref $r;
  80     my %params = %{$r->{params}};
  81     my %values = map { $_ => {$oper, $params{$_} } }
  82                  grep { $params{$_} and $fields{$_} } keys %params;
  83
  84     $r->objects([ %values ? $self->search_where(%values) : $self->retrieve_all ]);
  85     $r->template("list");
  86     $r->{template_args}{search} = 1;
  87 }
  88
  89 sub list :Exported {
  90     my ($self, $r) = @_;
  91     my %ok_columns = map {$_ => 1} $self->columns;
  92     if ( my $rows = $r->config->{rows_per_page}) {
  93         $self = $self->pager($rows, $r->query->{page});
  94         $r->{template_args}{pager} = $self;
  95     }
  96     my $order;
  97     if ($order = $r->query->{order} and $ok_columns{$order}) {
  98         $r->objects([ $self->retrieve_all_sorted_by( $order.
  99             ($r->query->{o2} eq "desc" && " DESC")
 100         )]);
 101     } else {
 102         $r->objects([ $self->retrieve_all ]);
 103     }
 104 }
 105
 106 sub setup_database {
 107     my ($self, $config, $namespace, $dsn, $u, $p) = @_;
 108     $config->{dsn} = $dsn;
 109     $config->{loader} = Class::DBI::Loader->new(
 110         namespace => $namespace,
 111         dsn => $dsn,
 112         user => $u,
 113         password => $p,
 114     );
 115     $config->{classes} = [ $config->{loader}->classes ];
 116     $config->{tables}  = [ $config->{loader}->tables ];
 117 }
 118
 119 sub class_of {
 120     my ($self, $r, $table) = @_;
 121     return $r->config->{loader}->_table2class($table);
 122 }
 123
 124 1;
 125