lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 =cut
  26
  27 sub related {
  28     my ($self, $r) = @_;
  29     # Has-many methods; XXX this is a hack
  30     map {to_PL($_)}
  31     grep { exists $r->{config}{ok_tables}{$_} }
  32     map {$_->table}
  33     keys %{shift->__hasa_list || {}}
  34 }
  35
  36 sub do_edit :Exported {
  37     my ($self, $r) = @_;
  38     my $h = CGI::Untaint->new(%{$r->{params}});
  39     my ($obj) = @{$r->objects || []};
  40     if ($obj) {
  41         # We have something to edit
  42         $obj->update_from_cgi($h);
  43     } else {
  44         $obj = $self->create_from_cgi($h);
  45     }
  46     if (my %errors = $obj->cgi_update_errors) {
  47         # Set it up as it was:
  48         $r->{template_args}{cgi_params} = $r->{params};
  49         $r->{template_args}{errors} = \%errors;
  50         $r->{template} = "edit";
  51     } else {
  52         $r->{template} = "view";
  53     }
  54     $r->objects([ $obj ]);
  55 }
  56
  57 sub delete :Exported {
  58     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  59     my ($self, $r) = @_;
  60     $_->SUPER::delete for @{ $r->objects || [] };
  61     $r->objects([ $self->retrieve_all ]);
  62     $r->{template} = "list";
  63     $self->list($r);
  64 }
  65
  66 sub stringify_column {
  67     my $class = shift;
  68     return ($class->columns("Stringify"),
  69                 (grep { $_ ne "id" } $class->primary_columns),
  70                 (grep { $_ eq "name" } $class->columns)
  71                )[0];
  72 }
  73
  74 sub adopt {
  75     my ($self, $child) = @_;
  76     $child->autoupdate(1);
  77     if (my $col = $child->stringify_column) {
  78         $child->columns( Stringify => $col );
  79     }
  80 }
  81
  82 sub search :Exported {
  83     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  84                                     # A real CDBI search.
  85     my ($self, $r) = @_;
  86     my %fields = map {$_ => 1 } $self->columns;
  87     my $oper = "like"; # For now
  88     my %params = %{$r->{params}};
  89     my %values = map { $_ => {$oper, $params{$_} } }
  90                  grep { $params{$_} and $fields{$_} } keys %params;
  91
  92     $r->template("list");
  93     if (!%values) { return $self->list($r) }
  94     my $order = $self->order($r);
  95     $self = $self->do_pager($r);
  96     $r->objects([ $self->search_where(\%values),
  97                   ($order ? { order => $order } : ())
  98                 ]);
  99     $r->{template_args}{search} = 1;
 100 }
 101
 102 sub do_pager {
 103     my ($self, $r) = @_;
 104     if ( my $rows = $r->config->{rows_per_page}) {
 105         return $r->{template_args}{pager} = $self->pager($rows, $r->query->{page});
 106     } else { return $self }
 107 }
 108
 109 sub order {
 110     my ($self, $r) = @_;
 111     my $order;
 112     my %ok_columns = map {$_ => 1} $self->columns;
 113     if ($order = $r->query->{order} and $ok_columns{$order}) {
 114        $order .= ($r->query->{o2} eq "desc" && " DESC")
 115     }
 116     $order;
 117 }
 118
 119 sub list :Exported {
 120     my ($self, $r) = @_;
 121     my $order = $self->order($r);
 122     $self = $self->do_pager($r);
 123     if ($order) {
 124         $r->objects([ $self->retrieve_all_sorted_by( $order )]);
 125     } else {
 126         $r->objects([ $self->retrieve_all ]);
 127     }
 128 }
 129
 130 sub setup_database {
 131     my ($self, $config, $namespace, $dsn, $u, $p) = @_;
 132     $config->{dsn} = $dsn;
 133     $config->{loader} = Class::DBI::Loader->new(
 134         namespace => $namespace,
 135         dsn => $dsn,
 136         user => $u,
 137         password => $p,
 138     );
 139     $config->{classes} = [ $config->{loader}->classes ];
 140     $config->{tables}  = [ $config->{loader}->tables ];
 141 }
 142
 143 sub class_of {
 144     my ($self, $r, $table) = @_;
 145     return $r->config->{loader}->_table2class($table);
 146 }
 147
 148 1;
 149