lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses L<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =item fetch_objects
  43
  44 =back
  45
  46 =head1 Additional Actions
  47
  48 =over
  49
  50 =item delete
  51
  52 Unsuprisingly, this command causes a database record to be forever lost.
  53
  54 =item search
  55
  56 The search action
  57
  58 =back
  59
  60 =head1 Helper Methods
  61
  62 =over
  63
  64 =item order
  65
  66 =item stringify_column
  67
  68 =item do_pager
  69
  70 =item related_class
  71
  72 Given an accessor name as a method, this function returns the class this accessor returns.
  73
  74 =back
  75
  76 =cut
  77
  78 sub related {
  79     my ( $self, $r ) = @_;
  80     return keys %{ $self->meta_info('has_many') || {} };
  81 }
  82
  83 sub related_class {
  84     my ( $self, $r, $accessor ) = @_;
  85
  86     my $related = $self->meta_info( has_many => $accessor ) ||
  87                   $self->meta_info( has_a    => $accessor ) ||
  88                   return;
  89
  90     my $mapping = $related->{args}->{mapping};
  91     if ( @$mapping ) {
  92         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  93           ->{foreign_class};
  94     }
  95     else {
  96         return $related->{foreign_class};
  97     }
  98 }
  99
 100 sub do_edit : Exported {
 101     my ( $self, $r ) = @_;
 102     my $h        = CGI::Untaint->new( %{ $r->{params} } );
 103     my $creating = 0;
 104     my ($obj) = @{ $r->objects || [] };
 105     my $fatal;
 106     if ($obj) {
 107         # We have something to edit
 108         eval {
 109             $obj->update_from_cgi( $h =>
 110                 { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 111             );
 112         };
 113         $fatal = $@;
 114     }
 115     else {
 116         eval {
 117             $obj =
 118                 $self->create_from_cgi( $h =>
 119                     { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 120             );
 121         };
 122         if ($fatal = $@) {
 123             warn "$fatal" if $r->debug;
 124         }
 125         $creating++;
 126     }
 127     if ( my %errors = $fatal ? (FATAL => $fatal) : $obj->cgi_update_errors ) {
 128
 129         # Set it up as it was:
 130         $r->{template_args}{cgi_params} = $r->{params};
 131         $r->{template_args}{errors}     = \%errors;
 132
 133         undef $obj if $creating;
 134         $r->template("edit");
 135     }
 136     else {
 137         $r->{template} = "view";
 138     }
 139     $r->objects( $obj ? [$obj] : []);
 140 }
 141
 142 sub delete : Exported {
 143     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 144     my ( $self, $r ) = @_;
 145     $_->SUPER::delete for @{ $r->objects || [] };
 146     $r->objects( [ $self->retrieve_all ] );
 147     $r->{template} = "list";
 148     $self->list($r);
 149 }
 150
 151 sub stringify_column {
 152     my $class = shift;
 153     return (
 154         $class->columns("Stringify"),
 155         ( grep { /^(name|title)$/i } $class->columns ),
 156         ( grep { /(name|title)/i } $class->columns ),
 157         ( grep { !/id$/i } $class->primary_columns ),
 158     )[0];
 159 }
 160
 161 sub adopt {
 162     my ( $self, $child ) = @_;
 163     $child->autoupdate(1);
 164     if ( my $col = $child->stringify_column ) {
 165         $child->columns( Stringify => $col );
 166     }
 167 }
 168
 169 sub search : Exported {
 170     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 171
 172     # A real CDBI search.
 173     my ( $self, $r ) = @_;
 174     my %fields = map { $_ => 1 } $self->columns;
 175     my $oper   = "like";                                # For now
 176     my %params = %{ $r->{params} };
 177     my %values = map { $_ => { $oper, $params{$_} } }
 178       grep { defined $params{$_} && length ($params{$_}) && $fields{$_} }
 179       keys %params;
 180
 181     $r->template("list");
 182     if ( !%values ) { return $self->list($r) }
 183     my $order = $self->order($r);
 184     $self = $self->do_pager($r);
 185     $r->objects(
 186         [
 187             $self->search_where(
 188                 \%values, ( $order ? { order_by => $order } : () )
 189             )
 190         ]
 191     );
 192     $r->{template_args}{search} = 1;
 193 }
 194
 195 sub do_pager {
 196     my ( $self, $r ) = @_;
 197     if ( my $rows = $r->config->rows_per_page ) {
 198         return $r->{template_args}{pager} =
 199           $self->pager( $rows, $r->query->{page} );
 200     }
 201     else { return $self }
 202 }
 203
 204 sub order {
 205     my ( $self, $r ) = @_;
 206     my %ok_columns = map { $_ => 1 } $self->columns;
 207     my $q = $r->query;
 208     my $order = $q->{order};
 209     return unless $order and $ok_columns{$order};
 210     $order .= ' DESC' if $q->{o2} and $q->{o2} eq 'desc';
 211     return $order;
 212 }
 213
 214 sub list : Exported {
 215     my ( $self, $r ) = @_;
 216     my $order = $self->order($r);
 217     $self = $self->do_pager($r);
 218     if ($order) {
 219         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 220     }
 221     else {
 222         $r->objects( [ $self->retrieve_all ] );
 223     }
 224 }
 225
 226 sub setup_database {
 227     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 228     $dsn  ||= $config->dsn;
 229     $u    ||= $config->user;
 230     $p    ||= $config->pass;
 231     $opts ||= $config->opts;
 232     $config->dsn($dsn);
 233     warn "No DSN set in config" unless $dsn;
 234     $config->loader || $config->loader(
 235         Class::DBI::Loader->new(
 236             namespace => $namespace,
 237             dsn       => $dsn,
 238             user      => $u,
 239             password  => $p,
 240             %$opts,
 241         )
 242     );
 243     $config->{classes} = [ $config->{loader}->classes ];
 244     $config->{tables}  = [ $config->{loader}->tables ];
 245     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 246       if $namespace->debug;
 247 }
 248
 249 sub class_of {
 250     my ( $self, $r, $table ) = @_;
 251     return $r->config->loader->_table2class($table);
 252 }
 253
 254 sub fetch_objects {
 255     my ($class, $r)=@_;
 256     my @pcs = $class->primary_columns;
 257     if ( $#pcs ) {
 258     my %pks;
 259         @pks{@pcs}=(@{$r->{args}});
 260         return $class->retrieve( %pks );
 261     }
 262     return $class->retrieve( $r->{args}->[0] );
 263 }
 264
 265 1;