lib/CGI/Maypole.pm

   1 package CGI::Maypole;
   2 use base 'Maypole';
   3
   4 use strict;
   5 use warnings;
   6 use CGI::Simple;
   7 use Maypole::Headers;
   8 use Maypole::Constants;
   9
  10 our $VERSION = '2.11';
  11
  12 __PACKAGE__->mk_accessors( qw/cgi/ );
  13
  14 =head1 NAME
  15
  16 CGI::Maypole - CGI-based front-end to Maypole
  17
  18 =head1 SYNOPSIS
  19
  20      package BeerDB;
  21      use Maypole::Application;
  22
  23      ## example beer.cgi:
  24
  25      #!/usr/bin/perl -w
  26      use strict;
  27      use BeerDB;
  28      BeerDB->run();
  29
  30 Now to access the beer database, type this URL into your browser:
  31 http://your.site/cgi-bin/beer.cgi/frontpage
  32
  33 NOTE: this Maypole frontend requires additional modules that won't be installed
  34 or included with Maypole. Please see below.
  35
  36 =head1 DESCRIPTION
  37
  38 This is a CGI platform driver for Maypole. Your application can inherit from
  39 CGI::Maypole directly, but it is recommended that you use
  40 L<Maypole::Application>.
  41
  42 This module requires CGI::Simple which you will have to install yourself via
  43 CPAN or manually.
  44
  45 =head1 METHODS
  46
  47 =over
  48
  49 =item run
  50
  51 Call this from your CGI script to start the Maypole application.
  52
  53 =back
  54
  55 =cut
  56
  57 sub run
  58 {
  59     my $self = shift;
  60     return $self->handler;
  61 }
  62
  63 =head1 Implementation
  64
  65 This class overrides a set of methods in the base Maypole class to provide it's
  66 functionality. See L<Maypole> for these:
  67
  68 =over
  69
  70 =item get_request
  71
  72 =cut
  73
  74 sub get_request
  75 {
  76     shift->cgi( CGI::Simple->new );
  77 }
  78
  79 =item parse_location
  80
  81 =cut
  82
  83 sub parse_location
  84 {
  85     my $r = shift;
  86     my $cgi = $r->cgi;
  87
  88     # Reconstruct the request headers (as far as this is possible)
  89     $r->headers_in(Maypole::Headers->new);
  90     for my $http_header ($cgi->http) {
  91         (my $field_name = $http_header) =~ s/^HTTPS?_//;
  92         $r->headers_in->set($field_name => $cgi->http($http_header));
  93     }
  94
  95     my $path = $cgi->url( -absolute => 1, -path_info => 1 );
  96     my $loc = $cgi->url( -absolute => 1 );
  97     {
  98         no warnings 'uninitialized';
  99         $path .= '/' if $path eq $loc;
 100         $path =~ s/^($loc)?\///;
 101     }
 102     $r->path($path);
 103
 104     $r->parse_path;
 105     $r->parse_args;
 106 }
 107
 108 sub warn {
 109     my ($self,@args) = @_;
 110     my ($package, $line) = (caller)[0,2];
 111     warn "[$package line $line] ", @args ;
 112     return;
 113 }
 114
 115 =item parse_args
 116
 117 =cut
 118
 119 sub parse_args
 120 {
 121     my $r = shift;
 122     my (%vars) = $r->cgi->Vars;
 123     while ( my ( $key, $value ) = each %vars ) {
 124         my @values = split "\0", $value;
 125         $vars{$key} = @values <= 1 ? $values[0] : \@values;
 126     }
 127     $r->params( {%vars} );
 128     $r->query( $r->params );
 129 }
 130
 131 =item redirect_request
 132
 133 =cut
 134
 135 # FIXME: use headers_in to gather host and other information?
 136 sub redirect_request
 137 {
 138   my $r = shift;
 139   my $redirect_url = $_[0];
 140   my $status = "302";
 141   if ($_[1]) {
 142     my %args = @_;
 143     if ($args{url}) {
 144       $redirect_url = $args{url};
 145     } else {
 146       my $path = $args{path} || $r->cgi->url(-absolute => 1, -query=>1);
 147       my $host = $args{domain};
 148       ($host = $r->cgi->url(-base => 1)) =~ s/^https?:\/\///i unless ($host);
 149       my $protocol = $args{protocol} || $r->get_protocol;
 150       $redirect_url = "${protocol}://${host}/${path}";
 151     }
 152     $status = $args{status} if ($args{status});
 153   }
 154
 155   $r->headers_out->set('Status' => $status);
 156   $r->headers_out->set('Location' => $redirect_url);
 157
 158   return;
 159 }
 160
 161 =item get_protocol
 162
 163 =cut
 164
 165 sub get_protocol
 166 {
 167   my $self = shift;
 168   my $protocol = ($self->cgi->https) ? 'https' : 'http';
 169   return $protocol;
 170 }
 171
 172 =item send_output
 173
 174 Generates output (using C<collect_output>) and prints it.
 175
 176 =cut
 177
 178 sub send_output
 179 {
 180     my $r = shift;
 181     print $r->collect_output;
 182 }
 183
 184 =item collect_output
 185
 186 Gathers headers and output together into a string and returns it.
 187
 188 Splitting this code out of C<send_output> supports L<Maypole::HTTPD::Frontend>.
 189
 190 =cut
 191
 192 sub collect_output
 193 {
 194     my $r = shift;
 195
 196     # Collect HTTP headers
 197     my %headers = (
 198         -type            => $r->content_type,
 199         -charset         => $r->document_encoding,
 200         -content_length  => do { use bytes; length $r->output },
 201     );
 202     foreach ($r->headers_out->field_names) {
 203         next if /^Content-(Type|Length)/;
 204         $headers{"-$_"} = $r->headers_out->get($_);
 205     }
 206
 207     return $r->cgi->header(%headers) . $r->output;
 208 }
 209
 210 =item get_template_root
 211
 212 =cut
 213
 214 sub get_template_root {
 215     my $r = shift;
 216     $r->cgi->document_root . "/" . $r->cgi->url( -relative => 1 );
 217 }
 218
 219 1;
 220
 221
 222 =back
 223
 224 =head1 DEPENDANCIES
 225
 226 CGI::Simple
 227
 228 =head1 AUTHORS
 229
 230 Dave Ranney C<dave@sialia.com>
 231
 232 Simon Cozens C<simon@cpan.org>
 233
 234 =cut