configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.0.8-rc4],[nfs@lists.sf.net],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_SRCDIR(tools/getiversion/getiversion.c)
   7 AC_CONFIG_MACRO_DIR(aclocal)
   8 AM_INIT_AUTOMAKE
   9 AC_PREREQ(2.59)
  10 AC_PREFIX_DEFAULT(/usr)
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_ENABLE(nfsv3,
  41         [AC_HELP_STRING([--enable-nfsv3],
  42                         [enable support for NFSv3 @<:@default=yes@:>@])],
  43         enable_nfsv3=$enableval,
  44         enable_nfsv3=yes)
  45         if test "$enable_nfsv3" = yes; then
  46                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  47         else
  48                 enable_nfsv3=
  49         fi
  50         AC_SUBST(enable_nfsv3)
  51 AC_ARG_ENABLE(nfsv4,
  52         [AC_HELP_STRING([--enable-nfsv4],
  53                         [enable support for NFSv4 @<:@default=yes@:>@])],
  54         enable_nfsv4=$enableval,
  55         enable_nfsv4=yes)
  56         if test "$enable_nfsv4" = yes; then
  57                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  58                 IDMAPD=idmapd
  59         else
  60                 enable_nfsv4=
  61                 IDMAPD=
  62         fi
  63         AC_SUBST(IDMAPD)
  64         AC_SUBST(enable_nfsv4)
  65         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  66 AC_ARG_ENABLE(gss,
  67         [AC_HELP_STRING([--enable-gss],
  68                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  69         enable_gss=$enableval,
  70         enable_gss=yes)
  71         if test "$enable_gss" = yes; then
  72                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  73                 GSSD=gssd
  74                 SVCGSSD=svcgssd
  75         else
  76                 enable_gss=
  77                 GSSD=
  78                 SVCGSSD=
  79         fi
  80         AC_SUBST(GSSD)
  81         AC_SUBST(SVCGSSD)
  82         AC_SUBST(enable_gss)
  83         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  84 AC_ARG_ENABLE(kprefix,
  85         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  86         test "$enableval" = "yes" && kprefix=k,
  87         kprefix=)
  88         AC_SUBST(kprefix)
  89 AC_ARG_ENABLE(secure-statd,
  90         [AC_HELP_STRING([--enable-secure-statd],
  91                         [Only lockd can use statd (security)])],
  92         test "$enableval" = "yes" && secure_statd=yes,
  93         secure_statd=no)
  94         if test "$secure_statd" = yes; then
  95                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
  96         fi
  97         AC_SUBST(secure_statd)
  98 AC_ARG_ENABLE(rquotad,
  99         [AC_HELP_STRING([--enable-rquotad],
 100                         [enable rquotad @<:@default=yes@:>@])],
 101         enable_rquotad=$enableval,
 102         enable_rquotad=yes)
 103         if test "$enable_rquotad" = yes; then
 104                 RQUOTAD=rquotad
 105         else
 106                 RQUOTAD=
 107         fi
 108         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
 109
 110 # Check whether user wants TCP wrappers support
 111 AC_TCP_WRAPPERS
 112
 113 AC_CONFIG_SRCDIR([support/include/config.h.in])
 114 AC_CONFIG_HEADERS([support/include/config.h])
 115
 116 # Checks for programs.
 117 AC_PROG_CXX
 118 AC_PROG_CC
 119 AC_PROG_CPP
 120 AC_PROG_INSTALL
 121 AC_PROG_LN_S
 122 AC_PROG_MAKE_SET
 123 AC_PROG_LIBTOOL
 124
 125 if test "x$cross_compiling" = "xno"; then
 126         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 127 else
 128         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 129 fi
 130
 131 AC_SUBST(CC_FOR_BUILD)
 132
 133 AC_CHECK_TOOL(AR, ar)
 134 AC_CHECK_TOOL(LD, ld)
 135
 136 AC_HEADER_STDC([])
 137 AC_GNULIBC
 138 AC_BSD_SIGNALS
 139
 140 dnl *************************************************************
 141 dnl * Check for required libraries
 142 dnl *************************************************************
 143 AC_CHECK_LIB(socket, main, [LIBSOCKET="-lnsl"])
 144 AC_CHECK_LIB(nsl, main, [LIBNSL="-lnsl"])
 145 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 146 if test "$enable_nfsv4" = yes; then
 147     AC_CHECK_LIB(event, event_dispatch, [libevent=1], [AC_MSG_ERROR(libevent needed for nfsv4 support)])
 148     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], [AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
 149     AC_CHECK_HEADERS(event.h, ,[AC_MSG_ERROR(libevent needed for nfsv4 support)])
 150     AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
 151     dnl librpcsecgss already has a dependency on libgssapi,
 152     dnl so we don't need to do an explicit check for libgssapi here
 153     if test "$enable_gss" = yes; then
 154      PKG_CHECK_MODULES(RPCSECGSS, librpcsecgss, [],
 155       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.
 156        If you have pkgconfig installed, you might try setting environment
 157        variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
 158       ]
 159      )
 160     fi
 161
 162 fi
 163 if test "$knfsd_cv_glibc2" = no; then
 164     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 165 fi
 166 AC_SUBST(LIBSOCKET)
 167 AC_SUBST(LIBNSL)
 168 AC_SUBST(LIBCRYPT)
 169 AC_SUBST(LIBBSD)
 170
 171 if test "$enable_gss" = yes; then
 172   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 173   AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for gss support)])
 174   AC_CHECK_HEADERS(spkm3.h, ,[AC_MSG_WARN(could not locate SPKM3 header; will not have SPKM3 support)])
 175
 176   dnl Check for Kerberos V5
 177   AC_KERBEROS_V5
 178
 179   dnl This is not done until here because we need to have KRBLIBS set
 180   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
 181   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], [AC_MSG_ERROR(librpcsecgss needed for nfsv4 support)], $KRBLIBS)
 182   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 183                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, $KRBLIBS)
 184
 185 fi
 186
 187 dnl *************************************************************
 188 dnl Check for headers
 189 dnl *************************************************************
 190 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 191                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 192                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 193                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 194                  syslog.h unistd.h com_err.h et/com_err.h])
 195
 196 dnl *************************************************************
 197 dnl Checks for typedefs, structures, and compiler characteristics
 198 dnl *************************************************************
 199 AC_C_CONST
 200 AC_TYPE_UID_T
 201 AC_C_INLINE
 202 AC_TYPE_OFF_T
 203 AC_TYPE_PID_T
 204 AC_TYPE_SIZE_T
 205 AC_HEADER_TIME
 206 AC_STRUCT_TM
 207
 208 dnl *************************************************************
 209 dnl Check for functions
 210 dnl *************************************************************
 211 AC_FUNC_ALLOCA
 212 AC_FUNC_CLOSEDIR_VOID
 213 AC_FUNC_ERROR_AT_LINE
 214 AC_FUNC_FORK
 215 AC_FUNC_GETGROUPS
 216 AC_FUNC_GETMNTENT
 217 AC_PROG_GCC_TRADITIONAL
 218 AC_FUNC_LSTAT
 219 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 220 AC_HEADER_MAJOR
 221 #AC_FUNC_MALLOC
 222 AC_FUNC_MEMCMP
 223 #AC_FUNC_REALLOC
 224 AC_FUNC_SELECT_ARGTYPES
 225 AC_TYPE_SIGNAL
 226 AC_FUNC_STAT
 227 AC_FUNC_VPRINTF
 228 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 229                gethostbyaddr gethostbyname gethostname getmntent \
 230                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 231                realpath rmdir select socket strcasecmp strchr strdup \
 232                strerror strrchr strtol strtoul])
 233
 234
 235 dnl *************************************************************
 236 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
 237 dnl *************************************************************
 238 AC_CHECK_SIZEOF(short)
 239 AC_CHECK_SIZEOF(int)
 240 AC_CHECK_SIZEOF(long)
 241 AC_CHECK_SIZEOF(size_t)
 242
 243 dnl *************************************************************
 244 dnl Export some path names to config.h
 245 dnl *************************************************************
 246 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 247
 248 if test "x$cross_compiling" = "xno"; then
 249         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 250         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 251         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 252         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 253 else
 254         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 255         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 256         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 257         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 258 fi
 259
 260 AC_SUBST(CFLAGS)
 261 AC_SUBST(CXXFLAGS)
 262 AC_SUBST(CPPFLAGS)
 263 AC_SUBST(LDFLAGS)
 264
 265 AC_SUBST(CFLAGS_FOR_BUILD)
 266 AC_SUBST(CXXFLAGS_FOR_BUILD)
 267 AC_SUBST(CPPFLAGS_FOR_BUILD)
 268 AC_SUBST(LDFLAGS_FOR_BUILD)
 269
 270 dnl *************************************************************
 271 dnl Set up "global" CFLAGS
 272 dnl *************************************************************
 273 dnl Use architecture-specific compile flags
 274 dnl (We use $host and not $build in case we are cross-compiling)
 275 dnl *************************************************************
 276 case $host in
 277   alpha*)
 278     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
 279   *)
 280     ARCHFLAGS="" ;;
 281 esac
 282
 283 my_am_cflags="-Wall $ARCHFLAGS -pipe"
 284
 285 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include -D_FILE_OFFSET_BITS=64"])
 286 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 287
 288 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 289 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 290
 291 AC_CONFIG_FILES([
 292         Makefile
 293         linux-nfs/Makefile
 294         support/Makefile
 295         support/export/Makefile
 296         support/include/nfs/Makefile
 297         support/include/rpcsvc/Makefile
 298         support/include/sys/fs/Makefile
 299         support/include/sys/Makefile
 300         support/include/Makefile
 301         support/misc/Makefile
 302         support/nfs/Makefile
 303         tools/Makefile
 304         tools/getiversion/Makefile
 305         tools/getkversion/Makefile
 306         tools/locktest/Makefile
 307         tools/nlmtest/Makefile
 308         tools/rpcdebug/Makefile
 309         tools/rpcgen/Makefile
 310         utils/Makefile
 311         utils/exportfs/Makefile
 312         utils/gssd/Makefile
 313         utils/idmapd/Makefile
 314         utils/lockd/Makefile
 315         utils/mountd/Makefile
 316         utils/nfsd/Makefile
 317         utils/nfsstat/Makefile
 318         utils/nhfsstone/Makefile
 319         utils/rquotad/Makefile
 320         utils/showmount/Makefile
 321         utils/statd/Makefile])
 322 AC_OUTPUT
 323