lib/Apache/MVC.pm

   1 package Apache::MVC;
   2
   3 our $VERSION = '2.11';
   4
   5 use strict;
   6 use warnings;
   7
   8 use URI;
   9 use URI::QueryParam;
  10
  11 use base 'Maypole';
  12 use Maypole::Headers;
  13 use Maypole::Constants;
  14
  15 __PACKAGE__->mk_accessors( qw( ar ) );
  16
  17 our $MODPERL2;
  18 our $modperl_version;
  19
  20 BEGIN {
  21     $MODPERL2  = ( exists $ENV{MOD_PERL_API_VERSION} and
  22                         $ENV{MOD_PERL_API_VERSION} >= 2 );
  23     if ($MODPERL2) {
  24      eval 'use mod_perl2; $modperl_version = $mod_perl2::VERSION;';
  25      if ($@) {
  26       $modperl_version = $Apache2::RequestRec::VERSION;
  27      }
  28      require Apache2::RequestIO;
  29      require Apache2::RequestRec;
  30      require Apache2::RequestUtil;
  31      eval 'use Apache2::Const -compile => qw/REDIRECT/;'; # -compile 4 no import
  32      require APR::URI;
  33      require HTTP::Body;
  34     } else {
  35      eval ' use mod_perl; ';
  36      require Apache;
  37      require Apache::Request;
  38      eval 'use Apache::Constants -compile => qw/REDIRECT/;';
  39      $modperl_version = 1;
  40     }
  41
  42 }
  43
  44 =head1 NAME
  45
  46 Apache::MVC - Apache front-end to Maypole
  47
  48 =head1 SYNOPSIS
  49
  50     package BeerDB;
  51     use Maypole::Application;
  52
  53 =head1 DESCRIPTION
  54
  55 A mod_perl platform driver for Maypole. Your application can inherit from
  56 Apache::MVC directly, but it is recommended that you use
  57 L<Maypole::Application>.
  58
  59 =head1 INSTALLATION
  60
  61 Create a driver module like the one illustrated in L<Maypole::Application>.
  62
  63 Put the following in your Apache config:
  64
  65     <Location /beer>
  66         SetHandler perl-script
  67         PerlHandler BeerDB
  68     </Location>
  69
  70 Copy the templates found in F<templates/factory> into the F<beer/factory>
  71 directory off the web root. When the designers get back to you with custom
  72 templates, they are to go in F<beer/custom>. If you need to override templates
  73 on a database-table-by-table basis, put the new template in F<beer/I<table>>.
  74
  75 This will automatically give you C<add>, C<edit>, C<list>, C<view> and C<delete>
  76 commands; for instance, to see a list of breweries, go to
  77
  78     http://your.site/beer/brewery/list
  79
  80 For more information about how the system works and how to extend it,
  81 see L<Maypole>.
  82
  83 =head1 Implementation
  84
  85 This class overrides a set of methods in the base Maypole class to provide its
  86 functionality. See L<Maypole> for these:
  87
  88 =over
  89
  90 =item get_request
  91
  92 =cut
  93
  94 sub get_request {
  95     my ($self, $r) = @_;
  96     my $ar;
  97     if ($MODPERL2) {
  98         $ar = eval {require Apache2::Request} ? Apache2::Request->new($r) : $r;
  99         }
 100     else { $ar = Apache::Request->instance($r); }
 101     $self->ar($ar);
 102 }
 103
 104 =item parse_location
 105
 106 =cut
 107
 108 sub parse_location {
 109     my $self = shift;
 110
 111     # Reconstruct the request headers
 112     $self->headers_in(Maypole::Headers->new);
 113     my %headers;
 114     if ($MODPERL2) { %headers = %{$self->ar->headers_in};
 115     } else { %headers = $self->ar->headers_in; }
 116     for (keys %headers) {
 117         $self->headers_in->set($_, $headers{$_});
 118     }
 119     my $path = $self->ar->uri;
 120     my $loc  = $self->ar->location;
 121     {
 122         no warnings 'uninitialized';
 123         $path .= '/' if $path eq $loc;
 124         $path =~ s/^($loc)?\///;
 125     }
 126     $self->path($path);
 127     $self->parse_path;
 128     $self->parse_args;
 129 }
 130
 131 =item parse_args
 132
 133 =cut
 134
 135 sub parse_args {
 136     my $self = shift;
 137     $self->params( { $self->_mod_perl_args( $self->ar ) } );
 138     $self->query( $self->params );
 139 }
 140
 141 =item redirect_request
 142
 143 =cut
 144
 145 sub redirect_request
 146 {
 147   my $r = shift;
 148   my $redirect_url = $_[0];
 149   my $status = $MODPERL2 ? eval 'Apache2::Const::REDIRECT;' :
 150           eval 'Apache::Constants::REDIRECT;'; # why have to eval this?
 151   if ($_[1]) {
 152     my %args = @_;
 153     if ($args{url}) {
 154       $redirect_url = $args{url};
 155     } else {
 156       my $path = $args{path} || $r->path;
 157       my $host = $args{domain} || $r->ar->hostname;
 158       my $protocol = $args{protocol} || $r->get_protocol;
 159       $redirect_url = "${protocol}://${host}/${path}";
 160     }
 161     $status = $args{status} if ($args{status});
 162   }
 163
 164   $r->ar->status($status);
 165   $r->ar->headers_out->set('Location' => $redirect_url);
 166   return OK;
 167 }
 168
 169 =item get_protocol
 170
 171 =cut
 172
 173 sub get_protocol {
 174   my $self = shift;
 175   my $protocol = ( $self->ar->protocol =~ m/https/i ) ? 'https' : 'http' ;
 176   return $protocol;
 177 }
 178
 179 =item send_output
 180
 181 =cut
 182
 183 sub send_output {
 184     my $r = shift;
 185     $r->ar->content_type(
 186           $r->content_type =~ m/^text/
 187         ? $r->content_type . "; charset=" . $r->document_encoding
 188         : $r->content_type
 189     );
 190     $r->ar->headers_out->set(
 191         "Content-Length" => do { use bytes; length $r->output }
 192     );
 193
 194     foreach ($r->headers_out->field_names) {
 195         next if /^Content-(Type|Length)/;
 196         $r->ar->headers_out->set($_ => $r->headers_out->get($_));
 197     }
 198
 199     $MODPERL2 || $r->ar->send_http_header;
 200     $r->ar->print( $r->output );
 201 }
 202
 203 =item get_template_root
 204
 205 =cut
 206
 207 sub get_template_root {
 208     my $r = shift;
 209     $r->ar->document_root . "/" . $r->ar->location;
 210 }
 211
 212 =back
 213
 214 =cut
 215
 216 #########################################################
 217 # private / internal methods and subs
 218
 219
 220 sub _mod_perl_args {
 221     my ( $self, $apr ) = @_;
 222     my %args;
 223     if ($apr->isa('Apache::Request')) {
 224       foreach my $key ( $apr->param ) {
 225         my @values = $apr->param($key);
 226         $args{$key} = @values == 1 ? $values[0] : \@values;
 227       }
 228     } else {
 229       my $body = $self->_prepare_body($apr);
 230       %args = %{$body->param};
 231       my $uri = URI->new($self->ar->unparsed_uri);
 232       foreach my $key ($uri->query_param) {
 233         if (ref $args{$key}) {
 234           push (@{$args{$key}}, $uri->query_param($key));
 235         } else {
 236           if ($args{$key}) {
 237             $args{$key} = [ $args{$key}, $uri->query_param($key) ];
 238           } else {
 239             my @args = $uri->query_param($key);
 240             if (scalar @args > 1) {
 241               $args{$key} = [ $uri->query_param($key) ];
 242             } else {
 243               $args{$key} = $uri->query_param($key);
 244             }
 245           }
 246         }
 247       }
 248     }
 249     return %args;
 250 }
 251
 252 sub _prepare_body {
 253     my ( $self, $r ) = @_;
 254
 255     unless ($self->{__http_body}) {
 256         my $content_type   = $r->headers_in->get('Content-Type');
 257         my $content_length = $r->headers_in->get('Content-Length');
 258         my $body   = HTTP::Body->new( $content_type, $content_length );
 259         my $length = $content_length;
 260         while ( $length ) {
 261             $r->read( my $buffer, ( $length < 8192 ) ? $length : 8192 );
 262             $length -= length($buffer);
 263             $body->add($buffer);
 264         }
 265         $self->{__http_body} = $body;
 266     }
 267     return $self->{__http_body};
 268 }
 269
 270
 271
 272 =head1 AUTHOR
 273
 274 Simon Cozens, C<simon@cpan.org>
 275
 276 =head1 CREDITS
 277
 278 Aaron Trevena
 279 Marcus Ramberg, C<marcus@thefeed.no>
 280 Sebastian Riedel, C<sri@oook.de>
 281
 282 =head1 LICENSE
 283
 284 You may distribute this code under the same terms as Perl itself.
 285
 286 =cut
 287
 288 1;