aclocal/kerberos5.m4

   1 dnl Checks for Kerberos
   2 dnl NOTE: while we intend to do generic gss-api, currently we
   3 dnl have a requirement to get an initial Kerberos machine
   4 dnl credential.  Thus, the requirement for Kerberos.
   5 dnl The Kerberos gssapi library will be dynamically loaded?
   6 AC_DEFUN([AC_KERBEROS_V5],[
   7   AC_MSG_CHECKING(for Kerberos v5)
   8   AC_ARG_WITH(krb5,
   9   [AC_HELP_STRING([--with-krb5=DIR], [use Kerberos v5 installation in DIR])],
  10   [ case "$withval" in
  11     yes|no)
  12        krb5_with=""
  13        ;;
  14     *)
  15        krb5_with="$withval"
  16        ;;
  17     esac ]
  18   )
  19
  20   for dir in $krb5_with /usr /usr/kerberos /usr/local /usr/local/krb5 \
  21              /usr/krb5 /usr/heimdal /usr/local/heimdal /usr/athena ; do
  22     dnl This ugly hack brought on by the split installation of
  23     dnl MIT Kerberos on Fedora Core 1
  24     K5CONFIG=""
  25     if test -f $dir/bin/krb5-config; then
  26       K5CONFIG=$dir/bin/krb5-config
  27     elif test -f "/usr/kerberos/bin/krb5-config"; then
  28       K5CONFIG="/usr/kerberos/bin/krb5-config"
  29     elif test -f "/usr/lib/mit/bin/krb5-config"; then
  30       K5CONFIG="/usr/lib/mit/bin/krb5-config"
  31     fi
  32     if test "$K5CONFIG" != ""; then
  33       KRBCFLAGS=`$K5CONFIG --cflags`
  34       KRBLIBS=`$K5CONFIG --libs gssapi`
  35       K5VERS=`$K5CONFIG --version | head -n 1 | awk '{split($(4),v,"."); if (v@<:@"3"@:>@ == "") v@<:@"3"@:>@ = "0"; print v@<:@"1"@:>@v@<:@"2"@:>@v@<:@"3"@:>@ }'`
  36       AC_DEFINE_UNQUOTED(KRB5_VERSION, $K5VERS, [Define this as the Kerberos version number])
  37       if test -f $dir/include/gssapi/gssapi_krb5.h -a \
  38                 \( -f $dir/lib/libgssapi_krb5.a -o \
  39                    -f $dir/lib/libgssapi_krb5.so \) ; then
  40          AC_DEFINE(HAVE_KRB5, 1, [Define this if you have MIT Kerberos libraries])
  41          KRBDIR="$dir"
  42   dnl If we are using MIT K5 1.3.1 and before, we *MUST* use the
  43   dnl private function (gss_krb5_ccache_name) to get correct
  44   dnl behavior of changing the ccache used by gssapi.
  45   dnl Starting in 1.3.2, we *DO NOT* want to use
  46   dnl gss_krb5_ccache_name, instead we want to set KRB5CCNAME
  47   dnl to get gssapi to use a different ccache
  48          if test $K5VERS -le 131; then
  49            AC_DEFINE(USE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the private function, gss_krb5_cache_name, must be used to tell the Kerberos library which credentials cache to use. Otherwise, this is done by setting the KRB5CCNAME environment variable])
  50          fi
  51          gssapi_lib=gssapi_krb5
  52          break
  53       dnl The following ugly hack brought on by the split installation
  54       dnl of Heimdal Kerberos on SuSe
  55       elif test \( -f $dir/include/heim_err.h -o\
  56                  -f $dir/include/heimdal/heim_err.h \) -a \
  57                 -f $dir/lib/libroken.a; then
  58          AC_DEFINE(HAVE_HEIMDAL, 1, [Define this if you have Heimdal Kerberos libraries])
  59          KRBDIR="$dir"
  60          gssapi_lib=gssapi
  61         break
  62       fi
  63     fi
  64   done
  65   dnl We didn't find a usable Kerberos environment
  66   if test "x$KRBDIR" = "x"; then
  67     if test "x$krb5_with" = "x"; then
  68       AC_MSG_ERROR(Kerberos v5 with GSS support not found: consider --disable-gss or --with-krb5=)
  69     else
  70       AC_MSG_ERROR(Kerberos v5 with GSS support not found at $krb5_with)
  71     fi
  72   fi
  73   AC_MSG_RESULT($KRBDIR)
  74
  75   dnl Check if -rpath=$(KRBDIR)/lib is needed
  76   echo "The current KRBDIR is $KRBDIR"
  77   if test "$KRBDIR/lib" = "/lib" -o "$KRBDIR/lib" = "/usr/lib" \
  78        -o "$KRBDIR/lib" = "//lib" -o "$KRBDIR/lib" = "/usr//lib" ; then
  79     KRBLDFLAGS="";
  80   elif /sbin/ldconfig -p | grep > /dev/null "=> $KRBDIR/lib/"; then
  81     KRBLDFLAGS="";
  82   else
  83     KRBLDFLAGS="-Wl,-rpath=$KRBDIR/lib"
  84   fi
  85
  86   dnl Now check for functions within gssapi library
  87   AC_CHECK_LIB($gssapi_lib, gss_krb5_export_lucid_sec_context,
  88     AC_DEFINE(HAVE_LUCID_CONTEXT_SUPPORT, 1, [Define this if the Kerberos GSS library supports gss_krb5_export_lucid_sec_context]), ,$KRBLIBS)
  89   AC_CHECK_LIB($gssapi_lib, gss_krb5_set_allowable_enctypes,
  90     AC_DEFINE(HAVE_SET_ALLOWABLE_ENCTYPES, 1, [Define this if the Kerberos GSS library supports gss_krb5_set_allowable_enctypes]), ,$KRBLIBS)
  91   AC_CHECK_LIB($gssapi_lib, gss_krb5_ccache_name,
  92     AC_DEFINE(HAVE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the Kerberos GSS library supports gss_krb5_ccache_name]), ,$KRBLIBS)
  93
  94   dnl If they specified a directory and it didn't work, give them a warning
  95   if test "x$krb5_with" != "x" -a "$krb5_with" != "$KRBDIR"; then
  96     AC_MSG_WARN(Using $KRBDIR instead of requested value of $krb5_with for Kerberos!)
  97   fi
  98
  99   AC_SUBST([KRBDIR])
 100   AC_SUBST([KRBLIBS])
 101   AC_SUBST([KRBCFLAGS])
 102   AC_SUBST([KRBLDFLAGS])
 103   AC_SUBST([K5VERS])
 104
 105 ])