lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =back
  43
  44 =head1 Additional Commands
  45
  46 =over
  47
  48 =item delete
  49
  50 Surprisingly, this command causes a database record to be forever lost.
  51
  52 =item search
  53
  54 =head1 Helper Methods
  55
  56 =item order
  57
  58 =item stringify_column
  59
  60 =item do_pager
  61
  62 =cut
  63
  64 sub related {
  65     my ( $self, $r ) = @_;
  66     return keys %{ $self->meta_info('has_many') || {} };
  67 }
  68
  69 #sub related_class {
  70 #    my ( $self, $r, $accessor ) = @_;
  71 #    my $related=$self->related->{$accessor};
  72 #    if ( my $mapping=$related->{args}->{mapping} ) {
  73 #       return  $related->{foreign_class}->meta_info('has_a')->{$$mapping[0]}->{foreign_class};
  74 #    } else {
  75 #       return $related->{foreign_class};
  76 #    }
  77 #}
  78
  79 sub do_edit : Exported {
  80     my ( $self, $r ) = @_;
  81     my $h        = CGI::Untaint->new( %{ $r->{params} } );
  82     my $creating = 0;
  83     my ($obj) = @{ $r->objects || [] };
  84     if ($obj) {
  85
  86         # We have something to edit
  87         $obj->update_from_cgi( $h =>
  88               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
  89         );
  90     }
  91     else {
  92         $obj =
  93           $self->create_from_cgi( $h =>
  94               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
  95           );
  96         $creating++;
  97     }
  98     if ( my %errors = $obj->cgi_update_errors ) {
  99
 100         # Set it up as it was:
 101         $r->{template_args}{cgi_params} = $r->{params};
 102         $r->{template_args}{errors}     = \%errors;
 103         $r->{template}                  = "edit";
 104         undef $obj if $creating;    # Couldn't create
 105     }
 106     else {
 107         $r->{template} = "view";
 108     }
 109     $r->objects( [$obj] );
 110 }
 111
 112 sub delete : Exported {
 113     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 114     my ( $self, $r ) = @_;
 115     $_->SUPER::delete for @{ $r->objects || [] };
 116     $r->objects( [ $self->retrieve_all ] );
 117     $r->{template} = "list";
 118     $self->list($r);
 119 }
 120
 121 sub stringify_column {
 122     my $class = shift;
 123     return (
 124         $class->columns("Stringify"),
 125         ( grep { /(name|title)/i } $class->columns ),
 126         ( grep { !/id$/i } $class->primary_columns ),
 127     )[0];
 128 }
 129
 130 sub adopt {
 131     my ( $self, $child ) = @_;
 132     $child->autoupdate(1);
 133     if ( my $col = $child->stringify_column ) {
 134         $child->columns( Stringify => $col );
 135     }
 136 }
 137
 138 sub search : Exported {
 139     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 140
 141     # A real CDBI search.
 142     my ( $self, $r ) = @_;
 143     my %fields = map { $_ => 1 } $self->columns;
 144     my $oper   = "like";                                # For now
 145     my %params = %{ $r->{params} };
 146     my %values = map { $_ => { $oper, $params{$_} } }
 147       grep { $params{$_} and $fields{$_} } keys %params;
 148
 149     $r->template("list");
 150     if ( !%values ) { return $self->list($r) }
 151     my $order = $self->order($r);
 152     $self = $self->do_pager($r);
 153     $r->objects(
 154         [
 155             $self->search_where(
 156                 \%values, ( $order ? { order => $order } : () )
 157             )
 158         ]
 159     );
 160     $r->{template_args}{search} = 1;
 161 }
 162
 163 sub do_pager {
 164     my ( $self, $r ) = @_;
 165     if ( my $rows = $r->config->rows_per_page ) {
 166         return $r->{template_args}{pager} =
 167           $self->pager( $rows, $r->query->{page} );
 168     }
 169     else { return $self }
 170 }
 171
 172 sub order {
 173     my ( $self, $r ) = @_;
 174     my $order;
 175     my %ok_columns = map { $_ => 1 } $self->columns;
 176     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 177         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 178     }
 179     $order;
 180 }
 181
 182 sub list : Exported {
 183     my ( $self, $r ) = @_;
 184     my $order = $self->order($r);
 185     $self = $self->do_pager($r);
 186     if ($order) {
 187         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 188     }
 189     else {
 190         $r->objects( [ $self->retrieve_all ] );
 191     }
 192 }
 193
 194 sub setup_database {
 195     my ( $self, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 196     $dsn  ||= $config->dsn;
 197     $u    ||= $config->user;
 198     $p    ||= $config->pass;
 199     $opts ||= $config->opts;
 200     $config->dsn($dsn);
 201     $config->loader || $config->loader(
 202         Class::DBI::Loader->new(
 203             namespace => $namespace,
 204             dsn       => $dsn,
 205             user      => $u,
 206             password  => $p,
 207             options   => $opts,
 208         )
 209     );
 210     $config->{classes} = [ $config->{loader}->classes ];
 211     $config->{tables}  = [ $config->{loader}->tables ];
 212 }
 213
 214 sub class_of {
 215     my ( $self, $r, $table ) = @_;
 216     return $r->config->loader->_table2class($table);
 217 }
 218
 219 1;
 220