configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.2.0],[linux-nfs@vger.kernel.org],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_MACRO_DIR(aclocal)
   7 AM_INIT_AUTOMAKE
   8 AC_PREREQ(2.59)
   9 AC_PREFIX_DEFAULT(/usr)
  10 AM_MAINTAINER_MODE
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [  --with-statedir=/foo    use state dir /foo [/var/lib/nfs]],
  22         statedir=$withval,
  23         statedir=/var/lib/nfs)
  24         AC_SUBST(statedir)
  25 AC_ARG_WITH(statduser,
  26         [AC_HELP_STRING([--with-statduser=rpcuser],
  27                         [statd to run under @<:@rpcuser or nobody@:>@]
  28         )],
  29         statduser=$withval,
  30         if test "x$cross_compiling" = "xno"; then
  31                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  32                         statduser=rpcuser
  33                 else
  34                         statduser=nobody
  35                 fi
  36         else
  37                 statduser=nobody
  38         fi)
  39         AC_SUBST(statduser)
  40 AC_ARG_WITH(start-statd,
  41         [AC_HELP_STRING([--with-start-statd=scriptname],
  42                         [When an nfs filesystems is mounted with locking, run this script]
  43         )],
  44         startstatd=$withval,
  45         startstatd=/usr/sbin/start-statd
  46         )
  47         AC_SUBST(startstatd)
  48         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  49 AC_ARG_ENABLE(nfsv3,
  50         [AC_HELP_STRING([--enable-nfsv3],
  51                         [enable support for NFSv3 @<:@default=yes@:>@])],
  52         enable_nfsv3=$enableval,
  53         enable_nfsv3=yes)
  54         if test "$enable_nfsv3" = yes; then
  55                 AC_DEFINE(NFS3_SUPPORTED, 1, [Define this if you want NFSv3 support compiled in])
  56         else
  57                 enable_nfsv3=
  58         fi
  59         AC_SUBST(enable_nfsv3)
  60 AC_ARG_ENABLE(nfsv4,
  61         [AC_HELP_STRING([--enable-nfsv4],
  62                         [enable support for NFSv4 @<:@default=yes@:>@])],
  63         enable_nfsv4=$enableval,
  64         enable_nfsv4=yes)
  65         if test "$enable_nfsv4" = yes; then
  66                 AC_DEFINE(NFS4_SUPPORTED, 1, [Define this if you want NFSv4 support compiled in])
  67                 IDMAPD=idmapd
  68         else
  69                 enable_nfsv4=
  70                 IDMAPD=
  71         fi
  72         AC_SUBST(IDMAPD)
  73         AC_SUBST(enable_nfsv4)
  74         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  75 AC_ARG_ENABLE(gss,
  76         [AC_HELP_STRING([--enable-gss],
  77                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  78         enable_gss=$enableval,
  79         enable_gss=yes)
  80         if test "$enable_gss" = yes; then
  81                 AC_DEFINE(GSS_SUPPORTED, 1, [Define this if you want rpcsec_gss support compiled in])
  82                 GSSD=gssd
  83                 SVCGSSD=svcgssd
  84         else
  85                 enable_gss=
  86                 GSSD=
  87                 SVCGSSD=
  88         fi
  89         AC_SUBST(GSSD)
  90         AC_SUBST(SVCGSSD)
  91         AC_SUBST(enable_gss)
  92         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
  93 AC_ARG_ENABLE(kprefix,
  94         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
  95         test "$enableval" = "yes" && kprefix=k,
  96         kprefix=)
  97         AC_SUBST(kprefix)
  98 AC_ARG_WITH(rpcgen,
  99         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
 100         rpcgen_path=$withval,
 101         rpcgen_path=yes )
 102         RPCGEN_PATH=
 103         if test "$rpcgen_path" == "yes"; then
 104             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
 105             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
 106         elif test "$rpcgen_path" != "internal"; then
 107             RPCGEN_PATH=$rpcgen_path
 108         fi
 109         AC_SUBST(RPCGEN_PATH)
 110         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" == ""])
 111 AC_ARG_ENABLE(uuid,
 112         [AC_HELP_STRING([--disable-uuid], [Exclude uuid support to avoid buggy libblkid])],
 113         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
 114         choose_blkid=default)
 115 AC_ARG_ENABLE(mount,
 116         [AC_HELP_STRING([--enable-mount],
 117                         [Create mount.nfs and don't use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
 118         enable_mount=$enableval,
 119         enable_mount=yes)
 120         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 121 AC_ARG_ENABLE(tirpc,
 122         [AC_HELP_STRING([--enable-tirpc],
 123                         [enable use of TI-RPC @<:@default=yes@:>@])],
 124         enable_tirpc=$enableval,
 125         enable_tirpc='yes')
 126 AC_ARG_ENABLE(ipv6,
 127         [AC_HELP_STRING([--enable-ipv6],
 128                         [enable support for IPv6 @<:@default=no@:>@])],
 129         enable_ipv6=$enableval,
 130         enable_ipv6=no)
 131         if test "$enable_ipv6" = yes; then
 132                 AC_DEFINE(IPV6_SUPPORTED, 1, [Define this if you want IPv6 support compiled in])
 133         else
 134                 enable_ipv6=
 135         fi
 136         AC_SUBST(enable_ipv6)
 137         AM_CONDITIONAL(CONFIG_IPV6, [test "$enable_ipv6" = "yes"])
 138
 139 dnl Check for TI-RPC library and headers
 140 AC_LIBTIRPC
 141
 142 # Check whether user wants TCP wrappers support
 143 AC_TCP_WRAPPERS
 144
 145 # Arrange for large-file support
 146 AC_SYS_LARGEFILE
 147
 148 AC_CONFIG_SRCDIR([support/include/config.h.in])
 149 AC_CONFIG_HEADERS([support/include/config.h])
 150
 151 # Checks for programs.
 152 AC_PROG_CXX
 153 AC_PROG_CC
 154 AC_PROG_CPP
 155 AC_PROG_INSTALL
 156 AC_PROG_LN_S
 157 AC_PROG_MAKE_SET
 158 AC_PROG_LIBTOOL
 159 AM_PROG_CC_C_O
 160
 161 if test "x$cross_compiling" = "xno"; then
 162         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 163 else
 164         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 165 fi
 166
 167 AC_SUBST(CC_FOR_BUILD)
 168
 169 AC_CHECK_TOOL(AR, ar)
 170 AC_CHECK_TOOL(LD, ld)
 171
 172 AC_HEADER_STDC([])
 173 AC_GNULIBC
 174 AC_BSD_SIGNALS
 175
 176 dnl *************************************************************
 177 dnl * Check for required libraries
 178 dnl *************************************************************
 179
 180 AC_CHECK_FUNC([gethostbyname], ,
 181               [AC_CHECK_LIB([nsl], [gethostbyname], [LIBNSL="-lnsl"])])
 182 AC_SUBST(LIBNSL)
 183
 184 AC_CHECK_FUNC([connect], ,
 185               [AC_CHECK_LIB([socket], [connect], [LIBSOCKET="-lsocket"],
 186                     [AC_MSG_ERROR([Function 'socket' not found.])], [$LIBNSL])])
 187
 188 AC_CHECK_FUNC([getaddrinfo], ,
 189               [AC_MSG_ERROR([Function 'getaddrinfo' not found.])])
 190
 191 AC_CHECK_FUNC([getrpcbynumber], ,
 192               [AC_MSG_ERROR([Function 'getrpcbynumber' not found.])])
 193
 194 AC_CHECK_FUNC([getservbyname], ,
 195               [AC_MSG_ERROR([Function 'getservbyname' not found.])])
 196
 197 AC_CHECK_LIB([crypt], [crypt], [LIBCRYPT="-lcrypt"])
 198
 199 if test "$enable_nfsv4" = yes; then
 200   dnl check for libevent libraries and headers
 201   AC_LIBEVENT
 202
 203   dnl check for nfsidmap libraries and headers
 204   AC_LIBNFSIDMAP
 205
 206   dnl librpcsecgss already has a dependency on libgssapi,
 207   dnl but we need to make sure we get the right version
 208   if test "$enable_gss" = yes; then
 209     AC_RPCSEC_VERSION
 210   fi
 211 fi
 212
 213 if test "$knfsd_cv_glibc2" = no; then
 214     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 215 fi
 216
 217 if test "$choose_blkid" != no; then
 218    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 219    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
 220    AC_BLKID_VERS
 221    if test $choose_blkid = yes; then
 222       use_blkid=1
 223       test $libblkid_cv_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
 224    else
 225       if test $libblkid_cv_is_recent = yes
 226       then use_blkid=1
 227       else use_blkid=0
 228            AC_MSG_WARN([uuid support disabled as libblkid is too old])
 229       fi
 230     fi
 231     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
 232 fi
 233 AC_SUBST(LIBSOCKET)
 234 AC_SUBST(LIBCRYPT)
 235 AC_SUBST(LIBBSD)
 236 AC_SUBST(LIBBLKID)
 237
 238 if test "$enable_gss" = yes; then
 239   dnl 'gss' requires getnameinfo - at least for gssd_proc.c
 240   AC_CHECK_FUNC([getnameinfo], , [AC_MSG_ERROR([GSSAPI support requires 'getnameinfo' function])])
 241
 242   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 243   AC_LIBNFSIDMAP
 244
 245   AC_CHECK_HEADERS([spkm3.h], ,
 246                    [AC_MSG_WARN([Could not locate SPKM3 header; will not have SPKM3 support])])
 247
 248   dnl Check for Kerberos V5
 249   AC_KERBEROS_V5
 250
 251   dnl Invoked after AC_KERBEROS_V5; AC_LIBRPCSECGSS needs to have KRBLIBS set
 252   AC_LIBRPCSECGSS
 253
 254 fi
 255
 256 dnl Check for IPv6 support
 257 AC_IPV6
 258
 259 dnl *************************************************************
 260 dnl Check for headers
 261 dnl *************************************************************
 262 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 263                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 264                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 265                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 266                  syslog.h unistd.h com_err.h et/com_err.h \
 267                  ifaddrs.h])
 268
 269 dnl *************************************************************
 270 dnl Checks for typedefs, structures, and compiler characteristics
 271 dnl *************************************************************
 272 AC_C_CONST
 273 AC_TYPE_UID_T
 274 AC_C_INLINE
 275 AC_TYPE_OFF_T
 276 AC_TYPE_PID_T
 277 AC_TYPE_SIZE_T
 278 AC_HEADER_TIME
 279 AC_STRUCT_TM
 280
 281 dnl *************************************************************
 282 dnl Check for functions
 283 dnl *************************************************************
 284 AC_FUNC_ALLOCA
 285 AC_FUNC_CLOSEDIR_VOID
 286 AC_FUNC_ERROR_AT_LINE
 287 AC_FUNC_FORK
 288 AC_FUNC_GETGROUPS
 289 AC_FUNC_GETMNTENT
 290 AC_PROG_GCC_TRADITIONAL
 291 AC_FUNC_LSTAT
 292 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 293 AC_HEADER_MAJOR
 294 #AC_FUNC_MALLOC
 295 AC_FUNC_MEMCMP
 296 #AC_FUNC_REALLOC
 297 AC_FUNC_SELECT_ARGTYPES
 298 AC_TYPE_SIGNAL
 299 AC_FUNC_STAT
 300 AC_FUNC_VPRINTF
 301 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 302                gethostbyaddr gethostbyname gethostname getmntent \
 303                getnameinfo getrpcbyname \
 304                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 305                realpath rmdir select socket strcasecmp strchr strdup \
 306                strerror strrchr strtol strtoul sigprocmask])
 307
 308
 309 dnl *************************************************************
 310 dnl Check for data sizes
 311 dnl *************************************************************
 312 AC_CHECK_SIZEOF(short)
 313 AC_CHECK_SIZEOF(int)
 314 AC_CHECK_SIZEOF(long)
 315 AC_CHECK_SIZEOF(size_t)
 316 AC_CHECK_SIZEOF(socklen_t)
 317
 318
 319 dnl *************************************************************
 320 dnl Export some path names to config.h
 321 dnl *************************************************************
 322 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 323
 324 if test "x$cross_compiling" = "xno"; then
 325         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 326         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 327         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 328         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 329 else
 330         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 331         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 332         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 333         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 334 fi
 335
 336 AC_SUBST(CFLAGS)
 337 AC_SUBST(CXXFLAGS)
 338 AC_SUBST(CPPFLAGS)
 339 AC_SUBST(LDFLAGS)
 340
 341 AC_SUBST(CFLAGS_FOR_BUILD)
 342 AC_SUBST(CXXFLAGS_FOR_BUILD)
 343 AC_SUBST(CPPFLAGS_FOR_BUILD)
 344 AC_SUBST(LDFLAGS_FOR_BUILD)
 345
 346 dnl *************************************************************
 347 dnl Set up "global" CFLAGS
 348 dnl *************************************************************
 349 dnl Use architecture-specific compile flags
 350 dnl (We use $host and not $build in case we are cross-compiling)
 351 dnl *************************************************************
 352 dnl Note: we no longer have arch specific compile flags, but
 353 dnl the stub is left here in case they are needed one day.
 354 case $host in
 355   *)
 356     ARCHFLAGS="" ;;
 357 esac
 358
 359 my_am_cflags="-Wall -Wstrict-prototypes $ARCHFLAGS -pipe"
 360
 361 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 362
 363 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 364 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 365
 366 AC_CONFIG_FILES([
 367         Makefile
 368         linux-nfs/Makefile
 369         support/Makefile
 370         support/export/Makefile
 371         support/include/nfs/Makefile
 372         support/include/rpcsvc/Makefile
 373         support/include/sys/fs/Makefile
 374         support/include/sys/Makefile
 375         support/include/Makefile
 376         support/misc/Makefile
 377         support/nfs/Makefile
 378         tools/Makefile
 379         tools/locktest/Makefile
 380         tools/nlmtest/Makefile
 381         tools/rpcdebug/Makefile
 382         tools/rpcgen/Makefile
 383         utils/Makefile
 384         utils/exportfs/Makefile
 385         utils/gssd/Makefile
 386         utils/idmapd/Makefile
 387         utils/mount/Makefile
 388         utils/mountd/Makefile
 389         utils/nfsd/Makefile
 390         utils/nfsstat/Makefile
 391         utils/showmount/Makefile
 392         utils/statd/Makefile])
 393 AC_OUTPUT
 394