lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses L<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =item fetch_objects
  43
  44 =back
  45
  46 =head1 Additional Actions
  47
  48 =over
  49
  50 =item delete
  51
  52 Unsuprisingly, this command causes a database record to be forever lost.
  53
  54 =item search
  55
  56 The search action
  57
  58 =back
  59
  60 =head1 Helper Methods
  61
  62 =over
  63
  64 =item order
  65
  66 =item stringify_column
  67
  68 =item do_pager
  69
  70 =item related_class
  71
  72 Given an accessor name as a method, this function returns the class this accessor returns.
  73
  74 =back
  75
  76 =cut
  77
  78 sub related {
  79     my ( $self, $r ) = @_;
  80     return keys %{ $self->meta_info('has_many') || {} };
  81 }
  82
  83 sub related_class {
  84     my ( $self, $r, $accessor ) = @_;
  85
  86     my $related = $self->meta_info( has_many => $accessor ) ||
  87                   $self->meta_info( has_a    => $accessor ) ||
  88                   return;
  89
  90     my $mapping = $related->{args}->{mapping};
  91     if ( @$mapping ) {
  92         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  93           ->{foreign_class};
  94     }
  95     else {
  96         return $related->{foreign_class};
  97     }
  98 }
  99
 100 sub do_edit : Exported {
 101     my ( $self, $r ) = @_;
 102     my $h        = CGI::Untaint->new( %{ $r->{params} } );
 103     my $creating = 0;
 104     my ($obj) = @{ $r->objects || [] };
 105     my $fatal;
 106     if ($obj) {
 107         # We have something to edit
 108         eval {
 109             $obj->update_from_cgi( $h =>
 110                 { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 111             );
 112         };
 113         $fatal = $@;
 114     }
 115     else {
 116         eval {
 117             $obj =
 118                 $self->create_from_cgi( $h =>
 119                     { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 120             );
 121         };
 122         $fatal = $@;
 123         $creating++;
 124     }
 125     if ( my %errors = $fatal ? (FATAL => $fatal) : $obj->cgi_update_errors ) {
 126
 127         # Set it up as it was:
 128         $r->{template_args}{cgi_params} = $r->{params};
 129         $r->{template_args}{errors}     = \%errors;
 130
 131         undef $obj if $creating;
 132         $r->template("edit");
 133     }
 134     else {
 135         $r->{template} = "view";
 136     }
 137     $r->objects( [$obj] );
 138 }
 139
 140 sub delete : Exported {
 141     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 142     my ( $self, $r ) = @_;
 143     $_->SUPER::delete for @{ $r->objects || [] };
 144     $r->objects( [ $self->retrieve_all ] );
 145     $r->{template} = "list";
 146     $self->list($r);
 147 }
 148
 149 sub stringify_column {
 150     my $class = shift;
 151     return (
 152         $class->columns("Stringify"),
 153         ( grep { /(name|title)/i } $class->columns ),
 154         ( grep { !/id$/i } $class->primary_columns ),
 155     )[0];
 156 }
 157
 158 sub adopt {
 159     my ( $self, $child ) = @_;
 160     $child->autoupdate(1);
 161     if ( my $col = $child->stringify_column ) {
 162         $child->columns( Stringify => $col );
 163     }
 164 }
 165
 166 sub search : Exported {
 167     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 168
 169     # A real CDBI search.
 170     my ( $self, $r ) = @_;
 171     my %fields = map { $_ => 1 } $self->columns;
 172     my $oper   = "like";                                # For now
 173     my %params = %{ $r->{params} };
 174     my %values = map { $_ => { $oper, $params{$_} } }
 175       grep { defined $params{$_} && length ($params{$_}) && $fields{$_} }
 176       keys %params;
 177
 178     $r->template("list");
 179     if ( !%values ) { return $self->list($r) }
 180     my $order = $self->order($r);
 181     $self = $self->do_pager($r);
 182     $r->objects(
 183         [
 184             $self->search_where(
 185                 \%values, ( $order ? { order_by => $order } : () )
 186             )
 187         ]
 188     );
 189     $r->{template_args}{search} = 1;
 190 }
 191
 192 sub do_pager {
 193     my ( $self, $r ) = @_;
 194     if ( my $rows = $r->config->rows_per_page ) {
 195         return $r->{template_args}{pager} =
 196           $self->pager( $rows, $r->query->{page} );
 197     }
 198     else { return $self }
 199 }
 200
 201 sub order {
 202     my ( $self, $r ) = @_;
 203     my $order;
 204     my %ok_columns = map { $_ => 1 } $self->columns;
 205     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 206         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 207     }
 208     $order;
 209 }
 210
 211 sub list : Exported {
 212     my ( $self, $r ) = @_;
 213     my $order = $self->order($r);
 214     $self = $self->do_pager($r);
 215     if ($order) {
 216         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 217     }
 218     else {
 219         $r->objects( [ $self->retrieve_all ] );
 220     }
 221 }
 222
 223 sub setup_database {
 224     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 225     $dsn  ||= $config->dsn;
 226     $u    ||= $config->user;
 227     $p    ||= $config->pass;
 228     $opts ||= $config->opts;
 229     $config->dsn($dsn);
 230     warn "No DSN set in config" unless $dsn;
 231     $config->loader || $config->loader(
 232         Class::DBI::Loader->new(
 233             namespace => $namespace,
 234             dsn       => $dsn,
 235             user      => $u,
 236             password  => $p,
 237             options   => $opts,
 238         )
 239     );
 240     $config->{classes} = [ $config->{loader}->classes ];
 241     $config->{tables}  = [ $config->{loader}->tables ];
 242     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 243       if $namespace->debug;
 244 }
 245
 246 sub class_of {
 247     my ( $self, $r, $table ) = @_;
 248     return $r->config->loader->_table2class($table);
 249 }
 250
 251 sub fetch_objects {
 252     my ($class, $r)=@_;
 253     my @pcs = $class->primary_columns;
 254     if ( $#pcs ) {
 255     my %pks;
 256         @pks{@pcs}=(@{$r->{args}});
 257         return $class->retrieve( %pks );
 258     }
 259     return $class->retrieve( $r->{args}->[0] );
 260 }
 261
 262 1;