configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.0.8-rc3],[nfs@lists.sf.net],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_SRCDIR(tools/getiversion/getiversion.c)
   7 AC_CONFIG_MACRO_DIR(aclocal)
   8 AM_INIT_AUTOMAKE
   9 AC_PREREQ(2.59)
  10 AC_PREFIX_DEFAULT(/usr)
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_ENABLE(nfsv3,
  41         [AC_HELP_STRING([--enable-nfsv3],
  42                         [enable support for NFSv3 @<:@default=yes@:>@])],
  43         enable_nfsv3=$enableval,
  44         enable_nfsv3=yes)
  45         if test "$enable_nfsv3" = yes; then
  46                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  47         else
  48                 enable_nfsv3=
  49         fi
  50         AC_SUBST(enable_nfsv3)
  51 AC_ARG_ENABLE(nfsv4,
  52         [AC_HELP_STRING([--enable-nfsv4],
  53                         [enable support for NFSv4 @<:@default=yes@:>@])],
  54         enable_nfsv4=$enableval,
  55         enable_nfsv4=yes)
  56         if test "$enable_nfsv4" = yes; then
  57                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  58                 IDMAPD=idmapd
  59         else
  60                 enable_nfsv4=
  61                 IDMAPD=
  62         fi
  63         AC_SUBST(IDMAPD)
  64         AC_SUBST(enable_nfsv4)
  65         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  66 AC_ARG_ENABLE(gss,
  67         [AC_HELP_STRING([--enable-gss],
  68                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  69         enable_gss=$enableval,
  70         enable_gss=yes)
  71         if test "$enable_gss" = yes; then
  72                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  73                 GSSD=gssd
  74                 SVCGSSD=svcgssd
  75         else
  76                 enable_gss=
  77                 GSSD=
  78                 SVCGSSD=
  79         fi
  80         AC_SUBST(GSSD)
  81         AC_SUBST(SVCGSSD)
  82         AC_SUBST(enable_gss)
  83         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  84 AC_ARG_ENABLE(kprefix,
  85         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  86         test "$enableval" = "yes" && kprefix=k,
  87         kprefix=)
  88         AC_SUBST(kprefix)
  89 AC_ARG_ENABLE(secure-statd,
  90         [AC_HELP_STRING([--enable-secure-statd],
  91                         [Only lockd can use statd (security)])],
  92         test "$enableval" = "yes" && secure_statd=yes,
  93         secure_statd=no)
  94         if test "$secure_statd" = yes; then
  95                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
  96         fi
  97         AC_SUBST(secure_statd)
  98 AC_ARG_ENABLE(rquotad,
  99         [AC_HELP_STRING([--enable-rquotad],
 100                         [enable rquotad @<:@default=yes@:>@])],
 101         enable_rquotad=$enableval,
 102         enable_rquotad=yes)
 103         if test "$enable_rquotad" = yes; then
 104                 RQUOTAD=rquotad
 105         else
 106                 RQUOTAD=
 107         fi
 108         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
 109
 110 # Check whether user wants TCP wrappers support
 111 AC_TCP_WRAPPERS
 112
 113 AC_CONFIG_SRCDIR([support/include/config.h.in])
 114 AC_CONFIG_HEADERS([support/include/config.h])
 115
 116 # Checks for programs.
 117 AC_PROG_CXX
 118 AC_PROG_CC
 119 AC_PROG_CPP
 120 AC_PROG_INSTALL
 121 AC_PROG_LN_S
 122 AC_PROG_MAKE_SET
 123 AC_PROG_LIBTOOL
 124
 125 if test "x$cross_compiling" = "xno"; then
 126         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 127 else
 128         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 129 fi
 130
 131 AC_SUBST(CC_FOR_BUILD)
 132
 133 AC_CHECK_TOOL(AR, ar)
 134 AC_CHECK_TOOL(LD, ld)
 135
 136 AC_HEADER_STDC([])
 137 AC_GNULIBC
 138 AC_BSD_SIGNALS
 139
 140 dnl *************************************************************
 141 dnl * Check for required libraries
 142 dnl *************************************************************
 143 AC_CHECK_LIB(socket, main, [LIBSOCKET="-lnsl"])
 144 AC_CHECK_LIB(nsl, main, [LIBNSL="-lnsl"])
 145 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 146 if test "$enable_nfsv4" = yes; then
 147     AC_CHECK_LIB(event, event_dispatch, [libevent=1], [AC_MSG_ERROR(libevent needed for nfsv4 support)])
 148     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], [AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
 149     AC_CHECK_HEADERS(event.h, ,[AC_MSG_ERROR(libevent needed for nfsv4 support)])
 150     AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for nfsv4 support)])
 151 fi
 152 if test "$knfsd_cv_glibc2" = no; then
 153     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 154 fi
 155 AC_SUBST(LIBSOCKET)
 156 AC_SUBST(LIBNSL)
 157 AC_SUBST(LIBCRYPT)
 158 AC_SUBST(LIBBSD)
 159
 160 if test "$enable_gss" = yes; then
 161   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 162   AC_CHECK_HEADERS(nfsidmap.h, ,[AC_MSG_ERROR(libnfsidmap needed for gss support)])
 163   AC_CHECK_HEADERS(spkm3.h, ,[AC_MSG_WARN(could not locate SPKM3 header; will not have SPKM3 support)])
 164
 165   dnl Check for Kerberos V5
 166   AC_KERBEROS_V5
 167
 168   dnl This is not done until here because we need to have KRBLIBS set
 169   dnl "librpcsecgss=1" is so that it doesn't get added to LIBS
 170   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], [AC_MSG_ERROR(librpcsecgss needed for nfsv4 support)], $KRBLIBS)
 171   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 172                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, $KRBLIBS)
 173
 174 fi
 175
 176 dnl *************************************************************
 177 dnl Check for headers
 178 dnl *************************************************************
 179 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 180                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 181                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 182                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 183                  syslog.h unistd.h com_err.h et/com_err.h])
 184
 185 dnl *************************************************************
 186 dnl Checks for typedefs, structures, and compiler characteristics
 187 dnl *************************************************************
 188 AC_C_CONST
 189 AC_TYPE_UID_T
 190 AC_C_INLINE
 191 AC_TYPE_OFF_T
 192 AC_TYPE_PID_T
 193 AC_TYPE_SIZE_T
 194 AC_HEADER_TIME
 195 AC_STRUCT_TM
 196
 197 dnl *************************************************************
 198 dnl Check for functions
 199 dnl *************************************************************
 200 AC_FUNC_ALLOCA
 201 AC_FUNC_CLOSEDIR_VOID
 202 AC_FUNC_ERROR_AT_LINE
 203 AC_FUNC_FORK
 204 AC_FUNC_GETGROUPS
 205 AC_FUNC_GETMNTENT
 206 AC_PROG_GCC_TRADITIONAL
 207 AC_FUNC_LSTAT
 208 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 209 AC_HEADER_MAJOR
 210 #AC_FUNC_MALLOC
 211 AC_FUNC_MEMCMP
 212 #AC_FUNC_REALLOC
 213 AC_FUNC_SELECT_ARGTYPES
 214 AC_TYPE_SIGNAL
 215 AC_FUNC_STAT
 216 AC_FUNC_VPRINTF
 217 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 218                gethostbyaddr gethostbyname gethostname getmntent \
 219                gettimeofday hasmntopt inet_ntoa memset mkdir pathconf \
 220                realpath rmdir select socket strcasecmp strchr strdup \
 221                strerror strrchr strtol strtoul])
 222
 223
 224 dnl *************************************************************
 225 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
 226 dnl *************************************************************
 227 AC_CHECK_SIZEOF(short)
 228 AC_CHECK_SIZEOF(int)
 229 AC_CHECK_SIZEOF(long)
 230 AC_CHECK_SIZEOF(size_t)
 231
 232 dnl *************************************************************
 233 dnl Export some path names to config.h
 234 dnl *************************************************************
 235 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 236
 237 if test "x$cross_compiling" = "xno"; then
 238         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 239         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 240         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 241         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 242 else
 243         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 244         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 245         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 246         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 247 fi
 248
 249 AC_SUBST(CFLAGS)
 250 AC_SUBST(CXXFLAGS)
 251 AC_SUBST(CPPFLAGS)
 252 AC_SUBST(LDFLAGS)
 253
 254 AC_SUBST(CFLAGS_FOR_BUILD)
 255 AC_SUBST(CXXFLAGS_FOR_BUILD)
 256 AC_SUBST(CPPFLAGS_FOR_BUILD)
 257 AC_SUBST(LDFLAGS_FOR_BUILD)
 258
 259 dnl *************************************************************
 260 dnl Set up "global" CFLAGS
 261 dnl *************************************************************
 262 dnl Use architecture-specific compile flags
 263 dnl (We use $host and not $build in case we are cross-compiling)
 264 dnl *************************************************************
 265 case $host in
 266   alpha*)
 267     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
 268   *)
 269     ARCHFLAGS="" ;;
 270 esac
 271
 272 my_am_cflags="-Wall $ARCHFLAGS -pipe"
 273
 274 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include -D_FILE_OFFSET_BITS=64"])
 275 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 276
 277 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 278 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 279
 280 AC_CONFIG_FILES([
 281         Makefile
 282         linux-nfs/Makefile
 283         support/Makefile
 284         support/export/Makefile
 285         support/include/nfs/Makefile
 286         support/include/rpcsvc/Makefile
 287         support/include/sys/fs/Makefile
 288         support/include/sys/Makefile
 289         support/include/Makefile
 290         support/misc/Makefile
 291         support/nfs/Makefile
 292         tools/Makefile
 293         tools/getiversion/Makefile
 294         tools/getkversion/Makefile
 295         tools/locktest/Makefile
 296         tools/nlmtest/Makefile
 297         tools/rpcdebug/Makefile
 298         tools/rpcgen/Makefile
 299         utils/Makefile
 300         utils/exportfs/Makefile
 301         utils/gssd/Makefile
 302         utils/idmapd/Makefile
 303         utils/lockd/Makefile
 304         utils/mountd/Makefile
 305         utils/nfsd/Makefile
 306         utils/nfsstat/Makefile
 307         utils/nhfsstone/Makefile
 308         utils/rquotad/Makefile
 309         utils/showmount/Makefile
 310         utils/statd/Makefile])
 311 AC_OUTPUT
 312