lib/CGI/Maypole.pm

   1 package CGI::Maypole;
   2 use base 'Maypole';
   3
   4 use strict;
   5 use warnings;
   6 use CGI::Simple;
   7 use Maypole::Headers;
   8 use Maypole::Constants;
   9
  10 our $VERSION = '2.11';
  11
  12 __PACKAGE__->mk_accessors( qw/cgi/ );
  13
  14 =head1 NAME
  15
  16 CGI::Maypole - CGI-based front-end to Maypole
  17
  18 =head1 SYNOPSIS
  19
  20      package BeerDB;
  21      use Maypole::Application;
  22
  23      ## example beer.cgi:
  24
  25      #!/usr/bin/perl -w
  26      use strict;
  27      use BeerDB;
  28      BeerDB->run();
  29
  30 Now to access the beer database, type this URL into your browser:
  31 http://your.site/cgi-bin/beer.cgi/frontpage
  32
  33 NOTE: this Maypole frontend requires additional modules that won't be installed
  34 or included with Maypole. Please see below.
  35
  36 =head1 DESCRIPTION
  37
  38 This is a CGI platform driver for Maypole. Your application can inherit from
  39 CGI::Maypole directly, but it is recommended that you use
  40 L<Maypole::Application>.
  41
  42 This module requires CGI::Simple which you will have to install yourself via
  43 CPAN or manually.
  44
  45 =head1 METHODS
  46
  47 =over
  48
  49 =item run
  50
  51 Call this from your CGI script to start the Maypole application.
  52
  53 =back
  54
  55 =cut
  56
  57 sub run
  58 {
  59     my $self = shift;
  60     return $self->handler;
  61 }
  62
  63 =head1 Implementation
  64
  65 This class overrides a set of methods in the base Maypole class to provide it's
  66 functionality. See L<Maypole> for these:
  67
  68 =over
  69
  70 =item get_request
  71
  72 =cut
  73
  74 sub get_request
  75 {
  76     shift->cgi( CGI::Simple->new );
  77 }
  78
  79 =item parse_location
  80
  81 =cut
  82
  83 sub parse_location
  84 {
  85     my $r = shift;
  86     my $cgi = $r->cgi;
  87
  88     # Reconstruct the request headers (as far as this is possible)
  89     $r->headers_in(Maypole::Headers->new);
  90     for my $http_header ($cgi->http) {
  91         (my $field_name = $http_header) =~ s/^HTTPS?_//;
  92         $r->headers_in->set($field_name => $cgi->http($http_header));
  93     }
  94
  95     $r->preprocess_location();
  96
  97     my $path = $cgi->url( -absolute => 1, -path_info => 1 );
  98     my $loc = $cgi->url( -absolute => 1 );
  99     {
 100         no warnings 'uninitialized';
 101         $path .= '/' if $path eq $loc;
 102         if ($loc =~ /\/$/) {
 103           $path =~ s/^($loc)?//;
 104         } else {
 105           $path =~ s/^($loc)?\///;
 106         }
 107     }
 108     $r->path($path);
 109
 110     $r->parse_path;
 111     $r->parse_args;
 112 }
 113
 114 =item warn
 115
 116 =cut
 117
 118 sub warn {
 119     my ($self,@args) = @_;
 120     my ($package, $line) = (caller)[0,2];
 121     warn "[$package line $line] ", @args ;
 122     return;
 123 }
 124
 125 =item parse_args
 126
 127 =cut
 128
 129 sub parse_args
 130 {
 131     my $r = shift;
 132     my (%vars) = $r->cgi->Vars;
 133     while ( my ( $key, $value ) = each %vars ) {
 134         my @values = split "\0", $value;
 135         $vars{$key} = @values <= 1 ? $values[0] : \@values;
 136     }
 137     $r->params( {%vars} );
 138     $r->query( $r->params );
 139 }
 140
 141 =item redirect_request
 142
 143 =cut
 144
 145 # FIXME: use headers_in to gather host and other information?
 146 sub redirect_request
 147 {
 148   my $r = shift;
 149   my $redirect_url = $_[0];
 150   my $status = "302";
 151   if ($_[1]) {
 152     my %args = @_;
 153     if ($args{url}) {
 154       $redirect_url = $args{url};
 155     } else {
 156       my $path = $args{path} || $r->cgi->url(-absolute => 1, -query=>1);
 157       my $host = $args{domain};
 158       ($host = $r->cgi->url(-base => 1)) =~ s/^https?:\/\///i unless ($host);
 159       my $protocol = $args{protocol} || $r->get_protocol;
 160       $redirect_url = "${protocol}://${host}/${path}";
 161     }
 162     $status = $args{status} if ($args{status});
 163   }
 164
 165   $r->headers_out->set('Status' => $status);
 166   $r->headers_out->set('Location' => $redirect_url);
 167
 168   return;
 169 }
 170
 171 =item get_protocol
 172
 173 =cut
 174
 175 sub get_protocol
 176 {
 177   my $self = shift;
 178   my $protocol = ($self->cgi->https) ? 'https' : 'http';
 179   return $protocol;
 180 }
 181
 182 =item send_output
 183
 184 Generates output (using C<collect_output>) and prints it.
 185
 186 =cut
 187
 188 sub send_output
 189 {
 190     my $r = shift;
 191     print $r->collect_output;
 192 }
 193
 194 =item collect_output
 195
 196 Gathers headers and output together into a string and returns it.
 197
 198 Splitting this code out of C<send_output> supports L<Maypole::HTTPD::Frontend>.
 199
 200 =cut
 201
 202 sub collect_output
 203 {
 204     my $r = shift;
 205
 206     # Collect HTTP headers
 207     my %headers = (
 208         -type            => $r->content_type,
 209         -charset         => $r->document_encoding,
 210         -content_length  => do { use bytes; length $r->output },
 211     );
 212     foreach ($r->headers_out->field_names) {
 213         next if /^Content-(Type|Length)/;
 214         $headers{"-$_"} = $r->headers_out->get($_);
 215     }
 216
 217     return $r->cgi->header(%headers) . $r->output;
 218 }
 219
 220 =item get_template_root
 221
 222 =cut
 223
 224 sub get_template_root {
 225     my $r = shift;
 226     $r->cgi->document_root . "/" . $r->cgi->url( -relative => 1 );
 227 }
 228
 229 1;
 230
 231
 232 =back
 233
 234 =head1 DEPENDANCIES
 235
 236 CGI::Simple
 237
 238 =head1 AUTHORS
 239
 240 Dave Ranney C<dave@sialia.com>
 241
 242 Simon Cozens C<simon@cpan.org>
 243
 244 =cut