lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 It implements a base set of methods required for a Maypole Data Model.
  26 See L<Maypole::Model::Base> for these:
  27
  28 =over 4
  29
  30 =item adopt
  31
  32 =item class_of
  33
  34 =item do_edit
  35
  36 =item list
  37
  38 =item related
  39
  40 =item setup_database
  41
  42 =back
  43
  44 =head1 Additional Commands
  45
  46 =over
  47
  48 =item delete
  49
  50 Surprisingly, this command causes a database record to be forever lost.
  51
  52 =item search
  53
  54 The search action
  55
  56 =back
  57
  58 =head1 Helper Methods
  59
  60 =over
  61
  62 =item order
  63
  64 =item stringify_column
  65
  66 =item do_pager
  67
  68 =item related_class
  69
  70 Given an accessor name as a method, this function returns the class this accessor returns.
  71
  72 =back
  73
  74 =cut
  75
  76 sub related {
  77     my ( $self, $r ) = @_;
  78     return keys %{ $self->meta_info('has_many') || {} };
  79 }
  80
  81 sub related_class {
  82     my ( $self, $r, $accessor ) = @_;
  83     my $related = $self->related->{$accessor};
  84     if ( my $mapping = $related->{args}->{mapping} ) {
  85         return $related->{foreign_class}->meta_info('has_a')->{ $$mapping[0] }
  86           ->{foreign_class};
  87     }
  88     else {
  89         return $related->{foreign_class};
  90     }
  91 }
  92
  93 sub do_edit : Exported {
  94     my ( $self, $r ) = @_;
  95     my $h        = CGI::Untaint->new( %{ $r->{params} } );
  96     my $creating = 0;
  97     my ($obj) = @{ $r->objects || [] };
  98     if ($obj) {
  99
 100         # We have something to edit
 101         $obj->update_from_cgi( $h =>
 102               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 103         );
 104     }
 105     else {
 106         $obj =
 107           $self->create_from_cgi( $h =>
 108               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
 109           );
 110         $creating++;
 111     }
 112     if ( my %errors = $obj->cgi_update_errors ) {
 113
 114         # Set it up as it was:
 115         $r->{template_args}{cgi_params} = $r->{params};
 116         $r->{template_args}{errors}     = \%errors;
 117         $r->{template}                  = "edit";
 118         undef $obj if $creating;    # Couldn't create
 119     }
 120     else {
 121         $r->{template} = "view";
 122     }
 123     $r->objects( [$obj] );
 124 }
 125
 126 sub delete : Exported {
 127     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
 128     my ( $self, $r ) = @_;
 129     $_->SUPER::delete for @{ $r->objects || [] };
 130     $r->objects( [ $self->retrieve_all ] );
 131     $r->{template} = "list";
 132     $self->list($r);
 133 }
 134
 135 sub stringify_column {
 136     my $class = shift;
 137     return (
 138         $class->columns("Stringify"),
 139         ( grep { /(name|title)/i } $class->columns ),
 140         ( grep { !/id$/i } $class->primary_columns ),
 141     )[0];
 142 }
 143
 144 sub adopt {
 145     my ( $self, $child ) = @_;
 146     $child->autoupdate(1);
 147     if ( my $col = $child->stringify_column ) {
 148         $child->columns( Stringify => $col );
 149     }
 150 }
 151
 152 sub search : Exported {
 153     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
 154
 155     # A real CDBI search.
 156     my ( $self, $r ) = @_;
 157     my %fields = map { $_ => 1 } $self->columns;
 158     my $oper   = "like";                                # For now
 159     my %params = %{ $r->{params} };
 160     my %values = map { $_ => { $oper, $params{$_} } }
 161       grep { length ($params{$_}) and $fields{$_} } keys %params;
 162
 163     $r->template("list");
 164     if ( !%values ) { return $self->list($r) }
 165     my $order = $self->order($r);
 166     $self = $self->do_pager($r);
 167     $r->objects(
 168         [
 169             $self->search_where(
 170                 \%values, ( $order ? { order_by => $order } : () )
 171             )
 172         ]
 173     );
 174     $r->{template_args}{search} = 1;
 175 }
 176
 177 sub do_pager {
 178     my ( $self, $r ) = @_;
 179     if ( my $rows = $r->config->rows_per_page ) {
 180         return $r->{template_args}{pager} =
 181           $self->pager( $rows, $r->query->{page} );
 182     }
 183     else { return $self }
 184 }
 185
 186 sub order {
 187     my ( $self, $r ) = @_;
 188     my $order;
 189     my %ok_columns = map { $_ => 1 } $self->columns;
 190     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 191         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 192     }
 193     $order;
 194 }
 195
 196 sub list : Exported {
 197     my ( $self, $r ) = @_;
 198     my $order = $self->order($r);
 199     $self = $self->do_pager($r);
 200     if ($order) {
 201         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 202     }
 203     else {
 204         $r->objects( [ $self->retrieve_all ] );
 205     }
 206 }
 207
 208 sub setup_database {
 209     my ( $class, $config, $namespace, $dsn, $u, $p, $opts ) = @_;
 210     $dsn  ||= $config->dsn;
 211     $u    ||= $config->user;
 212     $p    ||= $config->pass;
 213     $opts ||= $config->opts;
 214     $config->dsn($dsn);
 215     warn "No DSN set in config" unless $dsn;
 216     $config->loader || $config->loader(
 217         Class::DBI::Loader->new(
 218             namespace => $namespace,
 219             dsn       => $dsn,
 220             user      => $u,
 221             password  => $p,
 222             options   => $opts,
 223         )
 224     );
 225     $config->{classes} = [ $config->{loader}->classes ];
 226     $config->{tables}  = [ $config->{loader}->tables ];
 227     warn( 'Loaded tables: ' . join ',', @{ $config->{tables} } )
 228       if $namespace->debug;
 229 }
 230
 231 sub class_of {
 232     my ( $self, $r, $table ) = @_;
 233     return $r->config->loader->_table2class($table);
 234 }
 235
 236 1;