lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 # use Maypole::Form::CDBI;
   5 use CGI::Untaint;
   6 # use Maypole::Form;
   7
   8 use Class::DBI::FromCGI;
   9 use Class::DBI::Loader;
  10 use Class::DBI::AbstractSearch;
  11 use Class::DBI::Plugin::RetrieveAll;
  12 use Class::DBI::Pager;
  13
  14 use Lingua::EN::Inflect::Number qw(to_PL);
  15
  16 use strict;
  17
  18 =head1 NAME
  19
  20 Maypole::Model::CDBI - Model class based on Class::DBI
  21
  22 =head1 DESCRIPTION
  23
  24 This is a master model class which uses L<Class::DBI> to do all the hard
  25 work of fetching rows and representing them as objects. It is a good
  26 model to copy if you're replacing it with other database abstraction
  27 modules.
  28
  29 It implements a base set of methods required for a Maypole Data Model.
  30 See L<Maypole::Model::Base> for these:
  31
  32 =over 4
  33
  34 =item adopt
  35
  36 =item class_of
  37
  38 =item do_edit
  39
  40 =item list
  41
  42 =item related
  43
  44 =item setup_database
  45
  46 =item fetch_objects
  47
  48 =back
  49
  50 =head1 Additional Actions
  51
  52 =over
  53
  54 =item delete
  55
  56 Unsuprisingly, this command causes a database record to be forever lost.
  57
  58 =item search
  59
  60 The search action
  61
  62 =back
  63
  64 =head1 Helper Methods
  65
  66 =over
  67
  68 =item order
  69
  70 =item stringify_column
  71
  72 =item do_pager
  73
  74 =item related_class
  75
  76 Given an accessor name as a method, this function returns the class this accessor returns.
  77
  78 =back
  79
  80 =cut
  81
  82 sub related {
  83     my ( $self, $r ) = @_;
  84     return keys %{ $self->meta_info('has_many') || {} };
  85 }
  86
  87 sub related_class {
  88      my ( $self, $r, $accessor ) = @_;
  89      my $meta = $self->meta_info;
  90      my @rels = keys %$meta;
  91      my $related;
  92      foreach (@rels) {
  93          $related = $meta->{$_}{$accessor};
  94          last if $related;
  95      }
  96      return unless $related;
  97
  98      my $mapping = $related->{args}->{mapping};
  99      if ( $mapping and @$mapping ) {
 100        return $related->{foreign_class}->meta_info('has_a')->{$$mapping[0]}->{foreign_class};
 101      }
 102      else {
 103          return $related->{foreign_class};
 104      }
 105  }
 106
 107
 108 sub do_edit : Exported
 109 {
 110     my ($self, $r, $obj) = @_;
 111
 112     my $config   = $r->config;
 113     my $table    = $r->table;
 114
 115     my $required_cols = $config->{$table}->{required_cols} || [];
 116
 117     ($obj, my $fatal, my $creating) = $self->_do_update_or_create($r, $obj, $required_cols);
 118
 119     # handle errors, if none, proceed to view the newly created/updated object
 120     my %errors = $fatal ? (FATAL => $fatal) : $obj->cgi_update_errors;
 121
 122     if (%errors)
 123     {
 124         # Set it up as it was:
 125         $r->template_args->{cgi_params} = $r->params;
 126         $r->template_args->{errors}     = \%errors;
 127
 128         undef $obj if $creating;
 129         $r->template("edit");
 130     }
 131     else
 132     {
 133         $r->template("view");
 134     }
 135
 136     $r->objects( $obj ? [$obj] : []);
 137 }
 138
 139 # drb - I've (probably temporarily) split this out from do_edit, so it's
 140 # reported by Mp::P::Trace
 141 sub _do_update_or_create
 142 {
 143     my ($self, $r, $obj, $required_cols) = @_;
 144
 145     my $fatal;
 146     my $creating = 0;
 147     my $h = CGI::Untaint->new( %{$r->params} );
 148
 149     # update or create
 150     if ($obj)
 151     {
 152         # We have something to edit
 153         eval { $obj->update_from_cgi( $h => {required => $required_cols} ) };
 154         $fatal = $@;
 155     }
 156     else
 157     {
 158         eval {
 159             $obj = $self->create_from_cgi( $h => {required => $required_cols} )
 160         };
 161
 162         if ($fatal = $@)
 163         {
 164             warn "$fatal" if $r->debug;
 165         }
 166         $creating++;
 167     }
 168
 169     return $obj, $fatal, $creating;
 170 }
 171
 172 sub delete : Exported {
 173     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 174     my ( $self, $r ) = @_;
 175     $_->SUPER::delete for @{ $r->objects || [] };
 176     $r->objects( [ $self->retrieve_all ] );
 177     $r->{template} = "list";
 178     $self->list($r);
 179 }
 180
 181 sub stringify_column {
 182     my $class = shift;
 183     return (
 184         $class->columns("Stringify"),
 185         ( grep { /^(name|title)$/i } $class->columns ),
 186         ( grep { /(name|title)/i } $class->columns ),
 187         ( grep { !/id$/i } $class->primary_columns ),
 188     )[0];
 189 }
 190
 191 sub adopt {
 192     my ( $self, $child ) = @_;
 193     $child->autoupdate(1);
 194     if ( my $col = $child->stringify_column ) {
 195         $child->columns( Stringify => $col );
 196     }
 197 }
 198
 199 sub search : Exported {
 200     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 201
 202     # A real CDBI search.
 203     my ( $self, $r ) = @_;
 204     my %fields = map { $_ => 1 } $self->columns;
 205     my $oper   = "like";                                # For now
 206     my %params = %{ $r->{params} };
 207     my %values = map { $_ => { $oper, $params{$_} } }
 208       grep { defined $params{$_} && length ($params{$_}) && $fields{$_} }
 209       keys %params;
 210
 211     $r->template("list");
 212     if ( !%values ) { return $self->list($r) }
 213     my $order = $self->order($r);
 214     $self = $self->do_pager($r);
 215     $r->objects(
 216         [
 217             $self->search_where(
 218                 \%values, ( $order ? { order_by => $order } : () )
 219             )
 220         ]
 221     );
 222     $r->{template_args}{search} = 1;
 223 }
 224
 225 sub do_pager {
 226     my ( $self, $r ) = @_;
 227     if ( my $rows = $r->config->rows_per_page ) {
 228         return $r->{template_args}{pager} =
 229           $self->pager( $rows, $r->query->{page} );
 230     }
 231     else { return $self }
 232 }
 233
 234 sub order {
 235     my ( $self, $r ) = @_;
 236     my %ok_columns = map { $_ => 1 } $self->columns;
 237     my $q = $r->query;
 238     my $order = $q->{order};
 239     return unless $order and $ok_columns{$order};
 240     $order .= ' DESC' if $q->{o2} and $q->{o2} eq 'desc';
 241     return $order;
 242 }
 243
 244 sub list : Exported {
 245     my ( $self, $r ) = @_;
 246     my $order = $self->order($r);
 247     $self = $self->do_pager($r);
 248     if ($order) {
 249         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 250     }
 251     else {
 252         $r->objects( [ $self->retrieve_all ] );
 253     }
 254 }
 255
 256 sub setup_database {
 257     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 258     $dsn  ||= $config->dsn;
 259     $u    ||= $config->user;
 260     $p    ||= $config->pass;
 261     $opts ||= $config->opts;
 262     $config->dsn($dsn);
 263     warn "No DSN set in config" unless $dsn;
 264     $config->loader || $config->loader(
 265         Class::DBI::Loader->new(
 266             namespace => $namespace,
 267             dsn       => $dsn,
 268             user      => $u,
 269             password  => $p,
 270             %$opts,
 271         )
 272     );
 273     $config->{classes} = [ $config->{loader}->classes ];
 274     $config->{tables}  = [ $config->{loader}->tables ];
 275     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 276       if $namespace->debug;
 277 }
 278
 279 sub class_of {
 280     my ( $self, $r, $table ) = @_;
 281     return $r->config->loader->_table2class($table); # why not find_class ?
 282 }
 283
 284 sub fetch_objects {
 285     my ($class, $r)=@_;
 286     my @pcs = $class->primary_columns;
 287     if ( $#pcs ) {
 288     my %pks;
 289         @pks{@pcs}=(@{$r->{args}});
 290         return $class->retrieve( %pks );
 291     }
 292     return $class->retrieve( $r->{args}->[0] );
 293 }
 294
 295 1;