configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_INIT([linux nfs-utils],[1.2.6],[linux-nfs@vger.kernel.org],[nfs-utils])
   4 AC_CANONICAL_BUILD([])
   5 AC_CANONICAL_HOST([])
   6 AC_CONFIG_MACRO_DIR(aclocal)
   7 AM_INIT_AUTOMAKE
   8 AC_PREREQ(2.59)
   9 AC_PREFIX_DEFAULT(/usr)
  10 AM_MAINTAINER_MODE
  11
  12 dnl *************************************************************
  13 dnl * Define the set of applicable options
  14 dnl *************************************************************
  15 AC_ARG_WITH(release,
  16         [AC_HELP_STRING([--with-release=XXX], [set release to XXX [1]])],
  17         RELEASE=$withval,
  18         RELEASE=1)
  19         AC_SUBST(RELEASE)
  20 AC_ARG_WITH(statedir,
  21         [AC_HELP_STRING([--with-statedir=/foo],
  22                         [use state dir /foo @<:@default=/var/lib/nfs@:>@])],
  23         statedir=$withval,
  24         statedir=/var/lib/nfs)
  25         AC_SUBST(statedir)
  26 AC_ARG_WITH(statdpath,
  27         [AC_HELP_STRING([--with-statdpath=/foo],
  28                         [define the statd state dir as /foo instead of the NFS statedir @<:@default=/var/lib/nfs@:>@])],
  29         statdpath=$withval,
  30         statdpath=$statedir
  31         )
  32         AC_SUBST(statdpath)
  33 AC_ARG_WITH(statduser,
  34         [AC_HELP_STRING([--with-statduser=rpcuser],
  35                         [statd to run under @<:@rpcuser or nobody@:>@]
  36         )],
  37         statduser=$withval,
  38         if test "x$cross_compiling" = "xno"; then
  39                 if grep -s '^rpcuser:' /etc/passwd > /dev/null; then
  40                         statduser=rpcuser
  41                 else
  42                         statduser=nobody
  43                 fi
  44         else
  45                 statduser=nobody
  46         fi)
  47         AC_SUBST(statduser)
  48 AC_ARG_WITH(start-statd,
  49         [AC_HELP_STRING([--with-start-statd=scriptname],
  50                         [When an nfs filesystems is mounted with locking, run this script]
  51         )],
  52         startstatd=$withval,
  53         startstatd=/usr/sbin/start-statd
  54         )
  55         AC_SUBST(startstatd)
  56         AC_DEFINE_UNQUOTED(START_STATD, "$startstatd", [Define this to a script which can start statd on mount])
  57 AC_ARG_ENABLE(nfsv4,
  58         [AC_HELP_STRING([--enable-nfsv4],
  59                         [enable support for NFSv4 @<:@default=yes@:>@])],
  60         enable_nfsv4=$enableval,
  61         enable_nfsv4=yes)
  62         if test "$enable_nfsv4" = yes; then
  63                 IDMAPD=idmapd
  64         else
  65                 enable_nfsv4=
  66                 IDMAPD=
  67         fi
  68         AC_SUBST(IDMAPD)
  69         AC_SUBST(enable_nfsv4)
  70         AM_CONDITIONAL(CONFIG_NFSV4, [test "$enable_nfsv4" = "yes"])
  71
  72 AC_ARG_ENABLE(nfsv41,
  73         [AC_HELP_STRING([--enable-nfsv41],
  74                         [enable support for NFSv41 @<:@default=yes@:>@])],
  75         enable_nfsv41=$enableval,
  76         enable_nfsv41=yes)
  77         if test "$enable_nfsv41" = yes; then
  78                 if test "$enable_nfsv4" != yes; then
  79                         AC_MSG_ERROR([NFS v4.1 is enabled but NFS v4 is not. Use --disable-nfsv41])
  80                 fi
  81                 BLKMAPD=blkmapd
  82         else
  83                 enable_nfsv41=
  84                 BLKMAPD=
  85         fi
  86         AC_SUBST(enable_nfsv41)
  87         AM_CONDITIONAL(CONFIG_NFSV41, [test "$enable_nfsv41" = "yes"])
  88
  89 AC_ARG_ENABLE(gss,
  90         [AC_HELP_STRING([--enable-gss],
  91                         [enable support for rpcsec_gss @<:@default=yes@:>@])],
  92         enable_gss=$enableval,
  93         enable_gss=yes)
  94         if test "$enable_gss" = yes; then
  95                 GSSD=gssd
  96                 SVCGSSD=svcgssd
  97         else
  98                 enable_gss=
  99                 GSSD=
 100                 SVCGSSD=
 101         fi
 102         AC_SUBST(GSSD)
 103         AC_SUBST(SVCGSSD)
 104         AC_SUBST(enable_gss)
 105         AM_CONDITIONAL(CONFIG_GSS, [test "$enable_gss" = "yes"])
 106 AC_ARG_ENABLE(kprefix,
 107         [AC_HELP_STRING([--enable-kprefix], [install progs as rpc.knfsd etc])],
 108         test "$enableval" = "yes" && kprefix=k,
 109         kprefix=)
 110         AC_SUBST(kprefix)
 111 AC_ARG_WITH(rpcgen,
 112         [AC_HELP_STRING([--with-rpcgen=internal], [use internal rpcgen instead of system one])],
 113         rpcgen_path=$withval,
 114         rpcgen_path=yes )
 115         RPCGEN_PATH=
 116         if test "$rpcgen_path" = "yes"; then
 117             for p in /usr/local/bin/rpcgen /usr/bin/rpcgen /bin/rpcgen
 118             do if test -f $p ; then RPCGEN_PATH=$p ; break; fi ; done
 119         elif test "$rpcgen_path" != "internal"; then
 120             RPCGEN_PATH=$rpcgen_path
 121         fi
 122         AC_SUBST(RPCGEN_PATH)
 123         AM_CONDITIONAL(CONFIG_RPCGEN, [test "$RPCGEN_PATH" = ""])
 124 AC_ARG_ENABLE(uuid,
 125         [AC_HELP_STRING([--disable-uuid], [Exclude uuid support to avoid buggy libblkid])],
 126         if test "$enableval" = "yes" ; then choose_blkid=yes; else choose_blkid=no; fi,
 127         choose_blkid=default)
 128 AC_ARG_ENABLE(mount,
 129         [AC_HELP_STRING([--enable-mount],
 130                         [Create mount.nfs and do not use the util-linux mount(8) functionality. @<:@default=yes@:>@])],
 131         enable_mount=$enableval,
 132         enable_mount=yes)
 133         AM_CONDITIONAL(CONFIG_MOUNT, [test "$enable_mount" = "yes"])
 134
 135 if test "$enable_mount" = yes; then
 136         AC_ARG_ENABLE(libmount-mount,
 137                 [AC_HELP_STRING([--enable-libmount-mount],
 138                                 [Link mount.nfs with libmount (EXPERIMENTAL)])],
 139                 enable_libmount=$enableval,
 140                 enable_libmount=no)
 141 fi
 142
 143 AC_ARG_ENABLE(tirpc,
 144         [AC_HELP_STRING([--enable-tirpc],
 145                         [enable use of TI-RPC @<:@default=yes@:>@])],
 146         enable_tirpc=$enableval,
 147         enable_tirpc='')
 148 AC_ARG_ENABLE(ipv6,
 149         [AC_HELP_STRING([--enable-ipv6],
 150                         [enable support for IPv6 @<:@default=no@:>@])],
 151         enable_ipv6=$enableval,
 152         enable_ipv6=no)
 153         if test "$enable_ipv6" = yes; then
 154                 AC_DEFINE(IPV6_SUPPORTED, 1, [Define this if you want IPv6 support compiled in])
 155         else
 156                 enable_ipv6=
 157         fi
 158         AC_SUBST(enable_ipv6)
 159         AM_CONDITIONAL(CONFIG_IPV6, [test "$enable_ipv6" = "yes"])
 160
 161 if test "$enable_mount" = yes; then
 162         AC_ARG_ENABLE(mountconfig,
 163         [AC_HELP_STRING([--enable-mountconfig],
 164                         [enable mount to use a configuration file])],
 165         mountconfig=$enableval,
 166         mountconfig=no)
 167         if test "$enable_mountconfig" = yes; then
 168                 AC_DEFINE(MOUNT_CONFIG, 1,
 169                         [Define this if you want mount to read a configuration file])
 170                 AC_ARG_WITH(mountfile,
 171                         [AC_HELP_STRING([--with-mountfile=filename],
 172                         [Using filename as the NFS mount options file [/etc/nfsmounts.conf]]
 173                         )],
 174                 mountfile=$withval,
 175                 mountfile=/etc/nfsmount.conf)
 176                 AC_SUBST(mountfile)
 177                 AC_DEFINE_UNQUOTED(MOUNTOPTS_CONFFILE, "$mountfile",
 178                         [This defines the location of the NFS mount configuration file])
 179         else
 180                 enable_mountconfig=
 181         fi
 182         AC_SUBST(enable_mountconfig)
 183         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mountconfig" = "yes"])
 184 else
 185         AM_CONDITIONAL(MOUNT_CONFIG, [test "$enable_mount" = "yes"])
 186 fi
 187
 188 AC_ARG_ENABLE(nfsdcltrack,
 189         [AC_HELP_STRING([--enable-nfsdcltrack],
 190                         [enable NFSv4 clientid tracking programs @<:@default=yes@:>@])],
 191         enable_nfsdctrack=$enableval,
 192         enable_nfsdcltrack="yes")
 193
 194 dnl Check for TI-RPC library and headers
 195 AC_LIBTIRPC
 196
 197 dnl Check for -lcap
 198 AC_LIBCAP
 199
 200 # Check whether user wants TCP wrappers support
 201 AC_TCP_WRAPPERS
 202
 203 # Arrange for large-file support
 204 AC_SYS_LARGEFILE
 205
 206 AC_CONFIG_SRCDIR([support/include/config.h.in])
 207 AC_CONFIG_HEADERS([support/include/config.h])
 208
 209 # Checks for programs.
 210 AC_PROG_CXX
 211 AC_PROG_CC
 212 AC_PROG_CPP
 213 AC_PROG_INSTALL
 214 AC_PROG_LN_S
 215 AC_PROG_MAKE_SET
 216 AC_PROG_LIBTOOL
 217 AM_PROG_CC_C_O
 218
 219 if test "x$cross_compiling" = "xno"; then
 220         CC_FOR_BUILD=${CC_FOR_BUILD-${CC-gcc}}
 221 else
 222         CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 223 fi
 224
 225 AC_SUBST(CC_FOR_BUILD)
 226
 227 AC_CHECK_TOOL(AR, ar)
 228 AC_CHECK_TOOL(LD, ld)
 229
 230 AC_HEADER_STDC([])
 231 AC_GNULIBC
 232 AC_BSD_SIGNALS
 233
 234 dnl *************************************************************
 235 dnl * Check for required libraries
 236 dnl *************************************************************
 237
 238 AC_CHECK_FUNC([gethostbyname], ,
 239               [AC_CHECK_LIB([nsl], [gethostbyname], [LIBNSL="-lnsl"])])
 240 AC_SUBST(LIBNSL)
 241
 242 AC_CHECK_FUNC([connect], ,
 243               [AC_CHECK_LIB([socket], [connect], [LIBSOCKET="-lsocket"],
 244                     [AC_MSG_ERROR([Function 'socket' not found.])], [$LIBNSL])])
 245
 246 AC_CHECK_FUNC([getaddrinfo], ,
 247               [AC_MSG_ERROR([Function 'getaddrinfo' not found.])])
 248
 249 AC_CHECK_FUNC([getrpcbynumber], ,
 250               [AC_MSG_ERROR([Function 'getrpcbynumber' not found.])])
 251
 252 AC_CHECK_FUNC([getservbyname], ,
 253               [AC_MSG_ERROR([Function 'getservbyname' not found.])])
 254
 255 AC_CHECK_LIB([crypt], [crypt], [LIBCRYPT="-lcrypt"])
 256
 257 AC_CHECK_LIB([dl], [dlclose], [LIBDL="-ldl"])
 258
 259 if test "$enable_nfsv4" = yes; then
 260   dnl check for libevent libraries and headers
 261   AC_LIBEVENT
 262
 263   dnl check for nfsidmap libraries and headers
 264   AC_LIBNFSIDMAP
 265
 266   dnl check for the keyutils libraries and headers
 267   AC_KEYUTILS
 268
 269   dnl Check for sqlite3
 270   AC_SQLITE3_VERS
 271
 272   if test "$enable_nfsdcltrack" = "yes"; then
 273         AC_CHECK_HEADERS([libgen.h sys/inotify.h], ,
 274                 AC_MSG_ERROR([Cannot find header needed for nfsdcltrack]))
 275
 276         if test "$libsqlite3_cv_is_recent" != "yes" ; then
 277                 AC_MSG_ERROR([nfsdcltrack requires sqlite-devel])
 278         fi
 279   fi
 280
 281   dnl librpcsecgss already has a dependency on libgssapi,
 282   dnl but we need to make sure we get the right version
 283   if test "$enable_gss" = yes; then
 284     AC_RPCSEC_VERSION
 285   fi
 286 fi
 287
 288 if test "$enable_nfsv41" = yes; then
 289   AC_CHECK_LIB([devmapper], [dm_task_create], [LIBDEVMAPPER="-ldevmapper"], AC_MSG_ERROR([libdevmapper needed]))
 290   AC_CHECK_HEADER(libdevmapper.h, , AC_MSG_ERROR([Cannot find devmapper header file libdevmapper.h]))
 291   AC_CHECK_HEADER(sys/inotify.h, , AC_MSG_ERROR([Cannot find header file sys/inotify.h]))
 292 fi
 293
 294 dnl enable nfsidmap when its support by libnfsidmap
 295 AM_CONDITIONAL(CONFIG_NFSDCLTRACK, [test "$enable_nfsdcltrack" = "yes" ])
 296 AM_CONDITIONAL(CONFIG_NFSIDMAP, [test "$ac_cv_header_keyutils_h$ac_cv_lib_nfsidmap_nfs4_owner_to_uid" = "yesyes"])
 297
 298
 299 if test "$knfsd_cv_glibc2" = no; then
 300     AC_CHECK_LIB(bsd, daemon, [LIBBSD="-lbsd"])
 301 fi
 302
 303 if test "$choose_blkid" != no; then
 304    AC_CHECK_LIB(blkid, blkid_get_library_version, [LIBBLKID="-lblkid"], AC_MSG_ERROR([libblkid needed]))
 305    AC_CHECK_HEADER(blkid/blkid.h, , AC_MSG_ERROR([Cannot find libblkid header file blkid/blkid.h]))
 306    AC_BLKID_VERS
 307    if test $choose_blkid = yes; then
 308       use_blkid=1
 309       test $libblkid_cv_is_recent = no && AC_MSG_WARN([libblkid is old and may cause mountd to leak memory])
 310    else
 311       if test $libblkid_cv_is_recent = yes
 312       then use_blkid=1
 313       else use_blkid=0
 314            AC_MSG_WARN([uuid support disabled as libblkid is too old])
 315       fi
 316     fi
 317     AC_DEFINE_UNQUOTED(USE_BLKID, $use_blkid, [Define if you want to use blkid to find uuid of filesystems])
 318 fi
 319 AC_SUBST(LIBSOCKET)
 320 AC_SUBST(LIBCRYPT)
 321 AC_SUBST(LIBBSD)
 322 AC_SUBST(LIBBLKID)
 323 AC_SUBST(LIBDL)
 324
 325 if test "$enable_libmount" != no; then
 326    AC_CHECK_LIB(mount, mnt_context_do_mount, [LIBMOUNT="-lmount"], AC_MSG_ERROR([libmount needed]))
 327    AC_CHECK_HEADER(libmount/libmount.h, , AC_MSG_ERROR([Cannot find libmount header file libmount/libmount.h]))
 328 fi
 329 AM_CONDITIONAL(CONFIG_LIBMOUNT, [test "$enable_libmount" = "yes"])
 330 AC_SUBST(LIBMOUNT)
 331
 332 if test "$enable_gss" = yes; then
 333   dnl 'gss' requires getnameinfo - at least for gssd_proc.c
 334   AC_CHECK_FUNC([getnameinfo], , [AC_MSG_ERROR([GSSAPI support requires 'getnameinfo' function])])
 335
 336   dnl 'gss' also depends on nfsidmap.h - at least for svcgssd_proc.c
 337   AC_LIBNFSIDMAP
 338
 339   dnl Check for Kerberos V5
 340   AC_KERBEROS_V5
 341
 342   dnl Invoked after AC_KERBEROS_V5; AC_LIBRPCSECGSS needs to have KRBLIBS set
 343   AC_LIBRPCSECGSS
 344
 345 fi
 346
 347 dnl Check for IPv6 support
 348 AC_IPV6
 349
 350 dnl *************************************************************
 351 dnl Check for headers
 352 dnl *************************************************************
 353 AC_CHECK_HEADERS([arpa/inet.h fcntl.h libintl.h limits.h \
 354                  malloc.h memory.h netdb.h netinet/in.h paths.h \
 355                  stdlib.h string.h sys/file.h sys/ioctl.h sys/mount.h \
 356                  sys/param.h sys/socket.h sys/time.h sys/vfs.h \
 357                  syslog.h unistd.h com_err.h et/com_err.h \
 358                  ifaddrs.h nfs-plugin.h])
 359
 360 dnl *************************************************************
 361 dnl Checks for typedefs, structures, and compiler characteristics
 362 dnl *************************************************************
 363 AC_C_CONST
 364 AC_TYPE_UID_T
 365 AC_C_INLINE
 366 AC_TYPE_OFF_T
 367 AC_TYPE_PID_T
 368 AC_TYPE_SIZE_T
 369 AC_HEADER_TIME
 370 AC_STRUCT_TM
 371
 372 dnl *************************************************************
 373 dnl Check for functions
 374 dnl *************************************************************
 375 AC_FUNC_ALLOCA
 376 AC_FUNC_CLOSEDIR_VOID
 377 AC_FUNC_ERROR_AT_LINE
 378 AC_FUNC_FORK
 379 AC_FUNC_GETGROUPS
 380 AC_FUNC_GETMNTENT
 381 AC_PROG_GCC_TRADITIONAL
 382 AC_FUNC_LSTAT
 383 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 384 AC_HEADER_MAJOR
 385 #AC_FUNC_MALLOC
 386 AC_FUNC_MEMCMP
 387 #AC_FUNC_REALLOC
 388 AC_FUNC_SELECT_ARGTYPES
 389 AC_TYPE_SIGNAL
 390 AC_FUNC_STAT
 391 AC_FUNC_VPRINTF
 392 AC_CHECK_FUNCS([alarm atexit dup2 fdatasync ftruncate getcwd \
 393                gethostbyaddr gethostbyname gethostname getmntent \
 394                getnameinfo getrpcbyname getifaddrs \
 395                gettimeofday hasmntopt inet_ntoa innetgr memset mkdir pathconf \
 396                ppoll realpath rmdir select socket strcasecmp strchr strdup \
 397                strerror strrchr strtol strtoul sigprocmask])
 398
 399
 400 dnl *************************************************************
 401 dnl Check for data sizes
 402 dnl *************************************************************
 403 AC_CHECK_SIZEOF(short)
 404 AC_CHECK_SIZEOF(int)
 405 AC_CHECK_SIZEOF(long)
 406 AC_CHECK_SIZEOF(size_t)
 407 AC_CHECK_SIZEOF(socklen_t)
 408
 409
 410 dnl *************************************************************
 411 dnl Export some path names to config.h
 412 dnl *************************************************************
 413 AC_DEFINE_UNQUOTED(NFS_STATEDIR, "$statedir", [This defines the location of the NFS state files. Warning: this must match definitions in config.mk!])
 414 AC_DEFINE_UNQUOTED(NSM_DEFAULT_STATEDIR, "$statdpath", [Define this to the pathname where statd keeps its state file])
 415
 416 if test "x$cross_compiling" = "xno"; then
 417         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-"$CFLAGS"}
 418         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-"$CXXFLAGS"}
 419         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-"$CPPFLAGS"}
 420         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-"$LDFLAGS"}
 421 else
 422         CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-""}
 423         CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-""}
 424         CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-""}
 425         LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-""}
 426 fi
 427
 428 AC_SUBST(CFLAGS)
 429 AC_SUBST(CXXFLAGS)
 430 AC_SUBST(CPPFLAGS)
 431 AC_SUBST(LDFLAGS)
 432
 433 AC_SUBST(CFLAGS_FOR_BUILD)
 434 AC_SUBST(CXXFLAGS_FOR_BUILD)
 435 AC_SUBST(CPPFLAGS_FOR_BUILD)
 436 AC_SUBST(LDFLAGS_FOR_BUILD)
 437
 438 dnl *************************************************************
 439 dnl Set up "global" CFLAGS
 440 dnl *************************************************************
 441 dnl Use architecture-specific compile flags
 442 dnl (We use $host and not $build in case we are cross-compiling)
 443 dnl *************************************************************
 444 dnl Note: we no longer have arch specific compile flags, but
 445 dnl the stub is left here in case they are needed one day.
 446 case $host in
 447   *)
 448     ARCHFLAGS="" ;;
 449 esac
 450
 451 my_am_cflags="-Wall -Wextra -Wstrict-prototypes $ARCHFLAGS -pipe"
 452
 453 AC_SUBST([AM_CFLAGS], ["$my_am_cflags"])
 454
 455 # Make sure that $ACLOCAL_FLAGS are used during a rebuild
 456 AC_SUBST([ACLOCAL_AMFLAGS], ["-I $ac_macro_dir \$(ACLOCAL_FLAGS)"])
 457
 458 AC_CONFIG_FILES([
 459         Makefile
 460         linux-nfs/Makefile
 461         support/Makefile
 462         support/export/Makefile
 463         support/include/nfs/Makefile
 464         support/include/rpcsvc/Makefile
 465         support/include/sys/fs/Makefile
 466         support/include/sys/Makefile
 467         support/include/Makefile
 468         support/misc/Makefile
 469         support/nfs/Makefile
 470         support/nsm/Makefile
 471         tools/Makefile
 472         tools/locktest/Makefile
 473         tools/nlmtest/Makefile
 474         tools/rpcdebug/Makefile
 475         tools/rpcgen/Makefile
 476         tools/mountstats/Makefile
 477         tools/nfs-iostat/Makefile
 478         utils/Makefile
 479         utils/blkmapd/Makefile
 480         utils/nfsdcltrack/Makefile
 481         utils/exportfs/Makefile
 482         utils/gssd/Makefile
 483         utils/idmapd/Makefile
 484         utils/mount/Makefile
 485         utils/mountd/Makefile
 486         utils/nfsd/Makefile
 487         utils/nfsstat/Makefile
 488         utils/nfsidmap/Makefile
 489         utils/showmount/Makefile
 490         utils/statd/Makefile
 491         utils/osd_login/Makefile
 492         tests/Makefile
 493         tests/nsm_client/Makefile])
 494 AC_OUTPUT
 495