lib/Apache/MVC.pm

   1 package Apache::MVC;
   2
   3 our $VERSION = '2.05';
   4
   5 use strict;
   6 use warnings;
   7
   8 use base 'Maypole';
   9 use mod_perl;
  10
  11 use constant APACHE2 => $mod_perl::VERSION >= 1.99;
  12
  13 if (APACHE2) {
  14     require Apache2;
  15     require Apache::RequestIO;
  16     require Apache::RequestRec;
  17     require Apache::RequestUtil;
  18     require APR::URI;
  19 }
  20 else { require Apache }
  21 require Apache::Request;
  22
  23 sub get_request {
  24     my ( $self, $r ) = @_;
  25     $self->{ar} = Apache::Request->new($r);
  26 }
  27
  28 sub parse_location {
  29     my $self = shift;
  30     $self->{path} = $self->{ar}->uri;
  31     my $loc = $self->{ar}->location;
  32     no warnings 'uninitialized';
  33     $self->{path} .= '/' if $self->{path} eq $loc;
  34     $self->{path} =~ s/^($loc)?\///;
  35     $self->parse_path;
  36     $self->parse_args;
  37 }
  38
  39 sub parse_args {
  40     my $self = shift;
  41     $self->{params} = { $self->_mod_perl_args( $self->{ar} ) };
  42     $self->{query}  = { $self->_mod_perl_args( $self->{ar} ) };
  43 }
  44
  45 sub send_output {
  46     my $r = shift;
  47     $r->{ar}->content_type(
  48           $r->{content_type} =~ m/^text/
  49         ? $r->{content_type} . "; charset=" . $r->{document_encoding}
  50         : $r->{content_type}
  51     );
  52     $r->{ar}->headers_out->set(
  53         "Content-Length" => do { use bytes; length $r->{output} }
  54     );
  55     APACHE2 || $r->{ar}->send_http_header;
  56     $r->{ar}->print( $r->{output} );
  57 }
  58
  59 sub get_template_root {
  60     my $r = shift;
  61     $r->{ar}->document_root . "/" . $r->{ar}->location;
  62 }
  63
  64 sub _mod_perl_args {
  65     my ( $self, $apr ) = @_;
  66     my %args;
  67     foreach my $key ( $apr->param ) {
  68         my @values = $apr->param($key);
  69         $args{$key} = @values == 1 ? $values[0] : \@values;
  70     }
  71     return %args;
  72 }
  73
  74 1;
  75
  76 =head1 NAME
  77
  78 Apache::MVC - Apache front-end to Maypole
  79
  80 =head1 SYNOPSIS
  81
  82     package BeerDB;
  83     use base 'Apache::MVC';
  84     BeerDB->setup("dbi:mysql:beerdb");
  85     BeerDB->config->uri_base("http://your.site/");
  86     BeerDB->config->display_tables([qw[beer brewery pub style]]);
  87     # Now set up your database:
  88     # has-a relationships
  89     # untaint columns
  90
  91     1;
  92
  93 =head1 DESCRIPTION
  94
  95 Maypole is a Perl web application framework to Java's struts. It is
  96 essentially completely abstracted, and so doesn't know anything about
  97 how to talk to the outside world. C<Apache::MVC> is a mod_perl based
  98 subclass of Maypole.
  99
 100 To use it, you need to create a package which represents your entire
 101 application. In our example above, this is the C<BeerDB> package.
 102
 103 This needs to first inherit from C<Apache::MVC>, and then call setup.
 104 This will give your package an Apache-compatible C<handler> subroutine,
 105 and then pass any parameters onto the C<setup_database> method of the
 106 model class. The default model class for Maypole uses L<Class::DBI> to
 107 map a database to classes, but this can be changed by messing with the
 108 configuration. (B<Before> calling setup.)
 109
 110 Next, you should configure your application through the C<config>
 111 method. Configuration parameters at present are:
 112
 113 =over
 114
 115 =item uri_base
 116
 117 You B<must> specify this; it is the base URI of the application, which
 118 will be used to construct links.
 119
 120 =item display_tables
 121
 122 If you do not want all of the tables in the database to be accessible,
 123 then set this to a list of only the ones you want to display
 124
 125 =item rows_per_page
 126
 127 List output is paged if you set this to a positive number of rows.
 128
 129 =back
 130
 131 You should also set up relationships between your classes, such that,
 132 for instance, calling C<brewery> on a C<BeerDB::Beer> object returns an
 133 object representing its associated brewery.
 134
 135 For a full example, see the included "beer database" application.
 136
 137 =head1 INSTALLATION
 138
 139 Create a driver module like the one above.
 140
 141 Put the following in your Apache config:
 142
 143     <Location /beer>
 144         SetHandler perl-script
 145         PerlHandler BeerDB
 146     </Location>
 147
 148 Copy the templates found in F<templates/factory> into the
 149 F<beer/factory> directory off the web root. When the designers get
 150 back to you with custom templates, they are to go in
 151 F<beer/custom>. If you need to do override templates on a
 152 database-table-by-table basis, put the new template in
 153 F<beer/I<table>>.
 154
 155 This will automatically give you C<add>, C<edit>, C<list>, C<view> and
 156 C<delete> commands; for instance, a list of breweries, go to
 157
 158     http://your.site/beer/brewery/list
 159
 160 For more information about how the system works and how to extend it,
 161 see L<Maypole>.
 162
 163 =head1 Implementation
 164
 165 This class overrides a set of methods in the base Maypole class to provide it's
 166 functionality. See L<Maypole> for these:
 167
 168 =over
 169
 170 =item get_request
 171
 172 =item get_template_root
 173
 174 =item parse_args
 175
 176 =item parse_location
 177
 178 =item send_output
 179
 180 =back
 181
 182 =head1 AUTHOR
 183
 184 Simon Cozens, C<simon@cpan.org>
 185 Marcus Ramberg, C<marcus@thefeed.no>
 186 Screwed up by Sebastian Riedel, C<sri@oook.de>
 187
 188 =head1 LICENSE
 189
 190 You may distribute this code under the same terms as Perl itself.