lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 =cut
  26
  27 sub related {
  28     my ($self, $r) = @_;
  29
  30     # Has-many methods; XXX this is a hack
  31     map {to_PL($_)}
  32     grep { exists $r->{config}{ok_tables}{$_} }
  33     map {$_->table}
  34     keys %{shift->__hasa_list || {}}
  35 }
  36
  37 sub do_edit :Exported {
  38     my ($self, $r) = @_;
  39     my $h = CGI::Untaint->new(%{$r->{params}});
  40     my $creating = 0;
  41     my ($obj) = @{$r->objects || []};
  42     if ($obj) {
  43         # We have something to edit
  44         $obj->update_from_cgi($h);
  45     } else {
  46         $obj = $self->create_from_cgi($h);
  47         $creating++;
  48     }
  49     if (my %errors = $obj->cgi_update_errors) {
  50         # Set it up as it was:
  51         $r->{template_args}{cgi_params} = $r->{params};
  52         $r->{template_args}{errors} = \%errors;
  53         $r->{template} = "edit";
  54         undef $obj if $creating; # Couldn't create
  55     } else {
  56         $r->{template} = "view";
  57     }
  58     $r->objects([ $obj ]);
  59 }
  60
  61 sub delete :Exported {
  62     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  63     my ($self, $r) = @_;
  64     $_->SUPER::delete for @{ $r->objects || [] };
  65     $r->objects([ $self->retrieve_all ]);
  66     $r->{template} = "list";
  67     $self->list($r);
  68 }
  69
  70 sub stringify_column {
  71     my $class = shift;
  72     return ($class->columns("Stringify"),
  73                 (grep { /(name|title)/i } $class->columns),
  74                 (grep { !/id$/i } $class->primary_columns),
  75                )[0];
  76 }
  77
  78 sub adopt {
  79     my ($self, $child) = @_;
  80     $child->autoupdate(1);
  81     if (my $col = $child->stringify_column) {
  82         $child->columns( Stringify => $col );
  83     }
  84 }
  85
  86 sub search :Exported {
  87     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  88                                     # A real CDBI search.
  89     my ($self, $r) = @_;
  90     my %fields = map {$_ => 1 } $self->columns;
  91     my $oper = "like"; # For now
  92     my %params = %{$r->{params}};
  93     my %values = map { $_ => {$oper, $params{$_} } }
  94                  grep { $params{$_} and $fields{$_} } keys %params;
  95
  96     $r->template("list");
  97     if (!%values) { return $self->list($r) }
  98     my $order = $self->order($r);
  99     $self = $self->do_pager($r);
 100     $r->objects([ $self->search_where(\%values),
 101                   ($order ? { order => $order } : ())
 102                 ]);
 103     $r->{template_args}{search} = 1;
 104 }
 105
 106 sub do_pager {
 107     my ($self, $r) = @_;
 108     if ( my $rows = $r->config->{rows_per_page}) {
 109         return $r->{template_args}{pager} = $self->pager($rows, $r->query->{page});
 110     } else { return $self }
 111 }
 112
 113 sub order {
 114     my ($self, $r) = @_;
 115     my $order;
 116     my %ok_columns = map {$_ => 1} $self->columns;
 117     if ($order = $r->query->{order} and $ok_columns{$order}) {
 118        $order .= ($r->query->{o2} eq "desc" && " DESC")
 119     }
 120     $order;
 121 }
 122
 123 sub list :Exported {
 124     my ($self, $r) = @_;
 125     my $order = $self->order($r);
 126     $self = $self->do_pager($r);
 127     if ($order) {
 128         $r->objects([ $self->retrieve_all_sorted_by( $order )]);
 129     } else {
 130         $r->objects([ $self->retrieve_all ]);
 131     }
 132 }
 133
 134 sub setup_database {
 135     my ($self, $config, $namespace, $dsn, $u, $p) = @_;
 136     $config->{dsn} = $dsn;
 137     $config->{loader} = Class::DBI::Loader->new(
 138         namespace => $namespace,
 139         dsn => $dsn,
 140         user => $u,
 141         password => $p,
 142     );
 143     $config->{classes} = [ $config->{loader}->classes ];
 144     $config->{tables}  = [ $config->{loader}->tables ];
 145 }
 146
 147 sub class_of {
 148     my ($self, $r, $table) = @_;
 149     return $r->config->{loader}->_table2class($table);
 150 }
 151
 152 1;
 153