configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.2.4],[linux-nfs@vger.kernel.org],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_MACRO_DIR(aclocal)
   7 AM_INIT_AUTOMAKE
   8 AC_PREREQ(2.59)
   9 AC_PREFIX_DEFAULT(/usr)
  10 AM_MAINTAINER_MODE
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [AC_HELP_STRING([--with-statedir=/foo],
  22                         [use state dir /foo @<:@default=/var/lib/nfs@:>@])],
  23         statedir=$withval,
  24         statedir=/var/lib/nfs)
  25         AC_SUBST(statedir)
  26 AC_ARG_WITH(statdpath,
  27         [AC_HELP_STRING([--with-statdpath=/foo @<:@default=/var/lib/nfs@:>@],
  28                 [define statd's state dir as /foo instead of the NFS statedir]
  29         )],
  30         statdpath=$withval,
  31         statdpath=$statedir
  32         )
  33         AC_SUBST(statdpath)
  34 AC_ARG_WITH(statduser,
  35         [AC_HELP_STRING([--with-statduser=rpcuser],
  36                         [statd to run under @<:@rpcuser or nobody@:>@]
  37         )],
  38         statduser=$withval,
  39         if test "x$cross_compiling" = "xno"; then
  40                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  41                         statduser=rpcuser
  42                 else
  43                         statduser=nobody
  44                 fi
  45         else
  46                 statduser=nobody
  47         fi)
  48         AC_SUBST(statduser)
  49 AC_ARG_WITH(start-statd,
  50         [AC_HELP_STRING([--with-start-statd=scriptname],
  51                         [When an nfs filesystems is mounted with locking, run this script]
  52         )],
  53         startstatd=$withval,
  54         startstatd=/usr/sbin/start-statd
  55         )
  56         AC_SUBST(startstatd)
  57         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  58 AC_ARG_ENABLE(nfsv4,
  59         [AC_HELP_STRING([--enable-nfsv4],
  60                         [enable support for NFSv4 @<:@default=yes@:>@])],
  61         enable_nfsv4=$enableval,
  62         enable_nfsv4=yes)
  63         if test "$enable_nfsv4" = yes; then
  64                 IDMAPD=idmapd
  65         else
  66                 enable_nfsv4=
  67                 IDMAPD=
  68         fi
  69         AC_SUBST(IDMAPD)
  70         AC_SUBST(enable_nfsv4)
  71         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  72
  73 AC_ARG_ENABLE(nfsv41,
  74         [AC_HELP_STRING([--enable-nfsv41],
  75                         [enable support for NFSv41 @<:@default=yes@:>@])],
  76         enable_nfsv41=$enableval,
  77         enable_nfsv41=yes)
  78         if test "$enable_nfsv41" = yes; then
  79                 if test "$enable_nfsv4" != yes; then
  80                         AC_MSG_ERROR([NFS v4.1 is enabled but NFS v4 is not. Use --disable-nfsv41])
  81                 fi
  82                 BLKMAPD=blkmapd
  83         else
  84                 enable_nfsv41=
  85                 BLKMAPD=
  86         fi
  87         AC_SUBST(enable_nfsv41)
  88         AM_CONDITIONAL(CONFIG_NFSV41, [test "$enable_nfsv41" = "yes"])
  89
  90 AC_ARG_ENABLE(gss,
  91         [AC_HELP_STRING([--enable-gss],
  92                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  93         enable_gss=$enableval,
  94         enable_gss=yes)
  95         if test "$enable_gss" = yes; then
  96                 GSSD=gssd
  97                 SVCGSSD=svcgssd
  98         else
  99                 enable_gss=
 100                 GSSD=
 101                 SVCGSSD=
 102         fi
 103         AC_SUBST(GSSD)
 104         AC_SUBST(SVCGSSD)
 105         AC_SUBST(enable_gss)
 106         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
 107 AC_ARG_ENABLE(kprefix,
 108         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
 109         test "$enableval" = "yes" && kprefix=k,
 110         kprefix=)
 111         AC_SUBST(kprefix)
 112 AC_ARG_WITH(rpcgen,
 113         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
 114         rpcgen_path=$withval,
 115         rpcgen_path=yes )
 116         RPCGEN_PATH=
 117         if test "$rpcgen_path" = "yes"; then
 118             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
 119             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
 120         elif test "$rpcgen_path" != "internal"; then
 121             RPCGEN_PATH=$rpcgen_path
 122         fi
 123         AC_SUBST(RPCGEN_PATH)
 124         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" = ""])
 125 AC_ARG_ENABLE(uuid,
 126         [AC_HELP_STRING([--disable-uuid], [Exclude uuid support to avoid buggy libblkid])],
 127         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
 128         choose_blkid=default)
 129 AC_ARG_ENABLE(mount,
 130         [AC_HELP_STRING([--enable-mount],
 131                         [Create mount.nfs and do not use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
 132         enable_mount=$enableval,
 133         enable_mount=yes)
 134         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 135
 136 if test "$enable_mount" = yes; then
 137         AC_ARG_ENABLE(libmount-mount,
 138                 [AC_HELP_STRING([--enable-libmount-mount],
 139                                 [Link mount.nfs with libmount (EXPERIMENTAL)])],
 140                 enable_libmount=$enableval,
 141                 enable_libmount=no)
 142 fi
 143
 144 AC_ARG_ENABLE(tirpc,
 145         [AC_HELP_STRING([--enable-tirpc],
 146                         [enable use of TI-RPC @<:@default=yes@:>@])],
 147         enable_tirpc=$enableval,
 148         enable_tirpc='')
 149 AC_ARG_ENABLE(ipv6,
 150         [AC_HELP_STRING([--enable-ipv6],
 151                         [enable support for IPv6 @<:@default=no@:>@])],
 152         enable_ipv6=$enableval,
 153         enable_ipv6=no)
 154         if test "$enable_ipv6" = yes; then
 155                 AC_DEFINE(IPV6_SUPPORTED, 1, [Define this if you want IPv6 support compiled in])
 156         else
 157                 enable_ipv6=
 158         fi
 159         AC_SUBST(enable_ipv6)
 160         AM_CONDITIONAL(CONFIG_IPV6, [test "$enable_ipv6" = "yes"])
 161
 162 if test "$enable_mount" = yes; then
 163         AC_ARG_ENABLE(mountconfig,
 164         [AC_HELP_STRING([--enable-mountconfig],
 165                         [enable mount to use a configuration file])],
 166         mountconfig=$enableval,
 167         mountconfig=no)
 168         if test "$enable_mountconfig" = yes; then
 169                 AC_DEFINE(MOUNT_CONFIG, 1,
 170                         [Define this if you want mount to read a configuration file])
 171                 AC_ARG_WITH(mountfile,
 172                         [AC_HELP_STRING([--with-mountfile=filename],
 173                         [Using filename as the NFS mount options file [/etc/nfsmounts.conf]]
 174                         )],
 175                 mountfile=$withval,
 176                 mountfile=/etc/nfsmount.conf)
 177                 AC_SUBST(mountfile)
 178                 AC_DEFINE_UNQUOTED(MOUNTOPTS_CONFFILE, "$mountfile",
 179                         [This defines the location of the NFS mount configuration file])
 180         else
 181                 enable_mountconfig=
 182         fi
 183         AC_SUBST(enable_mountconfig)
 184         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mountconfig" = "yes"])
 185 else
 186         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mount" = "yes"])
 187 fi
 188
 189 dnl Check for TI-RPC library and headers
 190 AC_LIBTIRPC
 191
 192 dnl Check for -lcap
 193 AC_LIBCAP
 194
 195 # Check whether user wants TCP wrappers support
 196 AC_TCP_WRAPPERS
 197
 198 # Arrange for large-file support
 199 AC_SYS_LARGEFILE
 200
 201 AC_CONFIG_SRCDIR([support/include/config.h.in])
 202 AC_CONFIG_HEADERS([support/include/config.h])
 203
 204 # Checks for programs.
 205 AC_PROG_CXX
 206 AC_PROG_CC
 207 AC_PROG_CPP
 208 AC_PROG_INSTALL
 209 AC_PROG_LN_S
 210 AC_PROG_MAKE_SET
 211 AC_PROG_LIBTOOL
 212 AM_PROG_CC_C_O
 213
 214 if test "x$cross_compiling" = "xno"; then
 215         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 216 else
 217         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 218 fi
 219
 220 AC_SUBST(CC_FOR_BUILD)
 221
 222 AC_CHECK_TOOL(AR, ar)
 223 AC_CHECK_TOOL(LD, ld)
 224
 225 AC_HEADER_STDC([])
 226 AC_GNULIBC
 227 AC_BSD_SIGNALS
 228
 229 dnl *************************************************************
 230 dnl * Check for required libraries
 231 dnl *************************************************************
 232
 233 AC_CHECK_FUNC([gethostbyname], ,
 234               [AC_CHECK_LIB([nsl], [gethostbyname], [LIBNSL="-lnsl"])])
 235 AC_SUBST(LIBNSL)
 236
 237 AC_CHECK_FUNC([connect], ,
 238               [AC_CHECK_LIB([socket], [connect], [LIBSOCKET="-lsocket"],
 239                     [AC_MSG_ERROR([Function 'socket' not found.])], [$LIBNSL])])
 240
 241 AC_CHECK_FUNC([getaddrinfo], ,
 242               [AC_MSG_ERROR([Function 'getaddrinfo' not found.])])
 243
 244 AC_CHECK_FUNC([getrpcbynumber], ,
 245               [AC_MSG_ERROR([Function 'getrpcbynumber' not found.])])
 246
 247 AC_CHECK_FUNC([getservbyname], ,
 248               [AC_MSG_ERROR([Function 'getservbyname' not found.])])
 249
 250 AC_CHECK_LIB([crypt], [crypt], [LIBCRYPT="-lcrypt"])
 251
 252 if test "$enable_nfsv4" = yes; then
 253   dnl check for libevent libraries and headers
 254   AC_LIBEVENT
 255
 256   dnl check for nfsidmap libraries and headers
 257   AC_LIBNFSIDMAP
 258
 259   dnl check for the keyutils libraries and headers
 260   AC_KEYUTILS
 261
 262   dnl librpcsecgss already has a dependency on libgssapi,
 263   dnl but we need to make sure we get the right version
 264   if test "$enable_gss" = yes; then
 265     AC_RPCSEC_VERSION
 266   fi
 267 fi
 268 dnl enable nfsidmap when its support by libnfsidmap
 269 AM_CONDITIONAL(CONFIG_NFSIDMAP, [test "$ac_cv_header_keyutils_h$ac_cv_lib_nfsidmap_nfs4_owner_to_uid" = "yesyes"])
 270
 271
 272 if test "$knfsd_cv_glibc2" = no; then
 273     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 274 fi
 275
 276 if test "$choose_blkid" != no; then
 277    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 278    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
 279    AC_BLKID_VERS
 280    if test $choose_blkid = yes; then
 281       use_blkid=1
 282       test $libblkid_cv_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
 283    else
 284       if test $libblkid_cv_is_recent = yes
 285       then use_blkid=1
 286       else use_blkid=0
 287            AC_MSG_WARN([uuid support disabled as libblkid is too old])
 288       fi
 289     fi
 290     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
 291 fi
 292 AC_SUBST(LIBSOCKET)
 293 AC_SUBST(LIBCRYPT)
 294 AC_SUBST(LIBBSD)
 295 AC_SUBST(LIBBLKID)
 296
 297 if test "$enable_libmount" != no; then
 298    AC_CHECK_LIB(mount, mnt_context_do_mount, [LIBMOUNT="-lmount"], AC_MSG_ERROR([libmount needed]))
 299    AC_CHECK_HEADER(libmount/libmount.h, , AC_MSG_ERROR([Cannot find libmount header file libmount/libmount.h]))
 300 fi
 301 AM_CONDITIONAL(CONFIG_LIBMOUNT, [test "$enable_libmount" = "yes"])
 302 AC_SUBST(LIBMOUNT)
 303
 304 if test "$enable_gss" = yes; then
 305   dnl 'gss' requires getnameinfo - at least for gssd_proc.c
 306   AC_CHECK_FUNC([getnameinfo], , [AC_MSG_ERROR([GSSAPI support requires 'getnameinfo' function])])
 307
 308   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 309   AC_LIBNFSIDMAP
 310
 311   AC_CHECK_HEADERS([spkm3.h], ,
 312                    [AC_MSG_WARN([Could not locate SPKM3 header; will not have SPKM3 support])])
 313
 314   dnl Check for Kerberos V5
 315   AC_KERBEROS_V5
 316
 317   dnl Invoked after AC_KERBEROS_V5; AC_LIBRPCSECGSS needs to have KRBLIBS set
 318   AC_LIBRPCSECGSS
 319
 320 fi
 321
 322 dnl Check for IPv6 support
 323 AC_IPV6
 324
 325 dnl *************************************************************
 326 dnl Check for headers
 327 dnl *************************************************************
 328 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 329                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 330                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 331                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 332                  syslog.h unistd.h com_err.h et/com_err.h \
 333                  ifaddrs.h])
 334
 335 dnl *************************************************************
 336 dnl Checks for typedefs, structures, and compiler characteristics
 337 dnl *************************************************************
 338 AC_C_CONST
 339 AC_TYPE_UID_T
 340 AC_C_INLINE
 341 AC_TYPE_OFF_T
 342 AC_TYPE_PID_T
 343 AC_TYPE_SIZE_T
 344 AC_HEADER_TIME
 345 AC_STRUCT_TM
 346
 347 dnl *************************************************************
 348 dnl Check for functions
 349 dnl *************************************************************
 350 AC_FUNC_ALLOCA
 351 AC_FUNC_CLOSEDIR_VOID
 352 AC_FUNC_ERROR_AT_LINE
 353 AC_FUNC_FORK
 354 AC_FUNC_GETGROUPS
 355 AC_FUNC_GETMNTENT
 356 AC_PROG_GCC_TRADITIONAL
 357 AC_FUNC_LSTAT
 358 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 359 AC_HEADER_MAJOR
 360 #AC_FUNC_MALLOC
 361 AC_FUNC_MEMCMP
 362 #AC_FUNC_REALLOC
 363 AC_FUNC_SELECT_ARGTYPES
 364 AC_TYPE_SIGNAL
 365 AC_FUNC_STAT
 366 AC_FUNC_VPRINTF
 367 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 368                gethostbyaddr gethostbyname gethostname getmntent \
 369                getnameinfo getrpcbyname getifaddrs \
 370                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 371                realpath rmdir select socket strcasecmp strchr strdup \
 372                strerror strrchr strtol strtoul sigprocmask])
 373
 374
 375 dnl *************************************************************
 376 dnl Check for data sizes
 377 dnl *************************************************************
 378 AC_CHECK_SIZEOF(short)
 379 AC_CHECK_SIZEOF(int)
 380 AC_CHECK_SIZEOF(long)
 381 AC_CHECK_SIZEOF(size_t)
 382 AC_CHECK_SIZEOF(socklen_t)
 383
 384
 385 dnl *************************************************************
 386 dnl Export some path names to config.h
 387 dnl *************************************************************
 388 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 389 AC_DEFINE_UNQUOTED(NSM_DEFAULT_STATEDIR, "$statdpath", [Define this to the pathname where statd keeps its state file])
 390
 391 if test "x$cross_compiling" = "xno"; then
 392         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 393         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 394         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 395         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 396 else
 397         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 398         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 399         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 400         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 401 fi
 402
 403 AC_SUBST(CFLAGS)
 404 AC_SUBST(CXXFLAGS)
 405 AC_SUBST(CPPFLAGS)
 406 AC_SUBST(LDFLAGS)
 407
 408 AC_SUBST(CFLAGS_FOR_BUILD)
 409 AC_SUBST(CXXFLAGS_FOR_BUILD)
 410 AC_SUBST(CPPFLAGS_FOR_BUILD)
 411 AC_SUBST(LDFLAGS_FOR_BUILD)
 412
 413 dnl *************************************************************
 414 dnl Set up "global" CFLAGS
 415 dnl *************************************************************
 416 dnl Use architecture-specific compile flags
 417 dnl (We use $host and not $build in case we are cross-compiling)
 418 dnl *************************************************************
 419 dnl Note: we no longer have arch specific compile flags, but
 420 dnl the stub is left here in case they are needed one day.
 421 case $host in
 422   *)
 423     ARCHFLAGS="" ;;
 424 esac
 425
 426 my_am_cflags="-Wall -Wextra -Wstrict-prototypes $ARCHFLAGS -pipe"
 427
 428 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 429
 430 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 431 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 432
 433 AC_CONFIG_FILES([
 434         Makefile
 435         linux-nfs/Makefile
 436         support/Makefile
 437         support/export/Makefile
 438         support/include/nfs/Makefile
 439         support/include/rpcsvc/Makefile
 440         support/include/sys/fs/Makefile
 441         support/include/sys/Makefile
 442         support/include/Makefile
 443         support/misc/Makefile
 444         support/nfs/Makefile
 445         support/nsm/Makefile
 446         tools/Makefile
 447         tools/locktest/Makefile
 448         tools/nlmtest/Makefile
 449         tools/rpcdebug/Makefile
 450         tools/rpcgen/Makefile
 451         tools/mountstats/Makefile
 452         tools/nfs-iostat/Makefile
 453         utils/Makefile
 454         utils/blkmapd/Makefile
 455         utils/exportfs/Makefile
 456         utils/gssd/Makefile
 457         utils/idmapd/Makefile
 458         utils/mount/Makefile
 459         utils/mountd/Makefile
 460         utils/nfsd/Makefile
 461         utils/nfsstat/Makefile
 462         utils/nfsidmap/Makefile
 463         utils/showmount/Makefile
 464         utils/statd/Makefile
 465         tests/Makefile
 466         tests/nsm_client/Makefile])
 467 AC_OUTPUT
 468