configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.0.8],[nfs@lists.sf.net],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_SRCDIR(tools/getiversion/getiversion.c)
   7 AC_CONFIG_MACRO_DIR(aclocal)
   8 AM_INIT_AUTOMAKE
   9 AC_PREREQ(2.59)
  10 AC_PREFIX_DEFAULT(/usr)
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_ENABLE(nfsv3,
  41         [AC_HELP_STRING([--enable-nfsv3],
  42                         [enable support for NFSv3 @<:@default=yes@:>@])],
  43         enable_nfsv3=$enableval,
  44         enable_nfsv3=yes)
  45         if test "$enable_nfsv3" = yes; then
  46                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  47         else
  48                 enable_nfsv3=
  49         fi
  50         AC_SUBST(enable_nfsv3)
  51 AC_ARG_ENABLE(nfsv4,
  52         [AC_HELP_STRING([--enable-nfsv4],
  53                         [enable support for NFSv4 @<:@default=yes@:>@])],
  54         enable_nfsv4=$enableval,
  55         enable_nfsv4=yes)
  56         if test "$enable_nfsv4" = yes; then
  57                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  58                 IDMAPD=idmapd
  59         else
  60                 enable_nfsv4=
  61                 IDMAPD=
  62         fi
  63         AC_SUBST(IDMAPD)
  64         AC_SUBST(enable_nfsv4)
  65         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  66 AC_ARG_ENABLE(gss,
  67         [AC_HELP_STRING([--enable-gss],
  68                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  69         enable_gss=$enableval,
  70         enable_gss=yes)
  71         if test "$enable_gss" = yes; then
  72                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  73                 GSSD=gssd
  74                 SVCGSSD=svcgssd
  75         else
  76                 enable_gss=
  77                 GSSD=
  78                 SVCGSSD=
  79         fi
  80         AC_SUBST(GSSD)
  81         AC_SUBST(SVCGSSD)
  82         AC_SUBST(enable_gss)
  83         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  84 AC_ARG_ENABLE(kprefix,
  85         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  86         test "$enableval" = "yes" && kprefix=k,
  87         kprefix=)
  88         AC_SUBST(kprefix)
  89 AC_ARG_ENABLE(secure-statd,
  90         [AC_HELP_STRING([--enable-secure-statd],
  91                         [Only lockd can use statd (security)])],
  92         test "$enableval" = "yes" && secure_statd=yes,
  93         secure_statd=no)
  94         if test "$secure_statd" = yes; then
  95                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
  96         fi
  97         AC_SUBST(secure_statd)
  98 AC_ARG_ENABLE(rquotad,
  99         [AC_HELP_STRING([--enable-rquotad],
 100                         [enable rquotad @<:@default=yes@:>@])],
 101         enable_rquotad=$enableval,
 102         enable_rquotad=yes)
 103         if test "$enable_rquotad" = yes; then
 104                 RQUOTAD=rquotad
 105         else
 106                 RQUOTAD=
 107         fi
 108         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
 109
 110 AC_ARG_WITH(mount,
 111         [AC_HELP_STRING([--without-mount],
 112                         [Create mount.nfs and do not use the util-linux mount(8) functionality. By default it doesn't.])],
 113         use_mount=$withval,
 114         use_mount=yes)
 115         AM_CONDITIONAL(CONFIG_NOMOUNT, [test "$use_mount" = "no"])
 116
 117 # Check whether user wants TCP wrappers support
 118 AC_TCP_WRAPPERS
 119
 120 AC_CONFIG_SRCDIR([support/include/config.h.in])
 121 AC_CONFIG_HEADERS([support/include/config.h])
 122
 123 # Checks for programs.
 124 AC_PROG_CXX
 125 AC_PROG_CC
 126 AC_PROG_CPP
 127 AC_PROG_INSTALL
 128 AC_PROG_LN_S
 129 AC_PROG_MAKE_SET
 130 AC_PROG_LIBTOOL
 131
 132 if test "x$cross_compiling" = "xno"; then
 133         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 134 else
 135         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 136 fi
 137
 138 AC_SUBST(CC_FOR_BUILD)
 139
 140 AC_CHECK_TOOL(AR, ar)
 141 AC_CHECK_TOOL(LD, ld)
 142
 143 AC_HEADER_STDC([])
 144 AC_GNULIBC
 145 AC_BSD_SIGNALS
 146
 147 dnl *************************************************************
 148 dnl * Check for required libraries
 149 dnl *************************************************************
 150 AC_CHECK_LIB(socket, main, [LIBSOCKET="-lnsl"])
 151 AC_CHECK_LIB(nsl, main, [LIBNSL="-lnsl"])
 152 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 153 if test "$enable_nfsv4" = yes; then
 154     AC_CHECK_LIB(event, event_dispatch, [libevent=1], AC_MSG_ERROR([libevent needed for nfsv4 support]))
 155     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 156     AC_CHECK_HEADERS(event.h, ,AC_MSG_ERROR([libevent needed for nfsv4 support]))
 157     AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 158     dnl librpcsecgss already has a dependency on libgssapi,
 159     dnl but we need to make sure we get the right version
 160     if test "$enable_gss" = yes; then
 161      PKG_CHECK_MODULES(RPCSECGSS, librpcsecgss >= 0.10, ,
 162       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.])
 163        AC_MSG_ERROR([If you have pkgconfig installed, you might try setting environment])
 164        AC_MSG_ERROR([variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
 165       ]
 166      )
 167     PKG_CHECK_MODULES(GSSAPI, libgssapi >= 0.9)
 168     fi
 169
 170 fi
 171 if test "$knfsd_cv_glibc2" = no; then
 172     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 173 fi
 174 AC_SUBST(LIBSOCKET)
 175 AC_SUBST(LIBNSL)
 176 AC_SUBST(LIBCRYPT)
 177 AC_SUBST(LIBBSD)
 178
 179 if test "$enable_gss" = yes; then
 180   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 181   AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for gss support]))
 182   AC_CHECK_HEADERS(spkm3.h, ,AC_MSG_WARN([could not locate SPKM3 header; will not have SPKM3 support]))
 183   dnl the nfs4_set_debug function doesn't appear in all version of the library
 184   AC_CHECK_LIB(nfsidmap, nfs4_set_debug,
 185                AC_DEFINE(HAVE_NFS4_SET_DEBUG,1,
 186                          [Whether nfs4_set_debug() is present in libnfsidmap]),)
 187
 188   dnl Check for Kerberos V5
 189   AC_KERBEROS_V5
 190
 191   dnl This is not done until here because we need to have KRBLIBS set
 192   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
 193   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], AC_MSG_ERROR([librpcsecgss needed for nfsv4 support]), $KRBLIBS)
 194   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 195                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, $KRBLIBS)
 196
 197 fi
 198
 199 dnl *************************************************************
 200 dnl Check for headers
 201 dnl *************************************************************
 202 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 203                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 204                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 205                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 206                  syslog.h unistd.h com_err.h et/com_err.h \
 207                  ifaddrs.h])
 208
 209 dnl *************************************************************
 210 dnl Checks for typedefs, structures, and compiler characteristics
 211 dnl *************************************************************
 212 AC_C_CONST
 213 AC_TYPE_UID_T
 214 AC_C_INLINE
 215 AC_TYPE_OFF_T
 216 AC_TYPE_PID_T
 217 AC_TYPE_SIZE_T
 218 AC_HEADER_TIME
 219 AC_STRUCT_TM
 220
 221 dnl *************************************************************
 222 dnl Check for functions
 223 dnl *************************************************************
 224 AC_FUNC_ALLOCA
 225 AC_FUNC_CLOSEDIR_VOID
 226 AC_FUNC_ERROR_AT_LINE
 227 AC_FUNC_FORK
 228 AC_FUNC_GETGROUPS
 229 AC_FUNC_GETMNTENT
 230 AC_PROG_GCC_TRADITIONAL
 231 AC_FUNC_LSTAT
 232 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 233 AC_HEADER_MAJOR
 234 #AC_FUNC_MALLOC
 235 AC_FUNC_MEMCMP
 236 #AC_FUNC_REALLOC
 237 AC_FUNC_SELECT_ARGTYPES
 238 AC_TYPE_SIGNAL
 239 AC_FUNC_STAT
 240 AC_FUNC_VPRINTF
 241 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 242                gethostbyaddr gethostbyname gethostname getmntent \
 243                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 244                realpath rmdir select socket strcasecmp strchr strdup \
 245                strerror strrchr strtol strtoul sigprocmask])
 246
 247
 248 dnl *************************************************************
 249 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
 250 dnl *************************************************************
 251 AC_CHECK_SIZEOF(short)
 252 AC_CHECK_SIZEOF(int)
 253 AC_CHECK_SIZEOF(long)
 254 AC_CHECK_SIZEOF(size_t)
 255 AC_CHECK_SIZEOF(socklen_t)
 256
 257
 258 dnl *************************************************************
 259 dnl Export some path names to config.h
 260 dnl *************************************************************
 261 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 262
 263 if test "x$cross_compiling" = "xno"; then
 264         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 265         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 266         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 267         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 268 else
 269         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 270         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 271         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 272         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 273 fi
 274
 275 AC_SUBST(CFLAGS)
 276 AC_SUBST(CXXFLAGS)
 277 AC_SUBST(CPPFLAGS)
 278 AC_SUBST(LDFLAGS)
 279
 280 AC_SUBST(CFLAGS_FOR_BUILD)
 281 AC_SUBST(CXXFLAGS_FOR_BUILD)
 282 AC_SUBST(CPPFLAGS_FOR_BUILD)
 283 AC_SUBST(LDFLAGS_FOR_BUILD)
 284
 285 dnl *************************************************************
 286 dnl Set up "global" CFLAGS
 287 dnl *************************************************************
 288 dnl Use architecture-specific compile flags
 289 dnl (We use $host and not $build in case we are cross-compiling)
 290 dnl *************************************************************
 291 case $host in
 292   alpha*)
 293     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
 294   *)
 295     ARCHFLAGS="" ;;
 296 esac
 297
 298 my_am_cflags="-Wall $ARCHFLAGS -pipe"
 299
 300 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include -D_FILE_OFFSET_BITS=64"])
 301 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 302
 303 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 304 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 305
 306 AC_CONFIG_FILES([
 307         Makefile
 308         linux-nfs/Makefile
 309         support/Makefile
 310         support/export/Makefile
 311         support/include/nfs/Makefile
 312         support/include/rpcsvc/Makefile
 313         support/include/sys/fs/Makefile
 314         support/include/sys/Makefile
 315         support/include/Makefile
 316         support/misc/Makefile
 317         support/nfs/Makefile
 318         tools/Makefile
 319         tools/getiversion/Makefile
 320         tools/getkversion/Makefile
 321         tools/locktest/Makefile
 322         tools/nlmtest/Makefile
 323         tools/rpcdebug/Makefile
 324         tools/rpcgen/Makefile
 325         utils/Makefile
 326         utils/exportfs/Makefile
 327         utils/gssd/Makefile
 328         utils/idmapd/Makefile
 329         utils/lockd/Makefile
 330         utils/mount/Makefile
 331         utils/mountd/Makefile
 332         utils/nfsd/Makefile
 333         utils/nfsstat/Makefile
 334         utils/nhfsstone/Makefile
 335         utils/rquotad/Makefile
 336         utils/showmount/Makefile
 337         utils/statd/Makefile])
 338 AC_OUTPUT
 339