configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.0.11],[nfs@lists.sf.net],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_SRCDIR(tools/getiversion/getiversion.c)
   7 AC_CONFIG_MACRO_DIR(aclocal)
   8 AM_INIT_AUTOMAKE
   9 AC_PREREQ(2.59)
  10 AC_PREFIX_DEFAULT(/usr)
  11 AM_MAINTAINER_MODE
  12
  13 dnl *************************************************************
  14 dnl * Define the set of applicable options
  15 dnl *************************************************************
  16 AC_ARG_WITH(release,
  17         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  18         RELEASE=$withval,
  19         RELEASE=1)
  20         AC_SUBST(RELEASE)
  21 AC_ARG_WITH(statedir,
  22         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  23         statedir=$withval,
  24         statedir=/var/lib/nfs)
  25         AC_SUBST(statedir)
  26 AC_ARG_WITH(statduser,
  27         [AC_HELP_STRING([--with-statduser=rpcuser],
  28                         [statd to run under @<:@rpcuser or nobody@:>@]
  29         )],
  30         statduser=$withval,
  31         if test "x$cross_compiling" = "xno"; then
  32                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  33                         statduser=rpcuser
  34                 else
  35                         statduser=nobody
  36                 fi
  37         else
  38                 statduser=nobody
  39         fi)
  40         AC_SUBST(statduser)
  41 AC_ARG_WITH(start-statd,
  42         [AC_HELP_STRING([--with-start-statd=scriptname],
  43                         [When an nfs filesystems is mounted with locking, run this script]
  44         )],
  45         startstatd=$withval,
  46         startstatd=/usr/sbin/start-statd
  47         )
  48         AC_SUBST(startstatd)
  49         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  50 AC_ARG_ENABLE(nfsv3,
  51         [AC_HELP_STRING([--enable-nfsv3],
  52                         [enable support for NFSv3 @<:@default=yes@:>@])],
  53         enable_nfsv3=$enableval,
  54         enable_nfsv3=yes)
  55         if test "$enable_nfsv3" = yes; then
  56                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  57         else
  58                 enable_nfsv3=
  59         fi
  60         AC_SUBST(enable_nfsv3)
  61 AC_ARG_ENABLE(nfsv4,
  62         [AC_HELP_STRING([--enable-nfsv4],
  63                         [enable support for NFSv4 @<:@default=yes@:>@])],
  64         enable_nfsv4=$enableval,
  65         enable_nfsv4=yes)
  66         if test "$enable_nfsv4" = yes; then
  67                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  68                 IDMAPD=idmapd
  69         else
  70                 enable_nfsv4=
  71                 IDMAPD=
  72         fi
  73         AC_SUBST(IDMAPD)
  74         AC_SUBST(enable_nfsv4)
  75         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  76 AC_ARG_ENABLE(gss,
  77         [AC_HELP_STRING([--enable-gss],
  78                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  79         enable_gss=$enableval,
  80         enable_gss=yes)
  81         if test "$enable_gss" = yes; then
  82                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  83                 GSSD=gssd
  84                 SVCGSSD=svcgssd
  85         else
  86                 enable_gss=
  87                 GSSD=
  88                 SVCGSSD=
  89         fi
  90         AC_SUBST(GSSD)
  91         AC_SUBST(SVCGSSD)
  92         AC_SUBST(enable_gss)
  93         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  94 AC_ARG_ENABLE(kprefix,
  95         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  96         test "$enableval" = "yes" && kprefix=k,
  97         kprefix=)
  98         AC_SUBST(kprefix)
  99 AC_ARG_ENABLE(secure-statd,
 100         [AC_HELP_STRING([--enable-secure-statd],
 101                         [Only lockd can use statd (security)])],
 102         test "$enableval" = "yes" && secure_statd=yes,
 103         secure_statd=yes)
 104         if test "$secure_statd" = yes; then
 105                 AC_DEFINE(RESTRICTED_STATD, 1, [Define this if you want to enable various security checks in statd. These checks basically keep anyone but lockd from using this service.])
 106         fi
 107         AC_SUBST(secure_statd)
 108 AC_ARG_ENABLE(rquotad,
 109         [AC_HELP_STRING([--enable-rquotad],
 110                         [enable rquotad @<:@default=yes@:>@])],
 111         enable_rquotad=$enableval,
 112         enable_rquotad=yes)
 113         if test "$enable_rquotad" = yes; then
 114                 RQUOTAD=rquotad
 115         else
 116                 RQUOTAD=
 117         fi
 118         AM_CONDITIONAL(CONFIG_RQUOTAD, [test "$enable_rquotad" = "yes"])
 119
 120 AC_ARG_ENABLE(mount,
 121         [AC_HELP_STRING([--enable-mount],
 122                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=no@:>@])],
 123         enable_mount=$enableval,
 124         enable_mount=no)
 125         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 126
 127 # Check whether user wants TCP wrappers support
 128 AC_TCP_WRAPPERS
 129
 130 AC_CONFIG_SRCDIR([support/include/config.h.in])
 131 AC_CONFIG_HEADERS([support/include/config.h])
 132
 133 # Checks for programs.
 134 AC_PROG_CXX
 135 AC_PROG_CC
 136 AC_PROG_CPP
 137 AC_PROG_INSTALL
 138 AC_PROG_LN_S
 139 AC_PROG_MAKE_SET
 140 AC_PROG_LIBTOOL
 141
 142 if test "x$cross_compiling" = "xno"; then
 143         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 144 else
 145         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 146 fi
 147
 148 AC_SUBST(CC_FOR_BUILD)
 149
 150 AC_CHECK_TOOL(AR, ar)
 151 AC_CHECK_TOOL(LD, ld)
 152
 153 AC_HEADER_STDC([])
 154 AC_GNULIBC
 155 AC_BSD_SIGNALS
 156
 157 dnl *************************************************************
 158 dnl * Check for required libraries
 159 dnl *************************************************************
 160 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(nsl, gethostbyname, [LIBNSL="-lnsl"])])
 161 AC_SUBST(LIBNSL)
 162
 163 AC_CHECK_FUNC(connect, ,
 164       AC_CHECK_LIB(socket, connect, [LIBSOCKET="-lsocket"],
 165                 AC_MSG_ERROR(Function 'socket' not found.), $LIBNSL))
 166
 167 AC_CHECK_LIB(crypt, crypt, [LIBCRYPT="-lcrypt"])
 168 if test "$enable_nfsv4" = yes; then
 169     AC_CHECK_LIB(event, event_dispatch, [libevent=1], AC_MSG_ERROR([libevent needed for nfsv4 support]))
 170     AC_CHECK_LIB(nfsidmap, nfs4_init_name_mapping, [libnfsidmap=1], AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 171     AC_CHECK_HEADERS(event.h, ,AC_MSG_ERROR([libevent needed for nfsv4 support]))
 172     AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for nfsv4 support]))
 173     dnl librpcsecgss already has a dependency on libgssapi,
 174     dnl but we need to make sure we get the right version
 175     if test "$enable_gss" = yes; then
 176      PKG_CHECK_MODULES(RPCSECGSS, librpcsecgss >= 0.10, ,
 177       [AC_MSG_ERROR([Unable to locate information required to use librpcsecgss.  If you have pkgconfig installed, you might try setting environment variable PKG_CONFIG_PATH to /usr/local/lib/pkgconfig])
 178       ]
 179      )
 180     PKG_CHECK_MODULES(GSSAPI, libgssapi >= 0.9)
 181     fi
 182
 183 fi
 184 if test "$knfsd_cv_glibc2" = no; then
 185     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 186 fi
 187 AC_CHECK_LIB(blkid, blkid_get_cache, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 188 AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot file libblkid header file blkid/blkid.h]))
 189 AC_SUBST(LIBSOCKET)
 190 AC_SUBST(LIBCRYPT)
 191 AC_SUBST(LIBBSD)
 192 AC_SUBST(LIBBLKID)
 193
 194 if test "$enable_gss" = yes; then
 195   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 196   AC_CHECK_HEADERS(nfsidmap.h, ,AC_MSG_ERROR([libnfsidmap needed for gss support]))
 197   AC_CHECK_HEADERS(spkm3.h, ,AC_MSG_WARN([could not locate SPKM3 header; will not have SPKM3 support]))
 198   dnl the nfs4_set_debug function doesn't appear in all version of the library
 199   AC_CHECK_LIB(nfsidmap, nfs4_set_debug,
 200                AC_DEFINE(HAVE_NFS4_SET_DEBUG,1,
 201                          [Whether nfs4_set_debug() is present in libnfsidmap]),)
 202
 203   dnl Check for Kerberos V5
 204   AC_KERBEROS_V5
 205
 206   dnl This is not done until here because we need to have KRBLIBS set
 207   dnl ("librpcsecgss=1" is so that it doesn't get added to LIBS)
 208   AC_CHECK_LIB(rpcsecgss, authgss_create_default, [librpcsecgss=1], AC_MSG_ERROR([librpcsecgss needed for nfsv4 support]), -lgssapi -ldl)
 209   AC_CHECK_LIB(rpcsecgss, authgss_set_debug_level,
 210                AC_DEFINE(HAVE_AUTHGSS_SET_DEBUG_LEVEL, 1, [Define this if the rpcsec_gss library has the function authgss_set_debug_level]),, -lgssapi -ldl)
 211
 212 fi
 213
 214 dnl *************************************************************
 215 dnl Check for headers
 216 dnl *************************************************************
 217 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 218                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 219                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 220                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 221                  syslog.h unistd.h com_err.h et/com_err.h \
 222                  ifaddrs.h])
 223
 224 dnl *************************************************************
 225 dnl Checks for typedefs, structures, and compiler characteristics
 226 dnl *************************************************************
 227 AC_C_CONST
 228 AC_TYPE_UID_T
 229 AC_C_INLINE
 230 AC_TYPE_OFF_T
 231 AC_TYPE_PID_T
 232 AC_TYPE_SIZE_T
 233 AC_HEADER_TIME
 234 AC_STRUCT_TM
 235
 236 dnl *************************************************************
 237 dnl Check for functions
 238 dnl *************************************************************
 239 AC_FUNC_ALLOCA
 240 AC_FUNC_CLOSEDIR_VOID
 241 AC_FUNC_ERROR_AT_LINE
 242 AC_FUNC_FORK
 243 AC_FUNC_GETGROUPS
 244 AC_FUNC_GETMNTENT
 245 AC_PROG_GCC_TRADITIONAL
 246 AC_FUNC_LSTAT
 247 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 248 AC_HEADER_MAJOR
 249 #AC_FUNC_MALLOC
 250 AC_FUNC_MEMCMP
 251 #AC_FUNC_REALLOC
 252 AC_FUNC_SELECT_ARGTYPES
 253 AC_TYPE_SIGNAL
 254 AC_FUNC_STAT
 255 AC_FUNC_VPRINTF
 256 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 257                gethostbyaddr gethostbyname gethostname getmntent \
 258                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 259                realpath rmdir select socket strcasecmp strchr strdup \
 260                strerror strrchr strtol strtoul sigprocmask])
 261
 262
 263 dnl *************************************************************
 264 dnl Check for data sizes (XXX These should go away with libgssapi pkg-config)
 265 dnl *************************************************************
 266 AC_CHECK_SIZEOF(short)
 267 AC_CHECK_SIZEOF(int)
 268 AC_CHECK_SIZEOF(long)
 269 AC_CHECK_SIZEOF(size_t)
 270 AC_CHECK_SIZEOF(socklen_t)
 271
 272
 273 dnl *************************************************************
 274 dnl Export some path names to config.h
 275 dnl *************************************************************
 276 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 277
 278 if test "x$cross_compiling" = "xno"; then
 279         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 280         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 281         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 282         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 283 else
 284         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 285         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 286         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 287         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 288 fi
 289
 290 AC_SUBST(CFLAGS)
 291 AC_SUBST(CXXFLAGS)
 292 AC_SUBST(CPPFLAGS)
 293 AC_SUBST(LDFLAGS)
 294
 295 AC_SUBST(CFLAGS_FOR_BUILD)
 296 AC_SUBST(CXXFLAGS_FOR_BUILD)
 297 AC_SUBST(CPPFLAGS_FOR_BUILD)
 298 AC_SUBST(LDFLAGS_FOR_BUILD)
 299
 300 dnl *************************************************************
 301 dnl Set up "global" CFLAGS
 302 dnl *************************************************************
 303 dnl Use architecture-specific compile flags
 304 dnl (We use $host and not $build in case we are cross-compiling)
 305 dnl *************************************************************
 306 case $host in
 307   alpha*)
 308     ARCHFLAGS="-mno-fp-regs -ffixed-8" ;;
 309   *)
 310     ARCHFLAGS="" ;;
 311 esac
 312
 313 my_am_cflags="-Wall $ARCHFLAGS -pipe"
 314
 315 AC_SUBST([AM_CPPFLAGS], ["-I\${top_srcdir}/support/include -D_FILE_OFFSET_BITS=64"])
 316 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 317
 318 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 319 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 320
 321 AC_CONFIG_FILES([
 322         Makefile
 323         linux-nfs/Makefile
 324         support/Makefile
 325         support/export/Makefile
 326         support/include/nfs/Makefile
 327         support/include/rpcsvc/Makefile
 328         support/include/sys/fs/Makefile
 329         support/include/sys/Makefile
 330         support/include/Makefile
 331         support/misc/Makefile
 332         support/nfs/Makefile
 333         tools/Makefile
 334         tools/getiversion/Makefile
 335         tools/locktest/Makefile
 336         tools/nlmtest/Makefile
 337         tools/rpcdebug/Makefile
 338         tools/rpcgen/Makefile
 339         utils/Makefile
 340         utils/exportfs/Makefile
 341         utils/gssd/Makefile
 342         utils/idmapd/Makefile
 343         utils/mount/Makefile
 344         utils/mountd/Makefile
 345         utils/nfsd/Makefile
 346         utils/nfsstat/Makefile
 347         utils/rquotad/Makefile
 348         utils/showmount/Makefile
 349         utils/statd/Makefile])
 350 AC_OUTPUT
 351