configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.0.11],[nfs@lists.sf.net],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_MACRO_DIR(aclocal)
   7 AM_INIT_AUTOMAKE
   8 AC_PREREQ(2.59)
   9 AC_PREFIX_DEFAULT(/usr)
  10 AM_MAINTAINER_MODE
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_WITH(start-statd,
  41         [AC_HELP_STRING([--with-start-statd=scriptname],
  42                         [When an nfs filesystems is mounted with locking, run this script]
  43         )],
  44         startstatd=$withval,
  45         startstatd=/usr/sbin/start-statd
  46         )
  47         AC_SUBST(startstatd)
  48         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  49 AC_ARG_ENABLE(nfsv3,
  50         [AC_HELP_STRING([--enable-nfsv3],
  51                         [enable support for NFSv3 @<:@default=yes@:>@])],
  52         enable_nfsv3=$enableval,
  53         enable_nfsv3=yes)
  54         if test "$enable_nfsv3" = yes; then
  55                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  56         else
  57                 enable_nfsv3=
  58         fi
  59         AC_SUBST(enable_nfsv3)
  60 AC_ARG_ENABLE(nfsv4,
  61         [AC_HELP_STRING([--enable-nfsv4],
  62                         [enable support for NFSv4 @<:@default=yes@:>@])],
  63         enable_nfsv4=$enableval,
  64         enable_nfsv4=yes)
  65         if test "$enable_nfsv4" = yes; then
  66                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  67                 IDMAPD=idmapd
  68         else
  69                 enable_nfsv4=
  70                 IDMAPD=
  71         fi
  72         AC_SUBST(IDMAPD)
  73         AC_SUBST(enable_nfsv4)
  74         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  75 AC_ARG_ENABLE(gss,
  76         [AC_HELP_STRING([--enable-gss],
  77                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  78         enable_gss=$enableval,
  79         enable_gss=yes)
  80         if test "$enable_gss" = yes; then
  81                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  82                 GSSD=gssd
  83                 SVCGSSD=svcgssd
  84         else
  85                 enable_gss=
  86                 GSSD=
  87                 SVCGSSD=
  88         fi
  89         AC_SUBST(GSSD)
  90         AC_SUBST(SVCGSSD)
  91         AC_SUBST(enable_gss)
  92         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  93 AC_ARG_ENABLE(kprefix,
  94         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  95         test "$enableval" = "yes" && kprefix=k,
  96         kprefix=)
  97         AC_SUBST(kprefix)
  98 AC_ARG_ENABLE(secure-statd,
  99         [AC_HELP_STRING([--enable-secure-statd],
 100                         [Only lockd can use statd (security)])],
 101         test "$enableval" = "yes" && secure_statd=yes,
 102         secure_statd=yes)
 103         if test "$secure_statd" = yes; then
 104                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
 105         fi
 106         AC_SUBST(secure_statd)
 107 AC_ARG_ENABLE(rquotad,
 108         [AC_HELP_STRING([--enable-rquotad],
 109                         [enable rquotad @<:@default=yes@:>@])],
 110         enable_rquotad=$enableval,
 111         enable_rquotad=yes)
 112         if test "$enable_rquotad" = yes; then
 113                 RQUOTAD=rquotad
 114         else
 115                 RQUOTAD=
 116         fi
 117         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
 118
 119 AC_ARG_ENABLE(mount,
 120         [AC_HELP_STRING([--enable-mount],
 121                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=no@:>@])],
 122         enable_mount=$enableval,
 123         enable_mount=no)
 124         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 125
 126 # Check whether user wants TCP wrappers support
 127 AC_TCP_WRAPPERS
 128
 129 # Arrange for large-file support
 130 AC_SYS_LARGEFILE
 131
 132 AC_CONFIG_SRCDIR([support/include/config.h.in])
 133 AC_CONFIG_HEADERS([support/include/config.h])
 134
 135 # Checks for programs.
 136 AC_PROG_CXX
 137 AC_PROG_CC
 138 AC_PROG_CPP
 139 AC_PROG_INSTALL
 140 AC_PROG_LN_S
 141 AC_PROG_MAKE_SET
 142 AC_PROG_LIBTOOL
 143 AM_PROG_CC_C_O
 144
 145 if test "x$cross_compiling" = "xno"; then
 146         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 147 else
 148         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 149 fi
 150
 151 AC_SUBST(CC_FOR_BUILD)
 152
 153 AC_CHECK_TOOL(AR, ar)
 154 AC_CHECK_TOOL(LD, ld)
 155
 156 AC_HEADER_STDC([])
 157 AC_GNULIBC
 158 AC_BSD_SIGNALS
 159
 160 dnl *************************************************************
 161 dnl * Check for required libraries
 162 dnl *************************************************************
 163 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(nsl, gethostbyname, [LIBNSL="-lnsl"])])
 164 AC_SUBST(LIBNSL)
 165
 166 AC_CHECK_FUNC(connect, ,
 167       AC_CHECK_LIB(socket, connect, [LIBSOCKET="-lsocket"],
 168                 AC_MSG_ERROR(Function 'socket' not found.), $LIBNSL))
 169
 170 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 171 if test "$enable_nfsv4" = yes; then
 172     AC_CHECK_LIB(event, event_dispatch, [libevent=1], AC_MSG_ERROR([libevent needed for nfsv4 support]))
 173     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 174     AC_CHECK_HEADERS(event.h, ,AC_MSG_ERROR([libevent needed for nfsv4 support]))
 175     AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 176     dnl librpcsecgss already has a dependency on libgssapi,
 177     dnl but we need to make sure we get the right version
 178     if test "$enable_gss" = yes; then
 179      PKG_CHECK_MODULES(RPCSECGSS, librpcsecgss >= 0.10, ,
 180       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.  If you have pkgconfig installed, you might try setting environment variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
 181       ]
 182      )
 183     PKG_CHECK_MODULES(GSSAPI, libgssapi >= 0.9)
 184     fi
 185
 186 fi
 187 if test "$knfsd_cv_glibc2" = no; then
 188     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 189 fi
 190 AC_CHECK_LIB(blkid, blkid_get_cache, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 191 AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot file libblkid header file blkid/blkid.h]))
 192 AC_SUBST(LIBSOCKET)
 193 AC_SUBST(LIBCRYPT)
 194 AC_SUBST(LIBBSD)
 195 AC_SUBST(LIBBLKID)
 196
 197 if test "$enable_gss" = yes; then
 198   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 199   AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for gss support]))
 200   AC_CHECK_HEADERS(spkm3.h, ,AC_MSG_WARN([could not locate SPKM3 header; will not have SPKM3 support]))
 201   dnl the nfs4_set_debug function doesn't appear in all version of the library
 202   AC_CHECK_LIB(nfsidmap, nfs4_set_debug,
 203                AC_DEFINE(HAVE_NFS4_SET_DEBUG,1,
 204                          [Whether nfs4_set_debug() is present in libnfsidmap]),)
 205
 206   dnl Check for Kerberos V5
 207   AC_KERBEROS_V5
 208
 209   dnl This is not done until here because we need to have KRBLIBS set
 210   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
 211   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], AC_MSG_ERROR([librpcsecgss needed for nfsv4 support]), -lgssapi -ldl)
 212   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 213                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, -lgssapi -ldl)
 214
 215 fi
 216
 217 dnl *************************************************************
 218 dnl Check for headers
 219 dnl *************************************************************
 220 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 221                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 222                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 223                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 224                  syslog.h unistd.h com_err.h et/com_err.h \
 225                  ifaddrs.h])
 226
 227 dnl *************************************************************
 228 dnl Checks for typedefs, structures, and compiler characteristics
 229 dnl *************************************************************
 230 AC_C_CONST
 231 AC_TYPE_UID_T
 232 AC_C_INLINE
 233 AC_TYPE_OFF_T
 234 AC_TYPE_PID_T
 235 AC_TYPE_SIZE_T
 236 AC_HEADER_TIME
 237 AC_STRUCT_TM
 238
 239 dnl *************************************************************
 240 dnl Check for functions
 241 dnl *************************************************************
 242 AC_FUNC_ALLOCA
 243 AC_FUNC_CLOSEDIR_VOID
 244 AC_FUNC_ERROR_AT_LINE
 245 AC_FUNC_FORK
 246 AC_FUNC_GETGROUPS
 247 AC_FUNC_GETMNTENT
 248 AC_PROG_GCC_TRADITIONAL
 249 AC_FUNC_LSTAT
 250 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 251 AC_HEADER_MAJOR
 252 #AC_FUNC_MALLOC
 253 AC_FUNC_MEMCMP
 254 #AC_FUNC_REALLOC
 255 AC_FUNC_SELECT_ARGTYPES
 256 AC_TYPE_SIGNAL
 257 AC_FUNC_STAT
 258 AC_FUNC_VPRINTF
 259 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 260                gethostbyaddr gethostbyname gethostname getmntent \
 261                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 262                realpath rmdir select socket strcasecmp strchr strdup \
 263                strerror strrchr strtol strtoul sigprocmask])
 264
 265
 266 dnl *************************************************************
 267 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
 268 dnl *************************************************************
 269 AC_CHECK_SIZEOF(short)
 270 AC_CHECK_SIZEOF(int)
 271 AC_CHECK_SIZEOF(long)
 272 AC_CHECK_SIZEOF(size_t)
 273 AC_CHECK_SIZEOF(socklen_t)
 274
 275
 276 dnl *************************************************************
 277 dnl Export some path names to config.h
 278 dnl *************************************************************
 279 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 280
 281 if test "x$cross_compiling" = "xno"; then
 282         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 283         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 284         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 285         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 286 else
 287         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 288         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 289         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 290         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 291 fi
 292
 293 AC_SUBST(CFLAGS)
 294 AC_SUBST(CXXFLAGS)
 295 AC_SUBST(CPPFLAGS)
 296 AC_SUBST(LDFLAGS)
 297
 298 AC_SUBST(CFLAGS_FOR_BUILD)
 299 AC_SUBST(CXXFLAGS_FOR_BUILD)
 300 AC_SUBST(CPPFLAGS_FOR_BUILD)
 301 AC_SUBST(LDFLAGS_FOR_BUILD)
 302
 303 dnl *************************************************************
 304 dnl Set up "global" CFLAGS
 305 dnl *************************************************************
 306 dnl Use architecture-specific compile flags
 307 dnl (We use $host and not $build in case we are cross-compiling)
 308 dnl *************************************************************
 309 case $host in
 310   alpha*)
 311     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
 312   *)
 313     ARCHFLAGS="" ;;
 314 esac
 315
 316 my_am_cflags="-Wall $ARCHFLAGS -pipe"
 317
 318 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include"])
 319 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 320
 321 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 322 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 323
 324 AC_CONFIG_FILES([
 325         Makefile
 326         linux-nfs/Makefile
 327         support/Makefile
 328         support/export/Makefile
 329         support/include/nfs/Makefile
 330         support/include/rpcsvc/Makefile
 331         support/include/sys/fs/Makefile
 332         support/include/sys/Makefile
 333         support/include/Makefile
 334         support/misc/Makefile
 335         support/nfs/Makefile
 336         tools/Makefile
 337         tools/locktest/Makefile
 338         tools/nlmtest/Makefile
 339         tools/rpcdebug/Makefile
 340         tools/rpcgen/Makefile
 341         utils/Makefile
 342         utils/exportfs/Makefile
 343         utils/gssd/Makefile
 344         utils/idmapd/Makefile
 345         utils/mount/Makefile
 346         utils/mountd/Makefile
 347         utils/nfsd/Makefile
 348         utils/nfsstat/Makefile
 349         utils/rquotad/Makefile
 350         utils/showmount/Makefile
 351         utils/statd/Makefile])
 352 AC_OUTPUT
 353