lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =item fetch_objects
  43
  44 =back
  45
  46 =head1 Additional Commands
  47
  48 =over
  49
  50 =item delete
  51
  52 Surprisingly, this command causes a database record to be forever lost.
  53
  54 =item search
  55
  56 The search action
  57
  58 =back
  59
  60 =head1 Helper Methods
  61
  62 =over
  63
  64 =item order
  65
  66 =item stringify_column
  67
  68 =item do_pager
  69
  70 =item related_class
  71
  72 Given an accessor name as a method, this function returns the class this accessor returns.
  73
  74 =back
  75
  76 =cut
  77
  78 sub related {
  79     my ( $self, $r ) = @_;
  80     return keys %{ $self->meta_info('has_many') || {} };
  81 }
  82
  83 sub related_class {
  84     my ( $self, $r, $accessor ) = @_;
  85     my $related = $self->related->{$accessor};
  86     if ( my $mapping = $related->{args}->{mapping} ) {
  87         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  88           ->{foreign_class};
  89     }
  90     else {
  91         return $related->{foreign_class};
  92     }
  93 }
  94
  95 sub do_edit : Exported {
  96     my ( $self, $r ) = @_;
  97     my $h        = CGI::Untaint->new( %{ $r->{params} } );
  98     my $creating = 0;
  99     my ($obj) = @{ $r->objects || [] };
 100     if ($obj) {
 101
 102         # We have something to edit
 103         $obj->update_from_cgi( $h =>
 104               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 105         );
 106     }
 107     else {
 108         $obj =
 109           $self->create_from_cgi( $h =>
 110               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 111           );
 112         $creating++;
 113     }
 114     if ( my %errors = $obj->cgi_update_errors ) {
 115
 116         # Set it up as it was:
 117         $r->{template_args}{cgi_params} = $r->{params};
 118         $r->{template_args}{errors}     = \%errors;
 119         $r->{template}                  = "edit";
 120         undef $obj if $creating;    # Couldn't create
 121     }
 122     else {
 123         $r->{template} = "view";
 124     }
 125     $r->objects( [$obj] );
 126 }
 127
 128 sub delete : Exported {
 129     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 130     my ( $self, $r ) = @_;
 131     $_->SUPER::delete for @{ $r->objects || [] };
 132     $r->objects( [ $self->retrieve_all ] );
 133     $r->{template} = "list";
 134     $self->list($r);
 135 }
 136
 137 sub stringify_column {
 138     my $class = shift;
 139     return (
 140         $class->columns("Stringify"),
 141         ( grep { /(name|title)/i } $class->columns ),
 142         ( grep { !/id$/i } $class->primary_columns ),
 143     )[0];
 144 }
 145
 146 sub adopt {
 147     my ( $self, $child ) = @_;
 148     $child->autoupdate(1);
 149     if ( my $col = $child->stringify_column ) {
 150         $child->columns( Stringify => $col );
 151     }
 152 }
 153
 154 sub search : Exported {
 155     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 156
 157     # A real CDBI search.
 158     my ( $self, $r ) = @_;
 159     my %fields = map { $_ => 1 } $self->columns;
 160     my $oper   = "like";                                # For now
 161     my %params = %{ $r->{params} };
 162     my %values = map { $_ => { $oper, $params{$_} } }
 163       grep { length ($params{$_}) and $fields{$_} } keys %params;
 164
 165     $r->template("list");
 166     if ( !%values ) { return $self->list($r) }
 167     my $order = $self->order($r);
 168     $self = $self->do_pager($r);
 169     $r->objects(
 170         [
 171             $self->search_where(
 172                 \%values, ( $order ? { order_by => $order } : () )
 173             )
 174         ]
 175     );
 176     $r->{template_args}{search} = 1;
 177 }
 178
 179 sub do_pager {
 180     my ( $self, $r ) = @_;
 181     if ( my $rows = $r->config->rows_per_page ) {
 182         return $r->{template_args}{pager} =
 183           $self->pager( $rows, $r->query->{page} );
 184     }
 185     else { return $self }
 186 }
 187
 188 sub order {
 189     my ( $self, $r ) = @_;
 190     my $order;
 191     my %ok_columns = map { $_ => 1 } $self->columns;
 192     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 193         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 194     }
 195     $order;
 196 }
 197
 198 sub list : Exported {
 199     my ( $self, $r ) = @_;
 200     my $order = $self->order($r);
 201     $self = $self->do_pager($r);
 202     if ($order) {
 203         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 204     }
 205     else {
 206         $r->objects( [ $self->retrieve_all ] );
 207     }
 208 }
 209
 210 sub setup_database {
 211     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 212     $dsn  ||= $config->dsn;
 213     $u    ||= $config->user;
 214     $p    ||= $config->pass;
 215     $opts ||= $config->opts;
 216     $config->dsn($dsn);
 217     warn "No DSN set in config" unless $dsn;
 218     $config->loader || $config->loader(
 219         Class::DBI::Loader->new(
 220             namespace => $namespace,
 221             dsn       => $dsn,
 222             user      => $u,
 223             password  => $p,
 224             options   => $opts,
 225         )
 226     );
 227     $config->{classes} = [ $config->{loader}->classes ];
 228     $config->{tables}  = [ $config->{loader}->tables ];
 229     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 230       if $namespace->debug;
 231 }
 232
 233 sub class_of {
 234     my ( $self, $r, $table ) = @_;
 235     return $r->config->loader->_table2class($table);
 236 }
 237
 238 sub fetch_objects {
 239     my ($class,$r)=@_;
 240     my @pcs = $class->primary_columns;
 241     if ( $#pcs ) {
 242         my %pks;
 243         @pks{@pcs}=(@{$r->{args}});
 244         return $class->retrieve( %pks );
 245     }
 246     return $class->retrieve( %$r->{args}->[0] );
 247 }
 248
 249 1;