lib/Apache/MVC.pm

   1 package Apache::MVC;
   2
   3 our $VERSION = '2.11';
   4
   5 use strict;
   6 use warnings;
   7
   8 use URI;
   9 use URI::QueryParam;
  10
  11 use base 'Maypole';
  12 use Maypole::Headers;
  13 use Maypole::Constants;
  14
  15 __PACKAGE__->mk_accessors( qw( ar ) );
  16
  17 our $MODPERL2;
  18 our $modperl_version;
  19
  20 BEGIN {
  21     $MODPERL2  = ( exists $ENV{MOD_PERL_API_VERSION} and
  22                         $ENV{MOD_PERL_API_VERSION} >= 2 );
  23     if ($MODPERL2) {
  24      eval 'use mod_perl2; $modperl_version = $mod_perl2::VERSION;';
  25      if ($@) {
  26       $modperl_version = $Apache2::RequestRec::VERSION;
  27      }
  28      require Apache2::RequestIO;
  29      require Apache2::RequestRec;
  30      require Apache2::RequestUtil;
  31      eval 'use Apache2::Const -compile => qw/REDIRECT/;'; # -compile 4 no import
  32      require APR::URI;
  33      require HTTP::Body;
  34     } else {
  35      eval ' use mod_perl; ';
  36      require Apache;
  37      require Apache::Request;
  38      eval 'use Apache::Constants -compile => qw/REDIRECT/;';
  39      $modperl_version = 1;
  40     }
  41
  42 }
  43
  44 =head1 NAME
  45
  46 Apache::MVC - Apache front-end to Maypole
  47
  48 =head1 SYNOPSIS
  49
  50     package BeerDB;
  51     use Maypole::Application;
  52
  53 =head1 DESCRIPTION
  54
  55 A mod_perl platform driver for Maypole. Your application can inherit from
  56 Apache::MVC directly, but it is recommended that you use
  57 L<Maypole::Application>.
  58
  59 =head1 INSTALLATION
  60
  61 Create a driver module like the one illustrated in L<Maypole::Application>.
  62
  63 Put the following in your Apache config:
  64
  65     <Location /beer>
  66         SetHandler perl-script
  67         PerlHandler BeerDB
  68     </Location>
  69
  70 Copy the templates found in F<templates/factory> into the F<beer/factory>
  71 directory off the web root. When the designers get back to you with custom
  72 templates, they are to go in F<beer/custom>. If you need to override templates
  73 on a database-table-by-table basis, put the new template in F<beer/I<table>>.
  74
  75 This will automatically give you C<add>, C<edit>, C<list>, C<view> and C<delete>
  76 commands; for instance, to see a list of breweries, go to
  77
  78     http://your.site/beer/brewery/list
  79
  80 For more information about how the system works and how to extend it,
  81 see L<Maypole>.
  82
  83 =head1 Implementation
  84
  85 This class overrides a set of methods in the base Maypole class to provide its
  86 functionality. See L<Maypole> for these:
  87
  88 =over
  89
  90 =item get_request
  91
  92 =cut
  93
  94 sub get_request {
  95     my ($self, $r) = @_;
  96     my $ar;
  97     if ($MODPERL2) {
  98         $ar = eval {require Apache2::Request} ? Apache2::Request->new($r) : $r;
  99         }
 100     else { $ar = Apache::Request->instance($r); }
 101     $self->ar($ar);
 102 }
 103
 104 =item parse_location
 105
 106 =cut
 107
 108 sub warn {
 109   my ($self,@args) = @_;
 110   my ($package, $line) = (caller)[0,2];
 111   if ( $args[0] and ref $self ) {
 112     $self->{ar}->warn("[$package line $line] ", @args) ;
 113   } else {
 114     print "warn called by ", caller, " with ", @_, "\n";
 115   }
 116   return;
 117 }
 118
 119 =item warn
 120
 121 =cut
 122
 123 sub parse_location {
 124     my $self = shift;
 125
 126     # Reconstruct the request headers
 127     $self->headers_in(Maypole::Headers->new);
 128     my %headers;
 129     if ($MODPERL2) { %headers = %{$self->ar->headers_in};
 130     } else { %headers = $self->ar->headers_in; }
 131     for (keys %headers) {
 132         $self->headers_in->set($_, $headers{$_});
 133     }
 134     my $path = $self->ar->uri;
 135     my $loc  = $self->ar->location;
 136     {
 137         no warnings 'uninitialized';
 138         $path .= '/' if $path eq $loc;
 139         $path =~ s/^($loc)?\///;
 140     }
 141     $self->path($path);
 142     $self->parse_path;
 143     $self->parse_args;
 144 }
 145
 146 =item parse_args
 147
 148 =cut
 149
 150 sub parse_args {
 151     my $self = shift;
 152     $self->params( { $self->_mod_perl_args( $self->ar ) } );
 153     $self->query( $self->params );
 154 }
 155
 156 =item redirect_request
 157
 158 =cut
 159
 160 sub redirect_request
 161 {
 162   my $r = shift;
 163   my $redirect_url = $_[0];
 164   my $status = $MODPERL2 ? eval 'Apache2::Const::REDIRECT;' :
 165           eval 'Apache::Constants::REDIRECT;'; # why have to eval this?
 166   if ($_[1]) {
 167     my %args = @_;
 168     if ($args{url}) {
 169       $redirect_url = $args{url};
 170     } else {
 171       my $path = $args{path} || $r->path;
 172       my $host = $args{domain} || $r->ar->hostname;
 173       my $protocol = $args{protocol} || $r->get_protocol;
 174       $redirect_url = "${protocol}://${host}/${path}";
 175     }
 176     $status = $args{status} if ($args{status});
 177   }
 178
 179   $r->ar->status($status);
 180   $r->ar->headers_out->set('Location' => $redirect_url);
 181   return OK;
 182 }
 183
 184 =item get_protocol
 185
 186 =cut
 187
 188 sub get_protocol {
 189   my $self = shift;
 190   my $protocol = ( $self->ar->protocol =~ m/https/i ) ? 'https' : 'http' ;
 191   return $protocol;
 192 }
 193
 194 =item send_output
 195
 196 =cut
 197
 198 sub send_output {
 199     my $r = shift;
 200     $r->ar->content_type(
 201           $r->content_type =~ m/^text/
 202         ? $r->content_type . "; charset=" . $r->document_encoding
 203         : $r->content_type
 204     );
 205     $r->ar->headers_out->set(
 206         "Content-Length" => do { use bytes; length $r->output }
 207     );
 208
 209     foreach ($r->headers_out->field_names) {
 210         next if /^Content-(Type|Length)/;
 211         $r->ar->headers_out->set($_ => $r->headers_out->get($_));
 212     }
 213
 214     $MODPERL2 || $r->ar->send_http_header;
 215     $r->ar->print( $r->output );
 216 }
 217
 218 =item get_template_root
 219
 220 =cut
 221
 222 sub get_template_root {
 223     my $r = shift;
 224     $r->ar->document_root . "/" . $r->ar->location;
 225 }
 226
 227 =back
 228
 229 =cut
 230
 231 #########################################################
 232 # private / internal methods and subs
 233
 234
 235 sub _mod_perl_args {
 236     my ( $self, $apr ) = @_;
 237     my %args;
 238     if ($apr->isa('Apache::Request')) {
 239       foreach my $key ( $apr->param ) {
 240         my @values = $apr->param($key);
 241         $args{$key} = @values == 1 ? $values[0] : \@values;
 242       }
 243     } else {
 244       my $body = $self->_prepare_body($apr);
 245       %args = %{$body->param};
 246       my $uri = URI->new($self->ar->unparsed_uri);
 247       foreach my $key ($uri->query_param) {
 248         if (ref $args{$key}) {
 249           push (@{$args{$key}}, $uri->query_param($key));
 250         } else {
 251           if ($args{$key}) {
 252             $args{$key} = [ $args{$key}, $uri->query_param($key) ];
 253           } else {
 254             my @args = $uri->query_param($key);
 255             if (scalar @args > 1) {
 256               $args{$key} = [ $uri->query_param($key) ];
 257             } else {
 258               $args{$key} = $uri->query_param($key);
 259             }
 260           }
 261         }
 262       }
 263     }
 264     return %args;
 265 }
 266
 267 sub _prepare_body {
 268     my ( $self, $r ) = @_;
 269
 270     unless ($self->{__http_body}) {
 271         my $content_type   = $r->headers_in->get('Content-Type');
 272         my $content_length = $r->headers_in->get('Content-Length');
 273         my $body   = HTTP::Body->new( $content_type, $content_length );
 274         my $length = $content_length;
 275         while ( $length ) {
 276             $r->read( my $buffer, ( $length < 8192 ) ? $length : 8192 );
 277             $length -= length($buffer);
 278             $body->add($buffer);
 279         }
 280         $self->{__http_body} = $body;
 281     }
 282     return $self->{__http_body};
 283 }
 284
 285
 286
 287 =head1 AUTHOR
 288
 289 Simon Cozens, C<simon@cpan.org>
 290
 291 =head1 CREDITS
 292
 293 Aaron Trevena
 294 Marcus Ramberg, C<marcus@thefeed.no>
 295 Sebastian Riedel, C<sri@oook.de>
 296
 297 =head1 LICENSE
 298
 299 You may distribute this code under the same terms as Perl itself.
 300
 301 =cut
 302
 303 1;