aclocal/kerberos5.m4

   1 dnl Checks for Kerberos
   2 dnl NOTE: while we intend to do generic gss-api, currently we
   3 dnl have a requirement to get an initial Kerberos machine
   4 dnl credential.  Thus, the requirement for Kerberos.
   5 dnl The Kerberos gssapi library will be dynamically loaded?
   6 AC_DEFUN([AC_KERBEROS_V5],[
   7   AC_MSG_CHECKING(for Kerberos v5)
   8   AC_ARG_WITH(krb5,
   9   [AC_HELP_STRING([--with-krb5=DIR], [use Kerberos v5 installation in DIR])],
  10   [ case "$withval" in
  11     yes|no)
  12        krb5_with=""
  13        ;;
  14     *)
  15        krb5_with="$withval"
  16        ;;
  17     esac ]
  18   )
  19
  20   for dir in $krb5_with /usr /usr/kerberos /usr/local /usr/local/krb5 \
  21              /usr/krb5 /usr/heimdal /usr/local/heimdal /usr/athena ; do
  22     dnl This ugly hack brought on by the split installation of
  23     dnl MIT Kerberos on Fedora Core 1
  24     K5CONFIG=""
  25     if test -f $dir/bin/krb5-config; then
  26       K5CONFIG=$dir/bin/krb5-config
  27     elif test -f "/usr/kerberos/bin/krb5-config"; then
  28       K5CONFIG="/usr/kerberos/bin/krb5-config"
  29     fi
  30     if test "$K5CONFIG" != ""; then
  31       KRBCFLAGS=`$K5CONFIG --cflags`
  32       KRBLIBS=`$K5CONFIG --libs gssapi`
  33       K5VERS=`$K5CONFIG --version | head -n 1 | awk '{split($(4),v,"."); if (v@<:@"3"@:>@ == "") v@<:@"3"@:>@ = "0"; print v@<:@"1"@:>@v@<:@"2"@:>@v@<:@"3"@:>@ }'`
  34       AC_DEFINE_UNQUOTED(KRB5_VERSION, $K5VERS, [Define this as the Kerberos version number])
  35       if test -f $dir/include/gssapi/gssapi_krb5.h -a \
  36                 \( -f $dir/lib/libgssapi_krb5.a -o \
  37                    -f $dir/lib/libgssapi_krb5.so \) ; then
  38          AC_DEFINE(HAVE_KRB5, 1, [Define this if you have MIT Kerberos libraries])
  39          KRBDIR="$dir"
  40   dnl If we are using MIT K5 1.3.1 and before, we *MUST* use the
  41   dnl private function (gss_krb5_ccache_name) to get correct
  42   dnl behavior of changing the ccache used by gssapi.
  43   dnl Starting in 1.3.2, we *DO NOT* want to use
  44   dnl gss_krb5_ccache_name, instead we want to set KRB5CCNAME
  45   dnl to get gssapi to use a different ccache
  46          if test $K5VERS -le 131; then
  47            AC_DEFINE(USE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the private function, gss_krb5_cache_name, must be used to tell the Kerberos library which credentials cache to use. Otherwise, this is done by setting the KRB5CCNAME environment variable])
  48          fi
  49          gssapi_lib=gssapi_krb5
  50          break
  51       dnl The following ugly hack brought on by the split installation
  52       dnl of Heimdal Kerberos on SuSe
  53       elif test \( -f $dir/include/heim_err.h -o\
  54                  -f $dir/include/heimdal/heim_err.h \) -a \
  55                 -f $dir/lib/libroken.a; then
  56          AC_DEFINE(HAVE_HEIMDAL, 1, [Define this if you have Heimdal Kerberos libraries])
  57          KRBDIR="$dir"
  58          gssapi_lib=gssapi
  59         break
  60       fi
  61     fi
  62   done
  63   dnl We didn't find a usable Kerberos environment
  64   if test "x$KRBDIR" = "x"; then
  65     if test "x$krb5_with" = "x"; then
  66       AC_MSG_ERROR(Kerberos v5 with GSS support not found: consider --disable-gss or --with-krb5=)
  67     else
  68       AC_MSG_ERROR(Kerberos v5 with GSS support not found at $krb5_with)
  69     fi
  70   fi
  71   AC_MSG_RESULT($KRBDIR)
  72
  73   dnl Now check for functions within gssapi library
  74   AC_CHECK_LIB($gssapi_lib, gss_krb5_export_lucid_sec_context,
  75     AC_DEFINE(HAVE_LUCID_CONTEXT_SUPPORT, 1, [Define this if the Kerberos GSS library supports gss_krb5_export_lucid_sec_context]), ,$KRBLIBS)
  76   AC_CHECK_LIB($gssapi_lib, gss_krb5_set_allowable_enctypes,
  77     AC_DEFINE(HAVE_SET_ALLOWABLE_ENCTYPES, 1, [Define this if the Kerberos GSS library supports gss_krb5_set_allowable_enctypes]), ,$KRBLIBS)
  78   AC_CHECK_LIB($gssapi_lib, gss_krb5_ccache_name,
  79     AC_DEFINE(HAVE_GSS_KRB5_CCACHE_NAME, 1, [Define this if the Kerberos GSS library supports gss_krb5_ccache_name]), ,$KRBLIBS)
  80
  81   dnl If they specified a directory and it didn't work, give them a warning
  82   if test "x$krb5_with" != "x" -a "$krb5_with" != "$KRBDIR"; then
  83     AC_MSG_WARN(Using $KRBDIR instead of requested value of $krb5_with for Kerberos!)
  84   fi
  85
  86   AC_SUBST([KRBDIR])
  87   AC_SUBST([KRBLIBS])
  88   AC_SUBST([KRBCFLAGS])
  89   AC_SUBST([K5VERS])
  90
  91 ])