lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 # use Maypole::Form::CDBI;
   5 use CGI::Untaint;
   6 # use Maypole::Form;
   7
   8 use Class::DBI::FromCGI;
   9 use Class::DBI::Loader;
  10 use Class::DBI::AbstractSearch;
  11 use Class::DBI::Plugin::RetrieveAll;
  12 use Class::DBI::Pager;
  13
  14 use Lingua::EN::Inflect::Number qw(to_PL);
  15
  16 use strict;
  17
  18 =head1 NAME
  19
  20 Maypole::Model::CDBI - Model class based on Class::DBI
  21
  22 =head1 DESCRIPTION
  23
  24 This is a master model class which uses L<Class::DBI> to do all the hard
  25 work of fetching rows and representing them as objects. It is a good
  26 model to copy if you're replacing it with other database abstraction
  27 modules.
  28
  29 It implements a base set of methods required for a Maypole Data Model.
  30 See L<Maypole::Model::Base> for these:
  31
  32 =over 4
  33
  34 =item adopt
  35
  36 =item class_of
  37
  38 =item do_edit
  39
  40 =item list
  41
  42 =item related
  43
  44 =item setup_database
  45
  46 =item fetch_objects
  47
  48 =back
  49
  50 =head1 Additional Actions
  51
  52 =over
  53
  54 =item delete
  55
  56 Unsuprisingly, this command causes a database record to be forever lost.
  57
  58 =item search
  59
  60 The search action
  61
  62 =back
  63
  64 =head1 Helper Methods
  65
  66 =over
  67
  68 =item order
  69
  70 =item stringify_column
  71
  72 =item do_pager
  73
  74 =item related_class
  75
  76 Given an accessor name as a method, this function returns the class this accessor returns.
  77
  78 =back
  79
  80 =cut
  81
  82 sub related {
  83     my ( $self, $r ) = @_;
  84     return keys %{ $self->meta_info('has_many') || {} };
  85 }
  86
  87 sub related_class {
  88     my ( $self, $r, $accessor ) = @_;
  89
  90     my $related = $self->meta_info( has_many => $accessor ) ||
  91                   $self->meta_info( has_a    => $accessor ) ||
  92                   return;
  93
  94     my $mapping = $related->{args}->{mapping} || [];
  95     if ( @$mapping ) {
  96         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  97           ->{foreign_class};
  98     }
  99     else {
 100         return $related->{foreign_class};
 101     }
 102 }
 103
 104 sub do_edit : Exported {
 105     my ( $self, $r ) = @_;
 106     my $h        = CGI::Untaint->new( %{ $r->{params} } );
 107     my $creating = 0;
 108     my ($obj) = @{ $r->objects || [] };
 109     my $fatal;
 110     if ($obj) {
 111         # We have something to edit
 112         eval {
 113             $obj->update_from_cgi( $h =>
 114                 { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 115             );
 116         };
 117         $fatal = $@;
 118     }
 119     else {
 120         eval {
 121             $obj =
 122                 $self->create_from_cgi( $h =>
 123                     { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 124             );
 125         };
 126         if ($fatal = $@) {
 127             warn "$fatal" if $r->debug;
 128         }
 129         $creating++;
 130     }
 131     if ( my %errors = $fatal ? (FATAL => $fatal) : $obj->cgi_update_errors ) {
 132
 133         # Set it up as it was:
 134         $r->{template_args}{cgi_params} = $r->{params};
 135         $r->{template_args}{errors}     = \%errors;
 136
 137         undef $obj if $creating;
 138         $r->template("edit");
 139     }
 140     else {
 141         $r->{template} = "view";
 142     }
 143     $r->objects( $obj ? [$obj] : []);
 144 }
 145
 146 sub delete : Exported {
 147     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 148     my ( $self, $r ) = @_;
 149     $_->SUPER::delete for @{ $r->objects || [] };
 150     $r->objects( [ $self->retrieve_all ] );
 151     $r->{template} = "list";
 152     $self->list($r);
 153 }
 154
 155 sub stringify_column {
 156     my $class = shift;
 157     return (
 158         $class->columns("Stringify"),
 159         ( grep { /^(name|title)$/i } $class->columns ),
 160         ( grep { /(name|title)/i } $class->columns ),
 161         ( grep { !/id$/i } $class->primary_columns ),
 162     )[0];
 163 }
 164
 165 sub adopt {
 166     my ( $self, $child ) = @_;
 167     $child->autoupdate(1);
 168     if ( my $col = $child->stringify_column ) {
 169         $child->columns( Stringify => $col );
 170     }
 171 }
 172
 173 sub search : Exported {
 174     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 175
 176     # A real CDBI search.
 177     my ( $self, $r ) = @_;
 178     my %fields = map { $_ => 1 } $self->columns;
 179     my $oper   = "like";                                # For now
 180     my %params = %{ $r->{params} };
 181     my %values = map { $_ => { $oper, $params{$_} } }
 182       grep { defined $params{$_} && length ($params{$_}) && $fields{$_} }
 183       keys %params;
 184
 185     $r->template("list");
 186     if ( !%values ) { return $self->list($r) }
 187     my $order = $self->order($r);
 188     $self = $self->do_pager($r);
 189     $r->objects(
 190         [
 191             $self->search_where(
 192                 \%values, ( $order ? { order_by => $order } : () )
 193             )
 194         ]
 195     );
 196     $r->{template_args}{search} = 1;
 197 }
 198
 199 sub do_pager {
 200     my ( $self, $r ) = @_;
 201     if ( my $rows = $r->config->rows_per_page ) {
 202         return $r->{template_args}{pager} =
 203           $self->pager( $rows, $r->query->{page} );
 204     }
 205     else { return $self }
 206 }
 207
 208 sub order {
 209     my ( $self, $r ) = @_;
 210     my %ok_columns = map { $_ => 1 } $self->columns;
 211     my $q = $r->query;
 212     my $order = $q->{order};
 213     return unless $order and $ok_columns{$order};
 214     $order .= ' DESC' if $q->{o2} and $q->{o2} eq 'desc';
 215     return $order;
 216 }
 217
 218 sub list : Exported {
 219     my ( $self, $r ) = @_;
 220     my $order = $self->order($r);
 221     $self = $self->do_pager($r);
 222     if ($order) {
 223         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 224     }
 225     else {
 226         $r->objects( [ $self->retrieve_all ] );
 227     }
 228 }
 229
 230 sub setup_database {
 231     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 232     $dsn  ||= $config->dsn;
 233     $u    ||= $config->user;
 234     $p    ||= $config->pass;
 235     $opts ||= $config->opts;
 236     $config->dsn($dsn);
 237     warn "No DSN set in config" unless $dsn;
 238     $config->loader || $config->loader(
 239         Class::DBI::Loader->new(
 240             namespace => $namespace,
 241             dsn       => $dsn,
 242             user      => $u,
 243             password  => $p,
 244             %$opts,
 245         )
 246     );
 247     $config->{classes} = [ $config->{loader}->classes ];
 248     $config->{tables}  = [ $config->{loader}->tables ];
 249     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 250       if $namespace->debug;
 251 }
 252
 253 sub class_of {
 254     my ( $self, $r, $table ) = @_;
 255     return $r->config->loader->_table2class($table);
 256 }
 257
 258 sub fetch_objects {
 259     my ($class, $r)=@_;
 260     my @pcs = $class->primary_columns;
 261     if ( $#pcs ) {
 262     my %pks;
 263         @pks{@pcs}=(@{$r->{args}});
 264         return $class->retrieve( %pks );
 265     }
 266     return $class->retrieve( $r->{args}->[0] );
 267 }
 268
 269 1;