lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =back
  43
  44 =head1 Additional Commands
  45
  46 =over
  47
  48 =item delete
  49
  50 Surprisingly, this command causes a database record to be forever lost.
  51
  52 =item search
  53
  54 =head1 Helper Methods
  55
  56 =item order
  57
  58 =item stringify_column
  59
  60 =item do_pager
  61
  62 =cut
  63
  64 sub related {
  65     my ( $self, $r ) = @_;
  66     return keys %{ $self->meta_info('has_many') || {} };
  67 }
  68
  69 sub related_class {
  70     my ( $self, $r, $accessor ) = @_;
  71     my $related = $self->related->{$accessor};
  72     if ( my $mapping = $related->{args}->{mapping} ) {
  73         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  74           ->{foreign_class};
  75     }
  76     else {
  77         return $related->{foreign_class};
  78     }
  79 }
  80
  81 sub do_edit : Exported {
  82     my ( $self, $r ) = @_;
  83     my $h        = CGI::Untaint->new( %{ $r->{params} } );
  84     my $creating = 0;
  85     my ($obj) = @{ $r->objects || [] };
  86     if ($obj) {
  87
  88         # We have something to edit
  89         $obj->update_from_cgi( $h =>
  90               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
  91         );
  92     }
  93     else {
  94         $obj =
  95           $self->create_from_cgi( $h =>
  96               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
  97           );
  98         $creating++;
  99     }
 100     if ( my %errors = $obj->cgi_update_errors ) {
 101
 102         # Set it up as it was:
 103         $r->{template_args}{cgi_params} = $r->{params};
 104         $r->{template_args}{errors}     = \%errors;
 105         $r->{template}                  = "edit";
 106         undef $obj if $creating;    # Couldn't create
 107     }
 108     else {
 109         $r->{template} = "view";
 110     }
 111     $r->objects( [$obj] );
 112 }
 113
 114 sub delete : Exported {
 115     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 116     my ( $self, $r ) = @_;
 117     $_->SUPER::delete for @{ $r->objects || [] };
 118     $r->objects( [ $self->retrieve_all ] );
 119     $r->{template} = "list";
 120     $self->list($r);
 121 }
 122
 123 sub stringify_column {
 124     my $class = shift;
 125     return (
 126         $class->columns("Stringify"),
 127         ( grep { /(name|title)/i } $class->columns ),
 128         ( grep { !/id$/i } $class->primary_columns ),
 129     )[0];
 130 }
 131
 132 sub adopt {
 133     my ( $self, $child ) = @_;
 134     $child->autoupdate(1);
 135     if ( my $col = $child->stringify_column ) {
 136         $child->columns( Stringify => $col );
 137     }
 138 }
 139
 140 sub search : Exported {
 141     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 142
 143     # A real CDBI search.
 144     my ( $self, $r ) = @_;
 145     my %fields = map { $_ => 1 } $self->columns;
 146     my $oper   = "like";                                # For now
 147     my %params = %{ $r->{params} };
 148     my %values = map { $_ => { $oper, $params{$_} } }
 149       grep { defined $params{$_} and $fields{$_} } keys %params;
 150
 151     $r->template("list");
 152     if ( !%values ) { return $self->list($r) }
 153     my $order = $self->order($r);
 154     $self = $self->do_pager($r);
 155     $r->objects(
 156         [
 157             $self->search_where(
 158                 \%values, ( $order ? { order => $order } : () )
 159             )
 160         ]
 161     );
 162     $r->{template_args}{search} = 1;
 163 }
 164
 165 sub do_pager {
 166     my ( $self, $r ) = @_;
 167     if ( my $rows = $r->config->rows_per_page ) {
 168         return $r->{template_args}{pager} =
 169           $self->pager( $rows, $r->query->{page} );
 170     }
 171     else { return $self }
 172 }
 173
 174 sub order {
 175     my ( $self, $r ) = @_;
 176     my $order;
 177     my %ok_columns = map { $_ => 1 } $self->columns;
 178     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 179         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 180     }
 181     $order;
 182 }
 183
 184 sub list : Exported {
 185     my ( $self, $r ) = @_;
 186     my $order = $self->order($r);
 187     $self = $self->do_pager($r);
 188     if ($order) {
 189         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 190     }
 191     else {
 192         $r->objects( [ $self->retrieve_all ] );
 193     }
 194 }
 195
 196 sub setup_database {
 197     my ( $self, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 198     $dsn  ||= $config->dsn;
 199     $u    ||= $config->user;
 200     $p    ||= $config->pass;
 201     $opts ||= $config->opts;
 202     $config->dsn($dsn);
 203     $config->loader || $config->loader(
 204         Class::DBI::Loader->new(
 205             namespace => $namespace,
 206             dsn       => $dsn,
 207             user      => $u,
 208             password  => $p,
 209             options   => $opts,
 210         )
 211     );
 212     $config->{classes} = [ $config->{loader}->classes ];
 213     $config->{tables}  = [ $config->{loader}->tables ];
 214 }
 215
 216 sub class_of {
 217     my ( $self, $r, $table ) = @_;
 218     return $r->config->loader->_table2class($table);
 219 }
 220
 221 1;
 222