lib/CGI/Maypole.pm

   1 package CGI::Maypole;
   2 use base 'Maypole';
   3
   4 use strict;
   5 use warnings;
   6 use CGI::Simple;
   7 use Maypole::Headers;
   8 use Maypole::Constants;
   9
  10 our $VERSION = '2.11';
  11
  12 __PACKAGE__->mk_accessors( qw/cgi/ );
  13
  14 =head1 NAME
  15
  16 CGI::Maypole - CGI-based front-end to Maypole
  17
  18 =head1 SYNOPSIS
  19
  20      package BeerDB;
  21      use Maypole::Application;
  22
  23      ## example beer.cgi:
  24
  25      #!/usr/bin/perl -w
  26      use strict;
  27      use BeerDB;
  28      BeerDB->run();
  29
  30 Now to access the beer database, type this URL into your browser:
  31 http://your.site/cgi-bin/beer.cgi/frontpage
  32
  33 NOTE: this Maypole frontend requires additional modules that won't be installed
  34 or included with Maypole. Please see below.
  35
  36 =head1 DESCRIPTION
  37
  38 This is a CGI platform driver for Maypole. Your application can inherit from
  39 CGI::Maypole directly, but it is recommended that you use
  40 L<Maypole::Application>.
  41
  42 This module requires CGI::Simple which you will have to install yourself via
  43 CPAN or manually.
  44
  45 =head1 METHODS
  46
  47 =over
  48
  49 =item run
  50
  51 Call this from your CGI script to start the Maypole application.
  52
  53 =back
  54
  55 =cut
  56
  57 sub run
  58 {
  59     my $self = shift;
  60     return $self->handler;
  61 }
  62
  63 =head1 Implementation
  64
  65 This class overrides a set of methods in the base Maypole class to provide it's
  66 functionality. See L<Maypole> for these:
  67
  68 =over
  69
  70 =item get_request
  71
  72 =cut
  73
  74 sub get_request
  75 {
  76     shift->cgi( CGI::Simple->new );
  77 }
  78
  79 =item parse_location
  80
  81 =cut
  82
  83 sub parse_location
  84 {
  85     my $r = shift;
  86     my $cgi = $r->cgi;
  87
  88     # Reconstruct the request headers (as far as this is possible)
  89     $r->headers_in(Maypole::Headers->new);
  90     for my $http_header ($cgi->http) {
  91         (my $field_name = $http_header) =~ s/^HTTPS?_//;
  92         $r->headers_in->set($field_name => $cgi->http($http_header));
  93     }
  94
  95     my $path = $cgi->url( -absolute => 1, -path_info => 1 );
  96     my $loc = $cgi->url( -absolute => 1 );
  97     {
  98         no warnings 'uninitialized';
  99         $path .= '/' if $path eq $loc;
 100         if ($loc =~ /\/$/) {
 101           $path =~ s/^($loc)?//;
 102         } else {
 103           $path =~ s/^($loc)?\///;
 104         }
 105     }
 106     $r->path($path);
 107
 108     $r->parse_path;
 109     $r->parse_args;
 110 }
 111
 112 =item warn
 113
 114 =cut
 115
 116 sub warn {
 117     my ($self,@args) = @_;
 118     my ($package, $line) = (caller)[0,2];
 119     warn "[$package line $line] ", @args ;
 120     return;
 121 }
 122
 123 =item parse_args
 124
 125 =cut
 126
 127 sub parse_args
 128 {
 129     my $r = shift;
 130     my (%vars) = $r->cgi->Vars;
 131     while ( my ( $key, $value ) = each %vars ) {
 132         my @values = split "\0", $value;
 133         $vars{$key} = @values <= 1 ? $values[0] : \@values;
 134     }
 135     $r->params( {%vars} );
 136     $r->query( $r->params );
 137 }
 138
 139 =item redirect_request
 140
 141 =cut
 142
 143 # FIXME: use headers_in to gather host and other information?
 144 sub redirect_request
 145 {
 146   my $r = shift;
 147   my $redirect_url = $_[0];
 148   my $status = "302";
 149   if ($_[1]) {
 150     my %args = @_;
 151     if ($args{url}) {
 152       $redirect_url = $args{url};
 153     } else {
 154       my $path = $args{path} || $r->cgi->url(-absolute => 1, -query=>1);
 155       my $host = $args{domain};
 156       ($host = $r->cgi->url(-base => 1)) =~ s/^https?:\/\///i unless ($host);
 157       my $protocol = $args{protocol} || $r->get_protocol;
 158       $redirect_url = "${protocol}://${host}/${path}";
 159     }
 160     $status = $args{status} if ($args{status});
 161   }
 162
 163   $r->headers_out->set('Status' => $status);
 164   $r->headers_out->set('Location' => $redirect_url);
 165
 166   return;
 167 }
 168
 169 =item get_protocol
 170
 171 =cut
 172
 173 sub get_protocol
 174 {
 175   my $self = shift;
 176   my $protocol = ($self->cgi->https) ? 'https' : 'http';
 177   return $protocol;
 178 }
 179
 180 =item send_output
 181
 182 Generates output (using C<collect_output>) and prints it.
 183
 184 =cut
 185
 186 sub send_output
 187 {
 188     my $r = shift;
 189     print $r->collect_output;
 190 }
 191
 192 =item collect_output
 193
 194 Gathers headers and output together into a string and returns it.
 195
 196 Splitting this code out of C<send_output> supports L<Maypole::HTTPD::Frontend>.
 197
 198 =cut
 199
 200 sub collect_output
 201 {
 202     my $r = shift;
 203
 204     # Collect HTTP headers
 205     my %headers = (
 206         -type            => $r->content_type,
 207         -charset         => $r->document_encoding,
 208         -content_length  => do { use bytes; length $r->output },
 209     );
 210     foreach ($r->headers_out->field_names) {
 211         next if /^Content-(Type|Length)/;
 212         $headers{"-$_"} = $r->headers_out->get($_);
 213     }
 214
 215     return $r->cgi->header(%headers) . $r->output;
 216 }
 217
 218 =item get_template_root
 219
 220 =cut
 221
 222 sub get_template_root {
 223     my $r = shift;
 224     $r->cgi->document_root . "/" . $r->cgi->url( -relative => 1 );
 225 }
 226
 227 1;
 228
 229
 230 =back
 231
 232 =head1 DEPENDANCIES
 233
 234 CGI::Simple
 235
 236 =head1 AUTHORS
 237
 238 Dave Ranney C<dave@sialia.com>
 239
 240 Simon Cozens C<simon@cpan.org>
 241
 242 =cut