lib/Maypole/Model/CDBI.pm

   1 package Maypole::Model::CDBI;
   2 use base qw(Maypole::Model::Base Class::DBI);
   3 use Class::DBI::AsForm;
   4 use Class::DBI::FromCGI;
   5 use Class::DBI::Loader;
   6 use Class::DBI::AbstractSearch;
   7 use Class::DBI::Plugin::RetrieveAll;
   8 use Class::DBI::Pager;
   9
  10 use Lingua::EN::Inflect::Number qw(to_PL);
  11 use CGI::Untaint;
  12 use strict;
  13
  14 =head1 NAME
  15
  16 Maypole::Model::CDBI - Model class based on Class::DBI
  17
  18 =head1 DESCRIPTION
  19
  20 This is a master model class which uses C<Class::DBI> to do all the hard
  21 work of fetching rows and representing them as objects. It is a good
  22 model to copy if you're replacing it with other database abstraction
  23 modules.
  24
  25 =cut
  26
  27 sub related {
  28     my ( $self, $r ) = @_;
  29     return keys %{ $self->meta_info('has_many') || {} };
  30 }
  31
  32 sub do_edit : Exported {
  33     my ( $self, $r ) = @_;
  34     my $h        = CGI::Untaint->new( %{ $r->{params} } );
  35     my $creating = 0;
  36     my ($obj) = @{ $r->objects || [] };
  37     if ($obj) {
  38
  39         # We have something to edit
  40         $obj->update_from_cgi( $h =>
  41               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
  42         );
  43     }
  44     else {
  45         $obj =
  46           $self->create_from_cgi( $h =>
  47               { required => $r->{config}{ $r->{table} }{required_cols} || [], }
  48           );
  49         $creating++;
  50     }
  51     if ( my %errors = $obj->cgi_update_errors ) {
  52
  53         # Set it up as it was:
  54         $r->{template_args}{cgi_params} = $r->{params};
  55         $r->{template_args}{errors}     = \%errors;
  56         $r->{template}                  = "edit";
  57         undef $obj if $creating;    # Couldn't create
  58     }
  59     else {
  60         $r->{template} = "view";
  61     }
  62     $r->objects( [$obj] );
  63 }
  64
  65 sub delete : Exported {
  66     return shift->SUPER::delete(@_) if caller ne "Maypole::Model::Base";
  67     my ( $self, $r ) = @_;
  68     $_->SUPER::delete for @{ $r->objects || [] };
  69     $r->objects( [ $self->retrieve_all ] );
  70     $r->{template} = "list";
  71     $self->list($r);
  72 }
  73
  74 sub stringify_column {
  75     my $class = shift;
  76     return (
  77         $class->columns("Stringify"),
  78         ( grep { /(name|title)/i } $class->columns ),
  79         ( grep { !/id$/i } $class->primary_columns ),
  80     )[0];
  81 }
  82
  83 sub adopt {
  84     my ( $self, $child ) = @_;
  85     $child->autoupdate(1);
  86     if ( my $col = $child->stringify_column ) {
  87         $child->columns( Stringify => $col );
  88     }
  89 }
  90
  91 sub search : Exported {
  92     return shift->SUPER::search(@_) if caller ne "Maypole::Model::Base";
  93
  94     # A real CDBI search.
  95     my ( $self, $r ) = @_;
  96     my %fields = map { $_ => 1 } $self->columns;
  97     my $oper   = "like";                                # For now
  98     my %params = %{ $r->{params} };
  99     my %values = map { $_ => { $oper, $params{$_} } }
 100       grep { $params{$_} and $fields{$_} } keys %params;
 101
 102     $r->template("list");
 103     if ( !%values ) { return $self->list($r) }
 104     my $order = $self->order($r);
 105     $self = $self->do_pager($r);
 106     $r->objects(
 107         [
 108             $self->search_where( \%values ),
 109             ( $order ? { order => $order } : () )
 110         ]
 111     );
 112     $r->{template_args}{search} = 1;
 113 }
 114
 115 sub do_pager {
 116     my ( $self, $r ) = @_;
 117     if ( my $rows = $r->config->rows_per_page ) {
 118         return $r->{template_args}{pager} =
 119           $self->pager( $rows, $r->query->{page} );
 120     }
 121     else { return $self }
 122 }
 123
 124 sub order {
 125     my ( $self, $r ) = @_;
 126     my $order;
 127     my %ok_columns = map { $_ => 1 } $self->columns;
 128     if ( $order = $r->query->{order} and $ok_columns{$order} ) {
 129         $order .= ( $r->query->{o2} eq "desc" && " DESC" );
 130         }
 131         $order;
 132     }
 133
 134 sub list : Exported {
 135     my ( $self, $r ) = @_;
 136     my $order = $self->order($r);
 137     $self = $self->do_pager($r);
 138     if ($order) {
 139         $r->objects( [ $self->retrieve_all_sorted_by($order) ] );
 140     }
 141     else {
 142         $r->objects( [ $self->retrieve_all ] );
 143     }
 144 }
 145
 146 sub setup_database {
 147     my ($self, $config, $namespace, $dsn, $u, $p, $opts) = @_;
 148     $dsn  ||= $config->dsn;
 149     $u    ||= $config->user;
 150     $p    ||= $config->pass;
 151     $opts ||= $config->opts;
 152     $config->dsn($dsn);
 153     $config->loader || $config->loader( Class::DBI::Loader->new(
 154         namespace => $namespace,
 155         dsn => $dsn,
 156         user => $u,
 157         password => $p,
 158         options => $opts,
 159     ) );
 160     $config->{classes} = [ $config->{loader}->classes ];
 161     $config->{tables}  = [ $config->{loader}->tables ];
 162 }
 163
 164 sub class_of {
 165     my ( $self, $r, $table ) = @_;
 166     return $r->config->loader->_table2class($table);
 167 }
 168
 169 1;
 170