lib/CGI/Maypole.pm

   1 package CGI::Maypole;
   2 use base 'Maypole';
   3
   4 use strict;
   5 use warnings;
   6 use CGI::Simple;
   7 use Maypole::Headers;
   8 use Maypole::Constants;
   9
  10 our $VERSION = '2.10';
  11
  12 __PACKAGE__->mk_accessors( qw( cgi ) );
  13
  14 =head1 NAME
  15
  16 CGI::Maypole - CGI-based front-end to Maypole
  17
  18 =head1 SYNOPSIS
  19
  20      package BeerDB;
  21      use Maypole::Application;
  22
  23      ## example beer.cgi:
  24
  25      #!/usr/bin/perl -w
  26      use strict;
  27      use BeerDB;
  28      BeerDB->run();
  29
  30 Now to access the beer database, type this URL into your browser:
  31 http://your.site/cgi-bin/beer.cgi/frontpage
  32
  33 NOTE: this Maypole frontend requires additional modules that won't be installed
  34 or included with Maypole. Please see below.
  35
  36 =head1 DESCRIPTION
  37
  38 This is a CGI platform driver for Maypole. Your application can inherit from
  39 CGI::Maypole directly, but it is recommended that you use
  40 L<Maypole::Application>.
  41
  42 This module requires CGI::Simple which you will have to install yourself via
  43 CPAN or manually.
  44
  45 =head1 METHODS
  46
  47 =over
  48
  49 =item run
  50
  51 Call this from your CGI script to start the Maypole application.
  52
  53 =back
  54
  55 =cut
  56
  57 sub run
  58 {
  59     my $self = shift;
  60     return $self->handler;
  61 }
  62
  63 =head1 Implementation
  64
  65 This class overrides a set of methods in the base Maypole class to provide it's
  66 functionality. See L<Maypole> for these:
  67
  68 =over
  69
  70 =item get_request
  71
  72 =cut
  73
  74 sub get_request
  75 {
  76     shift->cgi( CGI::Simple->new );
  77 }
  78
  79 =item parse_location
  80
  81 =cut
  82
  83 sub parse_location
  84 {
  85     my $r = shift;
  86     my $cgi = $r->cgi;
  87
  88     # Reconstruct the request headers (as far as this is possible)
  89     $r->headers_in(Maypole::Headers->new);
  90     for my $http_header ($cgi->http) {
  91         (my $field_name = $http_header) =~ s/^HTTPS?_//;
  92         $r->headers_in->set($field_name => $cgi->http($http_header));
  93     }
  94
  95     my $path = $cgi->url( -absolute => 1, -path_info => 1 );
  96     my $loc = $cgi->url( -absolute => 1 );
  97     {
  98         no warnings 'uninitialized';
  99         $path .= '/' if $path eq $loc;
 100         $path =~ s/^($loc)?\///;
 101     }
 102     $r->path($path);
 103
 104     $r->parse_path;
 105     $r->parse_args;
 106 }
 107
 108 =item parse_args
 109
 110 =cut
 111
 112 sub parse_args
 113 {
 114     my $r = shift;
 115     my (%vars) = $r->cgi->Vars;
 116     while ( my ( $key, $value ) = each %vars ) {
 117         my @values = split "\0", $value;
 118         $vars{$key} = @values <= 1 ? $values[0] : \@values;
 119     }
 120     $r->params( {%vars} );
 121     $r->query( $r->params );
 122 }
 123
 124 =item redirect_request
 125
 126 =cut
 127
 128 # FIXME: use headers_in to gather host and other information?
 129 sub redirect_request
 130 {
 131   my $r = shift;
 132   my $redirect_url = $_[0];
 133   my $status = "302";
 134   if ($_[1]) {
 135     my %args = @_;
 136     if ($args{url}) {
 137       $redirect_url = $args{url};
 138     } else {
 139       my $path = $args{path} || $r->cgi->url(-absolute => 1, -query=>1);
 140       my $host = $args{domain};
 141       ($host = $r->cgi->url(-base => 1)) =~ s/^https?:\/\///i unless ($host);
 142       my $protocol = $args{protocol} || $r->get_protocol;
 143       $redirect_url = "${protocol}://${host}/${path}";
 144     }
 145     $status = $args{status} if ($args{status});
 146   }
 147
 148   $r->headers_out->set('Status' => $status);
 149   $r->headers_out->set('Location' => $redirect_url);
 150
 151   return;
 152 }
 153
 154 =item get_protocol
 155
 156 =cut
 157
 158 sub get_protocol
 159 {
 160   my $self = shift;
 161   my $protocol = ($self->cgi->https) ? 'https' : 'http';
 162   return $protocol;
 163 }
 164
 165 =item send_output
 166
 167 =cut
 168
 169 sub send_output
 170 {
 171     my $r = shift;
 172
 173     # Collect HTTP headers
 174     my %headers = (
 175         -type            => $r->content_type,
 176         -charset         => $r->document_encoding,
 177         -content_length  => do { use bytes; length $r->output },
 178     );
 179     foreach ($r->headers_out->field_names) {
 180         next if /^Content-(Type|Length)/;
 181         $headers{"-$_"} = $r->headers_out->get($_);
 182     }
 183
 184     print $r->cgi->header(%headers), $r->output;
 185 }
 186
 187 =item get_template_root
 188
 189 =cut
 190
 191 sub get_template_root {
 192     my $r = shift;
 193     $r->cgi->document_root . "/" . $r->cgi->url( -relative => 1 );
 194 }
 195
 196 1;
 197
 198
 199 =back
 200
 201 =head1 DEPENDANCIES
 202
 203 CGI::Simple
 204
 205 =head1 AUTHORS
 206
 207 Dave Ranney C<dave@sialia.com>
 208
 209 Simon Cozens C<simon@cpan.org>
 210
 211 =cut