lib/Apache/MVC.pm

   1 package Apache::MVC;
   2
   3 our $VERSION = '2.11';
   4
   5 use strict;
   6 use warnings;
   7
   8 use URI;
   9 use URI::QueryParam;
  10
  11 use base 'Maypole';
  12 use Maypole::Headers;
  13 use Maypole::Constants;
  14
  15 __PACKAGE__->mk_accessors( qw( ar ) );
  16
  17 our $MODPERL2;
  18 our $modperl_version;
  19
  20 BEGIN {
  21     $MODPERL2  = ( exists $ENV{MOD_PERL_API_VERSION} and
  22                         $ENV{MOD_PERL_API_VERSION} >= 2 );
  23     if ($MODPERL2) {
  24      eval 'use mod_perl2; $modperl_version = $mod_perl2::VERSION;';
  25      if ($@) {
  26       $modperl_version = $Apache2::RequestRec::VERSION;
  27      }
  28      require Apache2::RequestIO;
  29      require Apache2::RequestRec;
  30      require Apache2::RequestUtil;
  31      eval 'use Apache2::Const -compile => qw/REDIRECT/;'; # -compile 4 no import
  32      require APR::URI;
  33      require HTTP::Body;
  34     } else {
  35      eval ' use mod_perl; ';
  36      require Apache;
  37      require Apache::Request;
  38      eval 'use Apache::Constants -compile => qw/REDIRECT/;';
  39      $modperl_version = 1;
  40     }
  41
  42 }
  43
  44 =head1 NAME
  45
  46 Apache::MVC - Apache front-end to Maypole
  47
  48 =head1 SYNOPSIS
  49
  50     package BeerDB;
  51     use Maypole::Application;
  52
  53 =head1 DESCRIPTION
  54
  55 A mod_perl platform driver for Maypole. Your application can inherit from
  56 Apache::MVC directly, but it is recommended that you use
  57 L<Maypole::Application>.
  58
  59 =head1 INSTALLATION
  60
  61 Create a driver module like the one illustrated in L<Maypole::Application>.
  62
  63 Put the following in your Apache config:
  64
  65     <Location /beer>
  66         SetHandler perl-script
  67         PerlHandler BeerDB
  68     </Location>
  69
  70 Copy the templates found in F<templates/factory> into the F<beer/factory>
  71 directory off the web root. When the designers get back to you with custom
  72 templates, they are to go in F<beer/custom>. If you need to override templates
  73 on a database-table-by-table basis, put the new template in F<beer/I<table>>.
  74
  75 This will automatically give you C<add>, C<edit>, C<list>, C<view> and C<delete>
  76 commands; for instance, to see a list of breweries, go to
  77
  78     http://your.site/beer/brewery/list
  79
  80 For more information about how the system works and how to extend it,
  81 see L<Maypole>.
  82
  83 =head1 Implementation
  84
  85 This class overrides a set of methods in the base Maypole class to provide its
  86 functionality. See L<Maypole> for these:
  87
  88 =over
  89
  90 =item get_request
  91
  92 =cut
  93
  94 sub get_request {
  95     my ($self, $r) = @_;
  96     my $ar;
  97     if ($MODPERL2) {
  98         $ar = eval {require Apache2::Request} ? Apache2::Request->new($r) : $r;
  99         }
 100     else { $ar = Apache::Request->instance($r); }
 101     $self->ar($ar);
 102 }
 103
 104 =item parse_location
 105
 106 =cut
 107
 108 sub parse_location {
 109     my $self = shift;
 110
 111     # Reconstruct the request headers
 112     $self->headers_in(Maypole::Headers->new);
 113     my %headers;
 114     if ($MODPERL2) { %headers = %{$self->ar->headers_in};
 115     } else { %headers = $self->ar->headers_in; }
 116     for (keys %headers) {
 117         $self->headers_in->set($_, $headers{$_});
 118     }
 119     my $path = $self->ar->uri;
 120     my $loc  = $self->ar->location;
 121     {
 122         no warnings 'uninitialized';
 123         $path .= '/' if $path eq $loc;
 124         $path =~ s/^($loc)?\///;
 125     }
 126     $self->path($path);
 127     $self->parse_path;
 128     $self->parse_args;
 129 }
 130
 131 =item parse_args
 132
 133 =cut
 134
 135 sub parse_args {
 136     my $self = shift;
 137     $self->params( { $self->_mod_perl_args( $self->ar ) } );
 138     $self->query( $self->params );
 139 }
 140
 141 =item redirect_request
 142
 143 =cut
 144
 145 sub redirect_request {
 146   my $r = shift;
 147   my $redirect_url = $_[0];
 148   my $status = $MODPERL2 ? eval 'Apache2::Const::REDIRECT;' :
 149           eval 'Apache::Constants::REDIRECT;'; # why have to eval this?
 150   if ($_[1]) {
 151     my %args = @_;
 152     if ($args{url}) {
 153       $redirect_url = $args{url};
 154     } else {
 155       my $path = $args{path} || $r->path;
 156       my $host = $args{domain} || $r->ar->hostname;
 157       my $protocol = $args{protocol} || $r->get_protocol;
 158
 159       $redirect_url = URI->new;
 160          $redirect_url->scheme($protocol);
 161          $redirect_url->host($host);
 162          $redirect_url->path($path);
 163     }
 164     $status = $args{status} if ($args{status});
 165   }
 166
 167   $r->ar->status($status);
 168   $r->ar->headers_out->set('Location' => $redirect_url);
 169   return OK;
 170 }
 171
 172 =item get_protocol
 173
 174 =cut
 175
 176 sub get_protocol {
 177   my $self = shift;
 178   my $protocol = ( $self->ar->protocol =~ m/https/i ) ? 'https' : 'http' ;
 179   return $protocol;
 180 }
 181
 182 =item send_output
 183
 184 =cut
 185
 186 sub send_output {
 187     my $r = shift;
 188     $r->ar->content_type(
 189           $r->content_type =~ m/^text/
 190         ? $r->content_type . "; charset=" . $r->document_encoding
 191         : $r->content_type
 192     );
 193     $r->ar->headers_out->set(
 194         "Content-Length" => do { use bytes; length $r->output }
 195     );
 196
 197     foreach ($r->headers_out->field_names) {
 198         next if /^Content-(Type|Length)/;
 199         $r->ar->headers_out->set($_ => $r->headers_out->get($_));
 200     }
 201
 202     $MODPERL2 || $r->ar->send_http_header;
 203     $r->ar->print( $r->output );
 204 }
 205
 206 =item get_template_root
 207
 208 =cut
 209
 210 sub get_template_root {
 211     my $r = shift;
 212     $r->ar->document_root . "/" . $r->ar->location;
 213 }
 214
 215 =back
 216
 217 =cut
 218
 219 #########################################################
 220 # private / internal methods and subs
 221
 222
 223 sub _mod_perl_args {
 224     my ( $self, $apr ) = @_;
 225     my %args;
 226     if ($apr->isa('Apache::Request')) {
 227       foreach my $key ( $apr->param ) {
 228         my @values = $apr->param($key);
 229         $args{$key} = @values == 1 ? $values[0] : \@values;
 230       }
 231     } else {
 232       my $body = $self->_prepare_body($apr);
 233       %args = %{$body->param};
 234       my $uri = URI->new($self->ar->unparsed_uri);
 235       foreach my $key ($uri->query_param) {
 236         if (ref $args{$key}) {
 237           push (@{$args{$key}}, $uri->query_param($key));
 238         } else {
 239           if ($args{$key}) {
 240             $args{$key} = [ $args{$key}, $uri->query_param($key) ];
 241           } else {
 242             my @args = $uri->query_param($key);
 243             if (scalar @args > 1) {
 244               $args{$key} = [ $uri->query_param($key) ];
 245             } else {
 246               $args{$key} = $uri->query_param($key);
 247             }
 248           }
 249         }
 250       }
 251     }
 252     return %args;
 253 }
 254
 255 sub _prepare_body {
 256     my ( $self, $r ) = @_;
 257
 258     unless ($self->{__http_body}) {
 259         my $content_type   = $r->headers_in->get('Content-Type');
 260         my $content_length = $r->headers_in->get('Content-Length');
 261         my $body   = HTTP::Body->new( $content_type, $content_length );
 262         my $length = $content_length;
 263         while ( $length ) {
 264             $r->read( my $buffer, ( $length < 8192 ) ? $length : 8192 );
 265             $length -= length($buffer);
 266             $body->add($buffer);
 267         }
 268         $self->{__http_body} = $body;
 269     }
 270     return $self->{__http_body};
 271 }
 272
 273
 274
 275 =head1 AUTHOR
 276
 277 Simon Cozens, C<simon@cpan.org>
 278
 279 =head1 CREDITS
 280
 281 Aaron Trevena
 282 Marcus Ramberg, C<marcus@thefeed.no>
 283 Sebastian Riedel, C<sri@oook.de>
 284
 285 =head1 LICENSE
 286
 287 You may distribute this code under the same terms as Perl itself.
 288
 289 =cut
 290
 291 1;